学以致用——使用VBA向手动维护的数据表中自动添加时间戳（Add timestamp with VBA）

需求：

为了分析CSDN博客的统计数据，需要手动录入4条数据：篇数、访问总量、积分、排名。其余的各列：数据录入时间、星期、访问增量、日均访问增量、日篇均访问增量、排名提升位数、日均排名提升位数、篇数增加量、日均篇数增加量、积分增加量、日均积分增加量均可以通过固定的公式，基于上述4条数据计算而得。

目前，需要手动完成以下动作：

1. 手动添加当前日期 （通常只填写年月日，而忽略了时分秒，严格而言，并不是时间戳）

2. 手动复制公式到下一行（选择公式，拖动到下一行）

虽说手动作业并不多，但是毕竟是手动啊，通过使用VBA，完全可以将这两步操作给自动化掉，并且时间戳更为完整（增加了时分秒）。

解决方案：

在工作表中定义worksheet的change事件，代码如下：

Private Sub Worksheet_Change(ByVal Target As Range)

    With Target
        If .Count = 1 Then  '仅在单个单元格内容变化时记录时间戳
            If .Column >= 1 And .Column <= 4 Then   '仅在前4列中任一一列中输入内容时记录时间戳
                Application.EnableEvents = False
                If .Offset(0, 4 - .Column + 1).Value = "" Then      '仅在新建行时记录时间戳（避免更新单元格时覆盖之前的时间戳）
                    .Offset(0, 4 - .Column + 1).Value = Now         '将当前系统时间记录写入单元格
                End If
                
                If .Column = 4 Then     '仅当最后一列输入完毕时复制公式
                    '将上一行的公式复制到新创建的行
                    .Offset(-1, 4 - .Column + 2).Resize(1, 10).Select
                    Selection.Copy
                    .Offset(0, 4 - .Column + 2).Select
                    Selection.PasteSpecial Paste:=xlPasteFormulas, Operation:=xlNone, _
                        SkipBlanks:=False, Transpose:=False
                    UsedRange.Borders.LineStyle = xlContinuous
                End If
                Application.EnableEvents = True
            End If
        End If
    End With
End Sub

学以致用，挺好！