选课_ctsc1997_ssl1606_树形dp

Description

　　大学里实行学分。每门课程都有一定的学分，学生只要选修了这门课并考核通过就能获得相应的学分。学生最后的学分是他选修的各门课的学分的总和。

　　每个学生都要选择规定数量的课程。其中有些课程可以直接选修，有些课程需要一定的基础知识，必须在选了其它的一些课程的基础上才能选修。例如，《数据结构》必须在选修了《高级语言程序设计》之后才能选修。我们称《高级语言程序设计》是《数据结构》的先修课。每门课的直接先修课最多只有一门。两门课也可能存在相同的先修课。为便于表述每门课都有一个课号，课号依次为1，2，3，……。下面举例说明

 

　　上例中1是2的先修课，即如果要选修2，则1必定已被选过。同样，如果要选修3，那么1和2都一定已被选修过。

学生不可能学完大学所开设的所有课程，因此必须在入学时选定自己要学的课程。每个学生可选课程的总数是给定的。现在请你找出一种选课方案，使得你能得到学分最多，并且必须满足先修课优先的原则。假定课程之间不存在时间上的冲突。

 

Input

输入文件的第一行包括两个正整数M、N（中间用一个空格隔开）其中M表示待选课程总数（1≤M≤1000)，N表示学生可以选的课程总数（1≤N≤M)。

以下M行每行代表一门课，课号依次为1，2……M。每行有两个数（用一个空格隔开），第一个数为这门课的先修课的课号（若不存在先修课则该项为0），第二个数为这门课的学分。学分是不超过10的正整数。

 

Output

输出文件第一行只有一个数，即实际所选课程的学分总数。以下N行每行有一个数，表示学生所选课程的课号。

 

Sample Input

7   4

2   2

0   1

0   4

2   1

7   1

7   6

2   2

 

Sample Output

13

 

思路：

乍一看像是拓扑排序，仔细看看发现带权，再想想应该属于树形dp。但是原题建树得出的是一颗多叉树，甚至可能是森林，所以需要转成二叉树。戳这里戳这里戳这里

 

状态转移方程：

F[i,j]表示节点x取y门课得最高学分，则

F[i,j]＝max(f[i.l,k-1]+i.v+f[i.r,j-k]) k=0,1,..j

 

源代码/pas

type
binary=record
  l,r:longint;
end;
var
  n,m:longint;
  t:array[-1..100]of binary;
  w:array[-1..100]of longint;
  f:array[-1..100,-1..100]of longint;
function max(x,y:longint):longint;
begin
  max:=y;
  if x>y then
  max:=x;
end;
procedure init;
var
  i,j,x:longint;
  b:array[0..100]of longint;
begin
  readln(n,m);
  fillchar(b,sizeof(b),0);
  for i:=0 to n do
  with t[i] do
  begin
    l:=-1;
    r:=-1;
  end;
  for i:=1 to n do
  begin
    readln(x,w[i]);
    if b[x]=0 then
    t[x].l:=i
    else
    t[b[x]].r:=i;
    b[x]:=i;
  end;
  for i:=-1 to n do
  for j:=0 to m do
  if (i=-1)or(j=0) then
  f[i,j]:=0
  else
  f[i,j]:=-1;
end;
procedure dfs(i,j:Longint);
var
  k,max,temp:longint;
begin
  if f[i,j]>-1 then exit;
  dfs(t[i].r,j);
  max:=f[t[i].r,j];
  for k:=1 to j do
  begin
    dfs(t[i].l,k-1);
    dfs(t[i].r,j-k);
    temp:=f[t[i].l,k-1]+f[t[i].r,j-k]+w[i];
    if temp>max then max:=temp;
  end;
  f[i,j]:=max;
end;
begin
  init;
  dfs(t[0].l,m);
  writeln(f[t[0].l,m]);
end.