使用Visual Basic 6.0开发程序的一些方法技巧收集之三：重启计算机

    有时候，特别是像安装更新时，因为某些文件正在被使用，致使安装完更新时需要重启计算机才能完成。通常我们希望在检测到需要重启计算机时给用户一个提示并让用户选择是否立即重启计算机。在VB中，可以通过API来完成重启计算机的操作，方法有很多，这里介绍两种方法。

1、利用命令行执行重启计算机操作，可以使用Shell函数来执行操作，具体如下所示：
Shell "cmd.exe /c shutdown /r"
使用这种方式，通常要求你的程序要有对计算机足够的操作权限。那么，如果权限不够怎么办？不妨可以试试第二种方法。

2、通过提高权限来重启计算机
Option Explicit

Private Const EWX_LOGOFF = 0
Private Const EWX_SHUTDOWN = 1
Private Const EWX_REBOOT = 2
Private Const EWX_FORCE = 4
Private Const TOKEN_ADJUST_PRIVILEGES = &H20
Private Const TOKEN_QUERY = &H8
Private Const SE_PRIVILEGE_ENABLED = &H2
Private Const ANYSIZE_ARRAY = 1
Private Const VER_PLATFORM_WIN32_NT = 2
Type OSVERSIONINFO
    dwOSVersionInfoSize   As Long
    dwMajorVersion   As Long
    dwMinorVersion   As Long
    dwBuildNumber   As Long
    dwPlatformId   As Long
    szCSDVersion   As String * 128
End Type
Type LUID
    LowPart   As Long
    HighPart   As Long
End Type
Type LUID_AND_ATTRIBUTES
    pLuid   As LUID
    Attributes   As Long
End Type
Type TOKEN_PRIVILEGES
    PrivilegeCount   As Long
    Privileges(ANYSIZE_ARRAY)   As LUID_AND_ATTRIBUTES
End Type

Private Declare Function GetCurrentProcess Lib "kernel32" () As Long
Private Declare Function OpenProcessToken Lib "advapi32" (ByVal ProcessHandle As Long, ByVal DesiredAccess As Long, TokenHandle As Long) As Long
Private Declare Function LookupPrivilegeValue Lib "advapi32" Alias "LookupPrivilegeValueA" (ByVal lpSystemName As String, ByVal lpName As String, lpLuid As LUID) As Long
Private Declare Function AdjustTokenPrivileges Lib "advapi32" (ByVal TokenHandle As Long, ByVal DisableAllPrivileges As Long, NewState As TOKEN_PRIVILEGES, ByVal BufferLength As Long, PreviousState As TOKEN_PRIVILEGES, ReturnLength As Long) As Long
Private Declare Function ExitWindowsEx Lib "user32" (ByVal uFlags As Long, ByVal dwReserved As Long) As Long
Private Declare Function GetVersionEx Lib "kernel32" Alias "GetVersionExA" (ByRef lpVersionInformation As OSVERSIONINFO) As Long
 
 
' **********************************************************************
' 函数名称：IsWinNT
' 功能描述：检测程序是否运行在Windows NT 操作系统环境下
' 输    入：无
' 返    回：Boolean
' **********************************************************************
Private Function IsWinNT() As Boolean
    Dim myOS As OSVERSIONINFO
    myOS.dwOSVersionInfoSize = Len(myOS)
    GetVersionEx myOS
    IsWinNT = (myOS.dwPlatformId = VER_PLATFORM_WIN32_NT)
End Function
 
 
' **********************************************************************
' 函数名称：EnableShutDown
' 功能描述：为当前应用程序设置关闭/重启/注销计算机的权限
' 输    入：无
' 返    回：无
' **********************************************************************
Private Sub EnableShutDown()
    Dim hProc     As Long
    Dim hToken     As Long
    Dim mLUID     As LUID
    Dim mPriv     As TOKEN_PRIVILEGES
    Dim mNewPriv     As TOKEN_PRIVILEGES
    hProc = GetCurrentProcess()
    OpenProcessToken hProc, TOKEN_ADJUST_PRIVILEGES + TOKEN_QUERY, hToken
    LookupPrivilegeValue "", "SeShutdownPrivilege", mLUID
    mPriv.PrivilegeCount = 1
    mPriv.Privileges(0).Attributes = SE_PRIVILEGE_ENABLED
    mPriv.Privileges(0).pLuid = mLUID
   
    AdjustTokenPrivileges hToken, False, mPriv, 4 + (12 * mPriv.PrivilegeCount), mNewPriv, 4 + (12 * mNewPriv.PrivilegeCount)
End Sub

' **********************************************************************
' 函数名称：RestartComputer
' 功能描述：重启计算机
' 输    入：Force As Boolean
' 返    回：Boolean
' **********************************************************************
Public Function RestartComputer(Force As Boolean) As Boolean
    Dim lngFlags As Long
    Dim lngRetval As Long
    Dim blnReturn As Boolean
   
    lngFlags = EWX_REBOOT
    If Force Then lngFlags = lngFlags + EWX_FORCE
    If IsWinNT Then EnableShutDown
    lngRetval = ExitWindowsEx(lngFlags, 0) ' 重启计算机
    If lngRetval = 0 Then
        blnReturn = False
    Else
        blnReturn = True
    End If
   
    RestartComputer = blnReturn
End Function