uvm-1.2 examples —— 2.12 phase - timeout

最新推荐文章于 2024-03-26 14:36:52 发布
最新推荐文章于 2024-03-26 14:36:52 发布
阅读量1.1k 收藏 7
点赞数
分类专栏： uvm-1.2 examples
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/hh199203/article/details/115637590
版权

2.12 phase - timeout

文章目录

前言

本文以uvm-1.2/examples/simple/phases/timeout为例，通过代码了解UVM中的phases机制。通过这个例子可以基本了解以下知识点：

  • phase的“举手”和“放手”机制
  • phase运行的时间控制方法

一、基本介绍

在UVM中，执行仿真通过phase控制，phase的分类和执行顺序在《2.11 phase - basic》节中有具体介绍。在每个phase内部，则是通过raise_objection()和drop_objection()这对函数来控制，即我们常说的“举手”和“放手”，这两个函数通常成对出现，这一点和《2.10 objections》节类似，但是这里是通过phase来进行控制。

二、代码分析

这个测试用例一共有三个文件，包括：test.sv、tb_env.svh和tb_timer.svh。下面自顶向下分别介绍这三个文件的代码。

2.1 test.sv

program test;

import uvm_pkg::*;
`include "uvm_macros.svh"
`include "tb_timer.svh"
`include "tb_env.svh"

tb_env env;


class test extends uvm_test;
   `uvm_component_utils(test)

   function new(string name, uvm_component parent = null);
      super.new(name, parent);
   endfunction

   task pre_main_phase(uvm_phase phase);
      phase.raise_objection(this);
      #100;
      phase.drop_objection(this);
   endtask
   
   task main_phase(uvm_phase phase);
      phase.raise_objection(this);
      // Will cause a time-out
      // because we forgot to drop the objection
      //phase.drop_objection(this);
   endtask
   
   task shutdown_phase(uvm_phase phase);
      phase.raise_objection(this);
      #100;
      phase.drop_objection(this);
   endtask
endclass


initial
begin
   env = new("env");
   run_test("test");
end

endprogram

第1行，通过一个program关键字，将测试代码打成一个test包；
第3到6行，导入UVM包，以及另外tb_env.svh和tb_timer.svh两个文件；
第8行，声明tb_env，tb_env的实现位于tb_env.svh文件中；
第11到36行，test测试用例的实现，分别在pre_main_phase、main_phase和shutdown_phase中，通过phase.raise_objection(this)加入仿真时间，但是在main_phase中估计丢掉了；phase.drop_objection(this)函数，让其仿真无法结束；
第39到43行，实例化env并启动test的仿真。

2.2 tb_env.svh

class tb_env extends uvm_env;
   `uvm_component_utils(tb_env)

   function new(string name, uvm_component parent = null);
      super.new(name, parent);
   endfunction

   function void build_phase(uvm_phase phase);
      uvm_config_db#(time)::set(null, "global_timer.*",    "timeout", 1000);
      uvm_config_db#(time)::set(null, "global_timer.main", "timeout", 3000);
      uvm_config_db#(time)::set(null, "global_timer.run",  "timeout", 0);
   endfunction

   
   task reset_phase(uvm_phase phase);
      phase.raise_objection(this);
      #20;
      phase.drop_objection(this);
   endtask
   
   task configure_phase(uvm_phase phase);
      phase.raise_objection(this);
      #200;
      phase.drop_objection(this);
   endtask
   
   task main_phase(uvm_phase phase);
      phase.raise_objection(this);
      #1000;
      phase.drop_objection(this);
   endtask

   task shutdown_phase(uvm_phase phase);
      phase.raise_objection(this);
      #10;
      phase.drop_objection(this);
   endtask
endclass

这个文件是tb_env的具体实现。
其中，值得注意的是：
第8到12行，在build_phase中通过config_db机制，配置了global_timer中各个phase机制的timeout参数，global_timer的实现在tb_timer.svh中；
第15到37行，分别在reset_phase、configure_phase、main_phase、shutdown_phase中，通过phase.raise_objection(this)和phase.drop_objection(this)这对函数，加入了仿真时间。

2.3 tb_timer.svh

//
// Generic phase timer
//
// All time-out values are interprted in ns
//
// To set time-out values:
//
// - For one phase:
//
//   uvm_config_db#(time)::set(null, "global_timer.main", "timeout", 100);
//
// - For multiple phases:
//
//   uvm_config_db#(time)::set(null, "global_timer.pre*", "timeout", 100);
//

class tb_timer extends uvm_component;

   `uvm_component_utils(tb_timer)

   local static tb_timer m_global = new("global_timer", null);

   function new(string name, uvm_component parent = null);
      super.new(name, parent);
   endfunction
      
   task run_phase(uvm_phase phase);
      time t;
      if (uvm_config_db#(time)::get(this, "run", "timeout", t) &&
          t > 0) begin
         #(t * 1ns);
         `uvm_fatal("TIMEOUT", "Time-out expired in run phase")
      end
   endtask

   task pre_reset_phase(uvm_phase phase);
      time t;
      if (uvm_config_db#(time)::get(this, "pre_reset", "timeout", t) &&
          t > 0) begin
         #(t * 1ns);
         `uvm_fatal("TIMEOUT", "Time-out expired in pre_reset phase")
      end
   endtask

   task reset_phase(uvm_phase phase);
      time t;
      if (uvm_config_db#(time)::get(this, "reset", "timeout", t) &&
          t > 0) begin
         #(t * 1ns);
         `uvm_fatal("TIMEOUT", "Time-out expired in reset phase")
      end
   endtask

   task post_reset_phase(uvm_phase phase);
      time t;
      if (uvm_config_db#(time)::get(this, "post_reset", "timeout", t) &&
          t > 0) begin
         #(t * 1ns);
         `uvm_fatal("TIMEOUT", "Time-out expired in post_reset phase")
      end
   endtask

   task pre_configure_phase(uvm_phase phase);
      time t;
      if (uvm_config_db#(time)::get(this, "pre_configure", "timeout", t) &&
          t > 0) begin
         #(t * 1ns);
         `uvm_fatal("TIMEOUT", "Time-out expired in pre_configure phase")
      end
   endtask

   task configure_phase(uvm_phase phase);
      time t;
      if (uvm_config_db#(time)::get(this, "configure", "timeout", t) &&
          t > 0) begin
         #(t * 1ns);
         `uvm_fatal("TIMEOUT", "Time-out expired in configure phase")
      end
   endtask

   task post_configure_phase(uvm_phase phase);
      time t;
      if (uvm_config_db#(time)::get(this, "post_configure", "timeout", t) &&
          t > 0) begin
         #(t * 1ns);
         `uvm_fatal("TIMEOUT", "Time-out expired in post_configure phase")
      end
   endtask
   
   task pre_main_phase(uvm_phase phase);
      time t;
      if (uvm_config_db#(time)::get(this, "pre_main", "timeout", t) &&
          t > 0) begin
         #(t * 1ns);
         `uvm_fatal("TIMEOUT", "Time-out expired in pre_main phase")
      end
   endtask

   task main_phase(uvm_phase phase);
      time t;
      if (uvm_config_db#(time)::get(this, "main", "timeout", t) &&
          t > 0) begin
         #(t * 1ns);
         `uvm_fatal("TIMEOUT", "Time-out expired in main phase")
      end
   endtask

   task post_main_phase(uvm_phase phase);
      time t;
      if (uvm_config_db#(time)::get(this, "post_main", "timeout", t) &&
          t > 0) begin
         #(t * 1ns);
         `uvm_fatal("TIMEOUT", "Time-out expired in post_main phase")
      end
   endtask

   task pre_shutdown_phase(uvm_phase phase);
      time t;
      if (uvm_config_db#(time)::get(this, "pre_shutdown", "timeout", t) &&
          t > 0) begin
         #(t * 1ns);
         `uvm_fatal("TIMEOUT", "Time-out expired in pre_shutdown phase")
      end
   endtask

   task shutdown_phase(uvm_phase phase);
      time t;
      if (uvm_config_db#(time)::get(this, "shutdown", "timeout", t) &&
          t > 0) begin
         #(t * 1ns);
         `uvm_fatal("TIMEOUT", "Time-out expired in shutdown phase")
      end
   endtask

   task post_shutdown_phase(uvm_phase phase);
      time t;
      if (uvm_config_db#(time)::get(this, "post_shutdown", "timeout", t) &&
          t > 0) begin
         #(t * 1ns);
         `uvm_fatal("TIMEOUT", "Time-out expired in post_shutdown phase")
      end
   endtask

endclass

这个文件主要是tb_timer 的具体实现。
其中，值得注意的是：
第19行，将tb_timer注册到UVM的工厂机制中，这是为什么在env中没有例化m_global，却能够传递参数过来的原因；
第27到142行，代码实现上基本上都类似，意思是在每个phase中通过config_db机制获取到一个timeout的变量，并检测改phase执行的时间，是否超过了timeout的值，如果phase提前结束，则不会打印uvm_fatal相关的信息，否则打印在哪个phase超时的fatal信息。

2.4 仿真结果

UVM_INFO @ 0: reporter [RNTST] Running test test...
UVM_FATAL tb_timer.svh(126) @ 3320: global_timer [TIMEOUT] Time-out expired in main phase
UVM_INFO ../../../../src/base/uvm_report_server.svh(847) @ 3320: reporter [UVM/REPORT/SERVER] 
--- UVM Report Summary ---

** Report counts by severity
UVM_INFO :    2
UVM_WARNING :    0
UVM_ERROR :    0
UVM_FATAL :    1
** Report counts by id
[RNTST]     1
[TIMEOUT]     1
[UVM/RELNOTES]     1

$finish called from file "../../../../src/base/uvm_root.svh", line 135.
$finish at simulation time                 3320
           V C S   S i m u l a t i o n   R e p o r t 
Time: 3320 ns

通过仿真结果，可以看到打印了一个UVM_FATAL的信息，提示main phase执行超时，这是因为在test.sv文件的main phase中，我们故意丢了一个phase.drop_objection(this)函数。

另外，值得注意的是，仿真结束的时间是3320ns，这个时间是tb_env中reset_phase的20ns，加上tb_env中configure_phase的200ns，加上test中pre_main_phase的100ns，加上tb_env中build_phase给global_timer.main配置的3000ns，一共是20+200+100+3000=3320ns。

总结

通过这个测试用例，可以比较直观的看到，在phase内部，我们通过phase.raise_objection(this)和phase.drop_objection(this)这对函数来控制仿真执行的时间；另外，通过tb_timer 这个单独的类，来控制各个phase执行的时间，一旦超时则报UVM FATAL的错误信息。

hh199203
关注
  • 0
    点赞
  • 踩
  • 7
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
uvm-1.2_hidden871_universal_源码_uvm1.2_UVM_
10-03
Accellera Universal Verification Methodology1.2源代码
uvm-1.2源代码与应用实例
05-28
uvm-1.2源代码与官方实例
UVM验证中“仿真时间”的设置与处理
最新发布
qq_25749155的博客
03-26 921
对timescale、timeunit、timeprecision以及timeformat的使用、优先级、作用域进行介绍
uvm-1.2.rar
11-12
1小时玩转数字电路.rar AHB-SRAMC和FIFO的设计与验证.rar clock skew.rar IC攻城狮求职宝典.rar linux basic.rar Linux EDA虚拟机 - 个人学习IC设计.rar Perl语言在芯片设计中的应用.rar SoC芯片设计技能专题.rar SystemVerilog Assertion断言理论与实践.rar SystemVerilog_Assertions_应用指南-源代码.rar uvm-1.2.rar VCS_labs.rar Verdi 基础教程.rar Verilog RTL 编码实践.rar [Cadence.IC设计.全资料教
ces_uvm-1.2_2016.06.tar源码.zip
09-29
ces_uvm-1.2_2016.06.tar源码.zip
uvm-python:UVM 1.2端口到Python
04-15
适用于Python的UVM库 这是将SystemVerilog（SV）通用验证方法（UVM）1.2移植到Python和cocotb的端口。 到目前为止，仅使用Icarus Verilog（iverilog）来测试代码，但计划也将Verilator包括在回归中。 请参阅文档以获取更多详细信息： 。 何苦？ 任何开源/免费工具目前都不支持SystemVerilog UVM。 cocotb提供了与任何模拟器（免费/专有）进行交互的出色解决方案，因此测试平台也可以用Python编写。 uvm-python尝试提供类似于原始SV版本的API。 这意味着许多UVM验证技能可以很容易地从SV转移到Python。 如果要移植大量SV代码以使用uvm-python ，则可以尝试使用脚本bin/sv2py.pl作为第一步。 文献资料 该文档可在中的上readthedocs.io 。 安装 您可以将uv
UVM-1.2中PH_TIMEOUT错误的意义以及修改
Zoeeeyy的博客
06-06 2243
PH_TIMEOUT的源码，原因，解决方式
UVM设置超时退出timeout
hh199203的博客
08-24 7239
文章目录前言一、在仿真选项中设置二、在仿真环境中设置总结 前言 在uvm搭建的仿真环境，仿真过程中，有可能会出现仿真挂死的现象，导致仿真会一直卡在某个地方，无法自动退出。uvm提供了仿真超时退出的功能，本文主要介绍，如何在uvm环境中设置超时退出。 一、在仿真选项中设置 uvm中提供了**+UVM_TIMEOUT=“time, override”**这个选项，用于控制仿真超时退出。 time是超时的时间；override的选项为YES和NO，用于控制是否覆盖环境中设置的超时时间，UVM中默认的超时时间
UVM中超时退出set_timeout函数
Alfred的博客
07-10 3203
在UVM中通过uvm_root的set_timeout函数可以设置超时时间：
UVM set_timeout值与实际值不符，引发的timescale思考
munfxy的博客
02-03 1294
在仿真时，有时候会遇到仿真结束时间与"设置值不符的现象"。 比如通过uvm_root::set_timeout(1us)； 结果uvm在仿真进行到1ms的时候，才会自动timeout结束。造成该现象的原因是sv中虚假的time类型以及不同仿真单元间的timescale值不同。
UVM实战笔记（五）
weixin_44590534的博客
10-30 1622
1.phase机制 2.objection机制 3.domain概念
apb的uvm验证vip
04-11
APB的UVM验证VIP，非常实用。 初学UVM的可以作为模板参考学习，也可以直接用到项目中作为验证的环境！
UVM寄存器模型案例
MGoop的博客
10-10 905
UVM寄存器模型示例
(UVM验证学习21) apb timer的参考模型和覆盖率模型实现
fenggang2333的博客
03-08 1196
思路也是首先实现父类timer_subscriber,实现计分板和覆盖率模型的公用部分逻辑。
apbtimer模块验证学习笔记
weixin_41975611的博客
04-16 1369
本文仅个人学习过程笔记，如有疏漏，望指正或补充。apbtimer模块是一个以APB协议通信的timer减计数器。其内部含有多个可配置寄存器（本项目中未使用到的寄存器不做解释）：CTRL：控制寄存器。CTRL[0]：timer使能，CTRL[1]：外部输入作为使能端，CTRL[2]：外部输入作为clock端，CTRL[3]：timer中断使能。VALUE：timer减计数器的current value，写入时计数器值改变为写入值。
【UVM基础】仿真时间与运行时间
悟已往之不谏 知来者之可追
02-07 3592
仿真时间与运行时间区别
UVM学习小结
StephenX9760的博客
09-04 2373
UVM学习 1、UVM是一种用于验证数字设计标准化的简单方法，其优势是 第一种自动化方法和第二种自动化类库的集合； 贯穿于验证平台的可重用性； 通用的验证平台开发； 供应商和模拟器独立； 高智能的验证平台（即从预先设计的覆盖计划中产生合法的激励）； 即插即用的验证IP； 支持CDV（覆盖率驱动）验证； 支持CRV（受限随机）验证； 支持寄存器模型； UVM在Accelerate System Initialive 下标准化； 2、uvm_component与uvm_object之间有什么区别？ uvm_co
UVM实战 卷I学习笔记17——UVM命令行参数汇总
weixin_41979380的博客
01-14 2351
目录打印出所有的命令行参数指定运行测试用例的名称在命令行中设置冗余度阈值设置打印信息的不同行为重载冗余度设置全局的超时时间ERROR到达一定数量退出仿真打开phase的调试功能打开objection的调试功能打开config_db的调试功能打开resource_db的调试功能使用factory机制重载某个实例类型重载在命令行中使用set_config 命令行参数指的是运行时的命令行参数，而不是编译时的命令行参数。 打印出所有的命令行参数 <sim command> +UVM_DUMP_CMD
uvm1.2 支持 starting_phase 吗
06-13
Starting_phase 是 UVM 1.1 版本中引入的一个特性，在 UVM 1.2 中已经不再支持。在 UVM 1.2 中，可以使用 UVM_PHASE_SCHEDULE 中的 PHASE_SCHEDULED 代替 starting_phase。请注意，UVM 1.2 是 UVM 1.1 的升级版本，因此可以在 UVM 1.2 中使用 UVM 1.1 的代码，但是建议尽量使用 UVM 1.2 提供的新特性和改进。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值