新三价线交易策略源码 中长线

新三价线的定义：

新三价线指标，英文全名为Three Line Break(TLB)。史蒂夫·尼森（Steven Nison）在其《非K线判市法》一书中，将新三值线的概念引入到美国。原理是任意三根持续上涨或下跌K线，所创出短期新高或新低时，会形成红色或绿色的柱状体，分别表示买入或卖出信号。由于新三价线在平时盘整时不轻易出现信号，当多空趋势明显时，买卖讯号才会产生。但由于反应较慢，容易造成追涨或助跌的效果，所以适合做波段投资指标使用。

它的画法是这样子的 ： 首先要找出四天来的收盘价， 假设现在趋势向下， 我们要看今天的收盘价是否比四天前还要高，如果是 ，就在纸上划上一根阳棒 ，表示趋势已经翻多了 ，可以建立多单 ，空单也要立即停损出场 。明天如果收红 ，继续划下去 ，如果中间有收黑的日子 ，要看收盘有没有跌破四天前的开盘价位，如果答桉是否定的，一律不管它 ，一路划下去 ， 直到趋势改变 ， 反向划黑棒为止。

 

可以看得出 ，这是一种判别中长期多空趋势的指标 ，属于中长线投资人使用的技术指标，很适合无暇天天盯着盘势的上班族来使用 。这个指标的优点是当趋势很清楚走多或走空时 ， 它可以完整的抓到百分之七十以上的波段 ， 不怕遗漏。 直到趋势改变将你带出场为止。可称得上是真正的 「懒人操作法」。 但是这个指标有一个缺点， 整理盘时忽多忽空很容易 造成追高杀低的窘态，这也是所有技术指标所面临的困境。

 

低档出现红三兵，通常是正式起涨的前兆；高档出现黑三卒，则需留意趋势的转变，随时可能做头下杀，这是一般K线的理论，但套在简单的技术指标新三价线上，运用起来则更为贴切。

 

新三价线公式：

当日收盘价较前日的最高价都还高时→买进讯号

当日收盘价较前日的最低价都还低时→卖出讯号

 

新三价线指标的优缺点

1、新三价线指标的优点

新三值线的优点是在判断转势时，去除了主观武断的感情因素。通过发生的价格的真实状态，得出了反转的信号。

2、新三价线指标的缺点

在产生转值时，新趋势已经延续了一段时期。不过，许多交易者乐意接受迟缓的信号，以求
跟踪主要趋势。

 

指标程式码

input:CountL(3),CountS(3) ;

Vars:RevHigh(0),RevLow(0),TrendL(false),TrendS(false) ;

 

{ 收盘价 > 近三根K棒最高价 且前一根K棒低点为近三根最低点  且前三根K棒收黑}
TrendL = Close > Highest(High,CountL)[1] and Low[1] = Lowest(Low,CountL)[1]
and Countif(Close[1] < Open[1],CountL) = CountL;
if TrendL then RevHigh = Highest(High,CountL)[1] ;

 

{ 收盘价 < 近三根K棒最低价 且前一根K棒高点为近三根最高点 且前三根K棒收红}
TrendS = Close < Lowest(Low,CountS)[1] and High[1] = Highest(High,CountS)[1]
and Countif(Close[1] > Open[1],CountS) = CountS;
if TrendS then RevLow = Lowest(Low,CountS)[1] ;

 

Plot1(RevHigh,"RevHigh") ;

Plot2(RevLow,"RevLow") ;

测试程式码

input:ExitType(0) ;

input:NBarL(28),NBarS(3),TradeProfit(0.045),TradeStopLoss(0.025),ATRs_L(5.4),ATRs_S(10.9);

vars: IsBalanceDay(False),MP(0),PF(0),PL(0),HLRange(100);

 

input:CountL(2),CountS(5),EntL(6),EntS(3) ;

Vars:RevHigh(0),RevLow(0),TrendL(false),TrendS(false) ;

 

MP = MarketPosition ;

if DAYofMonth(Date) > 14 and DAYofMonth(Date) < 22 and DAYofWeek(Date)= 3 then isBalanceDay = True else isBalanceDay =False ;

 

PF = AvgPrice*TradeProfit ;
PL = AvgPrice*TradeStopLoss ;

 

TrendL = Close > Highest(High,CountL)[1] and Low[1] = Lowest(Low,CountL)[1]
and Countif(Close[1] < Open[1],CountL) = CountL;
TrendS = Close < Lowest(Low,CountS)[1] and High[1] = Highest(High,CountS)[1]
and Countif(Close[1] > Open[1],CountS) = CountS;

 

if TrendL then RevHigh = Highest(High,CountL)[1] ;
if TrendS then RevLow = Lowest(Low,CountS)[1] ;

 

if Close[1] < RevHigh[1] and Close > RevHigh then Buy next bar at Highest(High,EntL) stop ;
if Close[1] > RevLow[1] and Close < RevLow then Sell next bar at Lowest(Low,EntS) stop ;

 

if ExitType = 1 then SetStopLoss(PL * BigPointValue) ;

 

if ExitType = 2 then Begin

SetStopLoss(PL * BigPointValue) ;

setProfitTarget(PF * BigPointValue) ;

end;

if ExitType = 3 then Begin

if MP > 0 and BarsSinceEntry = NBarL then ExitLong next bar at Market ;

if MP < 0 and BarsSinceEntry = NBarS then ExitShort next bar at Market ;

end;

if ExitType = 4 then Begin

SetStopLoss(PL * BigPointValue) ;

setProfitTarget(PF * BigPointValue) ;

if MP > 0 and BarsSinceEntry = NBarL then {Sell } ExitLong next bar at Market ;

if MP < 0 and BarsSinceEntry = NBarS then {Buy} ExitShort next bar at Market ;

end;

 

if IsBalanceDay then setExitonClose ;

台指期 15 min K 多空留仓 交易週期 2004/8/31~ 2014/8/29 交易成本 1200

台指期 30 min K 多空留仓 交易週期 2004/8/31~ 2014/8/29 交易成本 1200