异步FIFO Verilog实现

最新推荐文章于 2024-08-26 21:15:20 发布
最新推荐文章于 2024-08-26 21:15:20 发布
阅读量1.9k 收藏 14
点赞数 1
分类专栏： verilog 文章标签： Verilog  FIFO  gray

本文大部分内容来自Clifford E. Cummings的《Simulation and Synthesis Techniques for Asynchronous FIFO Design》，同时加上一些自己的一些理解，有兴趣的朋友可以阅读原文。

一、FIFO简介

　　FIFO是英文First In First Out 的缩写，是一种先进先出的数据缓存器，它与普通存储器的区别是没有外部读写地址线，这样使用起来非常简单，但缺点就是只能顺序写入数据，顺序的读出数据，其数据地址由内部读写指针自动加1完成，不能像普通存储器那样可以由地址线决定读取或写入某个指定的地址。

用途1：

　　异步FIFO读写分别采用相互异步的不同时钟。在现代集成电路芯片中，随着设计规模的不断扩大，一个系统中往往含有数个时钟，多时钟域带来的一个问题就是，如何设计异步时钟之间的接口电路。异步FIFO是这个问题的一种简便、快捷的解决方案，使用异步FIFO可以在两个不同时钟系统之间快速而方便地传输实时数据。

用途2：

　　对于不同宽度的数据接口也可以用FIFO，例如单片机位8位数据输出，而DSP可能是16位数据输入，在单片机与DSP连接时就可以使用FIFO来达到数据匹配的目的。

二、分类

　　同步FIFO是指读时钟和写时钟为同一个时钟，在时钟沿来临时同时发生读写操作；

　　异步FIFO是指读写时钟不一致，读写时钟是互相独立的。

三、FIFO的常见参数

  • FIFO的宽度：即FIFO一次读写操作的数据位；
  • FIFO的深度：指的是FIFO可以存储多少个N位的数据（如果宽度为N）。
  • 满标志：FIFO已满或将要满时由FIFO的状态电路送出的一个信号，以阻止FIFO的写操作继续向FIFO中写数据而造成溢出（overflow）。
  • 空标志：FIFO已空或将要空时由FIFO的状态电路送出的一个信号，以阻止FIFO的读操作继续从FIFO中读出数据而造成无效数据的读出（underflow）。
  • 读时钟：读操作所遵循的时钟，在每个时钟沿来临时读数据。
  • 写时钟：写操作所遵循的时钟，在每个时钟沿来临时写数据。

===============================分   隔    符 ==============================

  1. 读写指针的工作原理

　　读指针：总是指向下一个将要被写入的单元，复位时，指向第1个单元(编号为0)。

　　写指针：总是指向当前要被读出的数据，复位时，指向第1个单元(编号为0)

 

  1. FIFO的“空”/“满”检测

　　FIFO设计的关键：产生可靠的FIFO读写指针和生成FIFO“空”/“满”状态标志。

　　当读写指针相等时，表明FIFO为空，这种情况发生在复位操作时，或者当读指针读出FIFO中最后一个字后，追赶上了写指针时，如下图所示：

当读写指针再次相等时，表明FIFO为满，这种情况发生在，当写指针转了一圈，折回来(wrapped around)又追上了读指针，如下图：    


为了区分到底是满状态还是空状态，可以采用以下方法：

　　　　方法1：在指针中添加一个额外的位(extra bit)，当写指针增加并越过最后一个FIFO地址时，就将写指针这个未用的MSB加1，其它位回零。对读指针也进行同样的操作。此时，对于深度为2n的FIFO，需要的读/写指针位宽为(n+1)位，如对于深度为8的FIFO，需要采用4bit的计数器，0000～1000、1001～1111，MSB作为折回标志位，而低3位作为地址指针。

    • 如果两个指针的MSB不同，说明写指针比读指针多折回了一次；如r_addr=0000,而w_addr = 1000,为满。
    • 如果两个指针的MSB相同，则说明两个指针折回的次数相等。其余位相等，说明FIFO为空；

3.二进制FIFO指针的考虑

　　将一个二进制的计数值从一个时钟域同步到另一个时钟域的时候很容易出现问题，因为采用二进制计数器时所有位都可能同时变化，在同一个时钟沿同步多个信号的变化会产生亚稳态问题。而使用格雷码只有一位变化，因此在两个时钟域间同步多个位不会产生问题。所以需要一个二进制到gray码的转换电路，将地址值转换为相应的gray码，然后将该gray码同步到另一个时钟域进行对比，作为空满状态的检测



4.

  • 使用gray码进行对比，如何判断“空”与“满”

 　　使用gray码解决了一个问题，但同时也带来另一个问题，即在格雷码域如何判断空与满。

　　对于“空”的判断依然依据二者完全相等(包括MSB)；

　　而对于“满”的判断，如下图，由于gray码除了MSB外，具有镜像对称的特点，当读指针指向7，写指针指向8时，除了MSB，其余位皆相同，不能说它为满。因此不能单纯的只检测最高位了，在gray码上判断为满必须同时满足以下3条：

  • wptr和同步过来的rptr的MSB不相等，因为wptr必须比rptr多折回一次。
  • wptr与rptr的次高位不相等，如上图位置7和位置15，转化为二进制对应的是0111和1111，MSB不同说明多折回一次，111相同代表同一位置。
  • 剩下的其余位完全相等。


5.总体实现

    系统的总体框图如下：

1.顶层模块：

module AsyncFIFO
 #(parameter ASIZE = 4,    //地址位宽
   parameter DSIZE = 8)    //数据位宽
 (
    input  [DSIZE-1:0] wdata,
    input              winc, wclk, wrst_n,  //写请求信号，写时钟，写复位
    input              rinc, rclk, rrst_n,  //读请求信号，读时钟，读复位
    output [DSIZE-1:0] rdata,
    output             wfull,
    output             rempty
 );
wire [ASIZE-1:0] waddr, raddr;
wire [ASIZE:0]   wptr, rptr, wq2_rptr, rq2_wptr;        /************************************************************
* In order to perform FIFO full and FIFO empty tests using 
* this FIFO style, the read and write pointers must be
* passed to the opposite clock domain for pointer comparison
*************************************************************/
/*在检测“满”或“空”状态之前，需要将指针同步到其它时钟域时，使用格雷码，可以降低同步过程中亚稳态出现的概率*/
sync_r2w I1_sync_r2w(
    .wq2_rptr(wq2_rptr), 
    .rptr(rptr),
    .wclk(wclk), 
    .wrst_n(wrst_n));
sync_w2r I2_sync_w2r (
    .rq2_wptr(rq2_wptr), 
    .wptr(wptr),
    .rclk(rclk), 
    .rrst_n(rrst_n));
/*
*  DualRAM 
*/
DualRAM #(DSIZE, ASIZE) I3_DualRAM(
    .rdata(rdata), 
    .wdata(wdata),
    .waddr(waddr), 
    .raddr(raddr),
    .wclken(winc), 
    .wclk(wclk));
    
/*
*  空、满比较逻辑
*/
rptr_empty #(ASIZE) I4_rptr_empty(
    .rempty(rempty),
    .raddr(raddr),
    .rptr(rptr), 
    .rq2_wptr(rq2_wptr),
    .rinc(rinc), 
    .rclk(rclk),
    .rrst_n(rrst_n));
wptr_full #(ASIZE) I5_wptr_full(
    .wfull(wfull), 
    .waddr(waddr),
    .wptr(wptr), 
    .wq2_rptr(wq2_rptr),
    .winc(winc), 
    .wclk(wclk),
    .wrst_n(wrst_n));
endmodule

2 .DualRAM模块

module DualRAM
#(
    parameter DATA_SIZE = 8,   // 数据位宽
    parameter ADDR_SIZE = 4   // 地址位宽
)
(
    input                       wclken,wclk,
    input      [ADDR_SIZE-1:0]  raddr,     //RAM read address
    input      [ADDR_SIZE-1:0]  waddr,     //RAM write address
    input      [DATA_SIZE-1:0]  wdata,    //data input
    output     [DATA_SIZE-1:0]  rdata      //data output
);    
localparam RAM_DEPTH = 1 << ADDR_SIZE;   //RAM深度 = 2^ADDR_WIDTH
        reg [DATA_SIZE-1:0] Mem[RAM_DEPTH-1:0];
        always@(posedge wclk)
begin
     if(wclken)
         Mem[waddr] <= wdata;
end
assign rdata =  Mem[raddr];
endmodule


3.同步模块

module sync_r2w 
#(parameter ADDRSIZE = 4)
(
    output reg [ADDRSIZE:0] wq2_rptr,
    input      [ADDRSIZE:0] rptr,
    input                       wclk, wrst_n
);
reg [ADDRSIZE:0] wq1_rptr;
always @(posedge wclk or negedge wrst_n)
    if (!wrst_n) 
        {wq2_rptr,wq1_rptr} <= 0;
    else 
        {wq2_rptr,wq1_rptr} <= {wq1_rptr,rptr};
endmodule


4)同步模块2

module sync_w2r 
#(parameter ADDRSIZE = 4)
(
    output reg  [ADDRSIZE:0] rq2_wptr,
    input         [ADDRSIZE:0] wptr,
    input         rclk, rrst_n
);        reg [ADDRSIZE:0] rq1_wptr;
always @(posedge rclk or negedge rrst_n)
    if (!rrst_n)
        {rq2_wptr,rq1_wptr} <= 0;
    else 
        {rq2_wptr,rq1_wptr} <= {rq1_wptr,wptr};
endmodule

5)空判断逻辑

module rptr_empty 
#(parameter ADDRSIZE = 4)
(
    output reg rempty,
    output     [ADDRSIZE-1:0] raddr,
    output reg [ADDRSIZE :0]  rptr,
    input       [ADDRSIZE :0] rq2_wptr,
    input       rinc, rclk, rrst_n);


reg  [ADDRSIZE:0] rbin;
wire [ADDRSIZE:0] rgraynext, rbinnext;
wire  rempty_val;
//-------------------
// GRAYSTYLE2 pointer: gray码读地址指针
//-------------------
always @(posedge rclk or negedge rrst_n)
    if (!rrst_n) 
        begin 
            rbin <= 0;
            rptr <= 0;
        end
    else
        begin
            rbin <= rbinnext ; 
            rptr <= rgraynext;
        end
// gray码计数逻辑
assign rbinnext = !rempty ? (rbin + rinc) : rbin;
assign rgraynext = (rbinnext>>1) ^ rbinnext;      //二进制到gray码的转换
        assign raddr = rbin[ADDRSIZE-1:0];
//---------------------------------------------------------------
// FIFO empty when the next rptr == synchronized wptr or on reset
//---------------------------------------------------------------
/*
*   读指针是一个n位的gray码计数器，比FIFO寻址所需的位宽大一位
*   当读指针和同步过来的写指针完全相等时(包括MSB)，说明二者折回次数一致,FIFO为空
*     
*/
assign rempty_val = (rgraynext == rq2_wptr);
        always @(posedge rclk or negedge rrst_n)
if (!rrst_n) 
    rempty <= 1'b1;
else 
    rempty <= rempty_val;
endmodule

6)满判断逻辑

module wptr_full 
#(
    parameter ADDRSIZE = 4
)
(
    output reg                wfull,
    output     [ADDRSIZE-1:0] waddr,
    output reg [ADDRSIZE :0]  wptr,
    input      [ADDRSIZE :0]  wq2_rptr,
    input                     winc, wclk, wrst_n);        

reg  [ADDRSIZE:0] wbin;
wire [ADDRSIZE:0] wgraynext, wbinnext;
wire wfull_val;
// GRAYSTYLE2 pointer
always @(posedge wclk or negedge wrst_n)
    if (!wrst_n) 
    begin
        wbin <= 0;
        wptr <= 0;
    end
    else 
    begin
        wbin <= wbinnext;
         wptr <= wgraynext;
    end
//gray 码计数逻辑    
assign wbinnext  = !wfull ? wbin + winc : wbin;
assign wgraynext = (wbinnext>>1) ^ wbinnext;
        assign waddr = wbin[ADDRSIZE-1:0];
        /*由于满标志在写时钟域产生，因此比较安全的做法是将读指针同步到写时钟域*/
/**/
//------------------------------------------------------------------
// Simplified version of the three necessary full-tests:
// assign wfull_val=((wgnext[ADDRSIZE] !=wq2_rptr[ADDRSIZE] ) &&
// (wgnext[ADDRSIZE-1] !=wq2_rptr[ADDRSIZE-1]) &&
// (wgnext[ADDRSIZE-2:0]==wq2_rptr[ADDRSIZE-2:0]));
//------------------------------------------------------------------
assign wfull_val = (wgraynext=={~wq2_rptr[ADDRSIZE:ADDRSIZE-1],
                    wq2_rptr[ADDRSIZE-2:0]});
always @(posedge wclk or negedge wrst_n)
if (!wrst_n) 
    wfull <= 1'b0;
else 
    wfull <= wfull_val;
endmodule
本文转自：http://www.cnblogs.com/BitArt/archive/2013/04/10/3010073.html

明天20度
关注
专栏目录
FPGA上实现fifo
08-02
在fpga中实现fifo，配合数码管显示，仅供学习参考
异步FIFO的FPGA实现
Ant's home
04-27 1804
本文大部分内容来自Clifford E. Cummings的《Simulation and Synthesis Techniques for Asynchronous FIFO Design》，同时加上一些自己的一些理解，有兴趣的朋友可以阅读原文。 一、FIFO简介 　　FIFO是英文First In First Out 的缩写，是一种先进先出的数据缓存器，它与普通存储器的区别是没有外部读写地
FPGA开发——使用verilog实现异步FIFO
最新发布
weixin_63553972的博客
08-26 1725
1、FIFO的分类FIFOFirst In First Out）先进先出存储器。根据接入的时钟信号，可以分为同步FIFO和异步FIFO。FIFO底层是基于双口RAM，同步FIFO的读写时钟一致，异步FIFO 读时钟和写时钟不同。作用：
FIFO的FPGA实现
热门推荐
hisense20112784的博客
10-22 1万+
FIFO队列是一种数据缓冲器，用于数据的缓存。他是一种先入先出的存储器，即最先写入的数据，最先读。FIFO的参数有数据深度和数据宽度。数据宽度是指存储数据的宽度。深度是指存储器可以存储多少个数据。 FIFO队列有两个标志位。一个满和一个空标志位。分别表示FIFO是数据写满，还是数据读空。在数据写满状态下，数据写入是不允许的，因此在这个状态下，写入的数据无效。而数据读空状态下，数据读取是不允许的，
FPGA实现FIFO结构
01-07
该程序是基于quartus FPGA开发板的模拟FIFO程序； 4个拨码开关为输入数据端口，两个独立按键控制读写操作，4个led灯表示当前FIFO的输出；两个led灯表示FIFO的”写满“”读空“两种状态；FIFO大小为16； 按下”写“按键时，系统将拨码开关当前的状态写入FIFO，若写满了16个数，”写满“的led灯亮；按下”读“按键时，系统将最先写入FIFO的值读出，用4个led灯表示，若已经将所有值读出，则“读空”led灯亮；
FPGA——FIFO
a17377547725的博客
10-20 2989
FPGA——FIFO
异步fifo verilog代码.rar_fifo verilog 实现_fifo的读写_异步FIFO
09-15
本资源提供了一种异步FIFO的Verilog代码实现，适用于处理不同时钟域的数据交互问题。理解并掌握异步FIFO的设计原理和Verilog实现方法对于数字系统设计者至关重要。 异步FIFO的核心挑战在于如何处理两个不同时钟域...
fifo.rar_fifo verilog_异步FIFO_异步FIFO verilog_异步fifo verilog
09-20
"fifo.rar_fifo verilog_异步FIFO_异步FIFO verilog_异步fifo verilog"这个标题暗示了我们正在讨论的是用Verilog实现的异步FIFO。 异步FIFO是指在读写端口之间存在不同的时钟域，它们各自由独立的时钟控制，这种...
异步FIFO，Verilog源码
10-31
### 异步FIFO及其Verilog实现 #### 1. FIFO的基本概念 FIFO（First In First Out，先进先出）是一种数据缓存技术，主要用于处理数据流中的数据缓冲问题。与传统存储器不同，FIFO没有外部读写地址线，这意味着数据...
fifo.rar_fifo_异步 fifo_异步FIFO_异步FIFO verilog
09-24
在本项目“fifo.rar_fifo_异步_fifo_异步FIFO_异步FIFO verilog”中，重点是使用Verilog硬件描述语言实现了一个异步FIFO。 Verilog是一种广泛使用的硬件描述语言，用于数字逻辑系统的建模、设计和仿真。在异步FIFO...
fifo.zip_metastable verilog_异步FIFO_异步FIFO verilog_异步fifo verilo
09-24
在这个压缩包中，"fifo.zip"包含了一个名为"fifo.v"的Verilog代码文件，用于实现一个异步FIFO。Verilog是一种硬件描述语言，广泛应用于数字电路设计和验证。 异步FIFO的关键挑战在于解决两个独立时钟域之间的数据...
FPGA进行FIFO缓存
04-24
FPGA实现FIFO缓存，对数据进行缓存
FPGA FIFO 实现关键代码
03-18
prj为工程文件存放目录 rtl为verilog可综合代码 img为设计相关图片存放目录（主要为了方便后期写文档） doc为设计相关文档存放目录 testbench为对应的testbench存放目录 prj文件夹下的ip文件夹存放quartus ii中生成的ip核文件
异步FIFO结构
02-08
异步FIFO结构
试题: 打印格雷码
二斗墨汁
10-04 1474
好久没做算法题了，来一个   格雷码 - 概念(百度百科)： 在一组数的编码中，若任意两个相邻的代码只有一位二进制数不同，则称这种编码为格雷码（Gray Code），另外由于最大数与最小数之间也仅一位数不同，即“首尾相连”，因此又称循环码或反射码。在数字系统中，常要求代码按一定顺序变化。例如，按自然数递增计数，若采用8421码，则数0111变到1000时四位均要变化，而在实际电路中，4位的变
FPGA通用FIFO设计
xiebo0973的博客
02-26 1020
本文给出的fifo具有通用性，适用于各行各业，各种场景。其关键点在于如何实现输入输出位宽不一致，如何处理深度不是2的幂的情况，实现溢出警告处理，数据指针功能，first word full through功能。
基于FPGA的FIFO实现,包含testbench,不使用IP核
FPGA/MATLAB学习教程/源码/项目合作开发
07-10 957
基于FPGA的First-In-First-Out（FIFO）队列实现是数字设计中的一个常见任务，特别是在数据流管理和跨时钟域数据传输中。FIFO作为一个缓冲器，能够有效地管理数据流的速率匹配问题，避免数据丢失或过载。在不使用IP核的情况下，使用Verilog HDL手动设计FIFO，可以深入理解其工作原理并进行定制化设计。下面将详细介绍FIFO的工作原理，并展示如何使用Verilog语言实现一个简单的同步FIFO。
异步FIFO结构及FPGA设计
03-30 2675
http://www.pld.com.cn/application/a82.htm摘要：首先介绍异步FIFO的概念、应用及其结构，然后分析实现异步FIFO的难点问题及其解决办法；在传统设计的基础上提出一种新颖的电路结构并对其进行综合仿真和FPGA实现。 关键词：异步电路 FIFO 亚稳态 格雷码1 异步FIFO介绍在现代的集成电路芯片中，随着设计规模的不断扩大，一个系统中往往含有数
异步fifo verilog实现
07-28
异步FIFO的Verilog实现可以通过使用双时钟域同步器来实现。在Verilog代码中，需要定义FIFO的输入和输出接口，以及内部的存储器和控制逻辑。 首先，定义FIFO的输入和输出接口，包括数据输入端口、数据输出端口、写使能信号和读使能信号等。这些接口可以根据具体需求进行定义。 接下来，使用双时钟域同步器将异步的读写操作转换为同步操作。在写操作时，将写入的数据和写使能信号通过同步器同步到写时钟域，并将数据存储到FIFO的存储器中。在读操作时，将读使能信号通过同步器同步到读时钟域，并从FIFO的存储器中读取数据。 同时，需要实现FIFO的控制逻辑，包括判断FIFO是否为空、是否已满以及读写指针的更新等。根据引用\[1\]中提到的异步FIFO的特性，需要考虑读写地址的比较和空状态指示信号的延时等问题。 最后，根据引用\[2\]和引用\[3\]中提到的FIFO的工作流程和保守性原则，可以在Verilog代码中实现相应的逻辑。 需要注意的是，异步FIFO的Verilog实现可能会有一定的性能损失，但可以保证FIFO的正确性和稳定性。具体的实现细节可以根据具体需求和设计要求进行调整和优化。 #### 引用[.reference_title] - *1* *2* [异步FIFO设计（Verilog）](https://blog.csdn.net/qq_21842097/article/details/118307227)[target="_blank" data-report-click={"spm":"1018.2226.3001.9630","extra":{"utm_source":"vip_chatgpt_common_search_pc_result","utm_medium":"distribute.pc_search_result.none-task-cask-2~all~insert_cask~default-1-null.142^v91^insertT0,239^v3^insert_chatgpt"}} ] [.reference_item] - *3* [异步FIFO_Verilog实现](https://blog.csdn.net/qq_40147893/article/details/117000168)[target="_blank" data-report-click={"spm":"1018.2226.3001.9630","extra":{"utm_source":"vip_chatgpt_common_search_pc_result","utm_medium":"distribute.pc_search_result.none-task-cask-2~all~insert_cask~default-1-null.142^v91^insertT0,239^v3^insert_chatgpt"}} ] [.reference_item] [ .reference_list ]
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值