Conditional Execution And Branch：带条件的指令和分支

状态寄存器每位代表的含义

在ARM状态下，绝大多数的指令都是有条件执行的；在THUMB状态下，仅有分支指令是条件执行的。

• 从代码中看标志位

.global main

main:
        mov     r0, #2     /* setting up initial variable */
        cmp     r0, #3     /* comparing r0 to number 3. Negative bit get's set to 1 */
        addlt   r0, r0, #1 /* increasing r0 IF it was determined that it is smaller (lower than) number 3 */
        cmp     r0, #3     /* comparing r0 to number 3 again. Zero bit gets set to 1. Negative bit is set to 0 */
        addlt   r0, r0, #1 /* increasing r0 IF it was determined that it is smaller (lower than) number 3 */
        bx      lr

运行到mov r0, #2时，先i r cpsr查看状态寄存器

cpsr           0x10 0x10

然后ni 2执行完cmp r0, #3，即r0-3，再次查看状态寄存器，可以对应第一个表知道，Z=0表示结果非0

cpsr           0x80000010   0x80000010
即：1000  0000  0000  0000  0000  0000  0001  0000

执行cmp r0, #3，得到如下，也就是Z=1&&C=1，根据上面的表得到，结果r0-3=0，没有借位

cpsr           0x60000010   0x60000010
即：0110  0000  0000  0000  0000  0000  0001  0000

带条件指令

2018-11-28_110157.png

• 继续根据上面的代码：分析addlt r0, r0, #1。addlt = add + LT。只要上面一条指令cmp r0, #3，r0<3即可执行

Thumb中的条件指令

Thumb-1（16位指令）：用于ARMv6和早期架构。
Thumb-2（16位和32位指令）：通过添加更多指令并允许它们为16位或32位宽（ARMv6T2，ARMv7）来扩展Thumb-1。
ThumbEE：包括针对动态生成的代码的一些更改和添加（在执行之前或执行期间在设备上编译的代码）。

Thumb和ARM差异

• 条件执行：ARM状态中的所有指令都支持条件执行。 某些ARM处理器版本允许使用IT指令在Thumb中进行条件执行。 条件执行会导致更高的代码密度，因为它减少了要执行的指令数量，并减少了昂贵的分支指令数量。
• 32位ARM和Thumb指令：32位Thumb指令具有.w后缀。
• 桶形移位器是另一种独特的ARM模式功能

切换指令模式的条件（任意一个即可）

• 我们可以使用分支指令BX（分支和交换）或BLX（分支，链接和交换）并将目标寄存器的最低有效位设置为1
• 设置当前程序状态寄存器中的T位置位

某些ARM处理器版本支持“IT”指令，该指令允许在Thumb状态下有条件地执行最多4条指令

语法：IT { x { y { z }}} cond

cond指定IT块中第一条指令的条件
x指定IT块中第二条指令的条件开关
y指定IT块中第三条指令的条件开关
z指定IT块中第四条指令的条件开关
IT指令的结构是“IF-Then-（Else）”，语法是两个字母T和E的结构：

IT指的是If-Then（下一条指令是有条件的）
ITT指的是If-Then-Then（接下来的2条指令是有条件的）
ITE指的是If-Then-Else（接下来的2条指令是有条件的）
ITTE指的是If-Then-Then-Else（接下来的3条指令是有条件的）
ITTEE指的是If-Then-Then-Else-Else（接下来的4条指令是有条件的）
IT块内的每条指令必须指定相同或逻辑反转的条件后缀。 这意味着如果使用ITE，则第一个和第二个指令（If-Then）必须具有相同的条件后缀，而第三个（Else）必须具有前两个的逻辑反转

ITTE   NE           ; Next 3 instructions are conditional
ANDNE  R0, R0, R1   ; ANDNE does not update condition flags
ADDSNE R2, R2, #1   ; ADDSNE updates condition flags
MOVEQ  R2, R3       ; Conditional move

ITE    GT           ; Next 2 instructions are conditional
ADDGT  R1, R0, #55  ; Conditional addition in case the GT is true
ADDLE  R1, R0, #48  ; Conditional addition in case the GT is not true

ITTEE  EQ           ; Next 4 instructions are conditional
MOVEQ  R0, R1       ; Conditional MOV
ADDEQ  R2, R2, #10  ; Conditional ADD
ANDNE  R3, R3, #1   ; Conditional AND
BNE.W  dloop        ; Branch instruction can only be used in the last instruction of an IT block

实例：

int main() {
   int max = 0;
   int a = 2;
   int b = 3;
   if(a < b) {
    max = b;
   }
   else {
    max = a;
   }
   return max;
}

对应汇编：
.global main

main:
        mov     r1, #2     /* setting up initial variable a */
        mov     r2, #3     /* setting up initial variable b */
        cmp     r1, r2     /* comparing variables to determine which is bigger */
        blt     r1_lower   /* jump to r1_lower in case r2 is bigger (N==1) */
        mov     r0, r1     /* if branching/jumping did not occur, r1 is bigger (or the same) so store r1 into r0 */
        b       end        /* proceed to the end */
r1_lower:
        mov r0, r2         /* We ended up here because r1 was smaller than r2, so move r2 into r0 */
        b end              /* proceed to the end */
end:
        bx lr              /* THE END */

int main() {
   int a = 0;
   while(a < 4) {
   a= a+1;
   }
   return a;
}

汇编：
.global main

main:
        mov     r0, #0     /* setting up initial variable a */
loop:
        cmp     r0, #4     /* checking if a==4 */
        beq     end        /* proceeding to the end if a==4 */
        add     r0, r0, #1 /* increasing a by 1 if the jump to the end did not occur */
        b loop             /* repeating the loop */
end:
        bx lr              /* THE END */