09 呼吸灯

已于 2024-07-28 17:37:09 修改
阅读量1.7k 收藏 22
点赞数 26
分类专栏： FPGA开发入门 文章标签： fpga开发
于 2024-02-25 10:54:09 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/lf282481431/article/details/136220782
版权
本文详细介绍了如何利用FPGA和PWM技术实现LED灯的呼吸效果，包括PWM信号的产生机制、占空比控制以及呼吸灯模块的设计。通过周期计数器和比较值调整，展示了如何通过外部占空比控制LED灯的亮度变化，模拟了整个系统的搭建和仿真过程。
摘要由CSDN通过智能技术生成

呼吸灯简介

呼吸灯实际展示的效果就是一个 LED 灯的亮度由亮到暗，再由暗到亮的变化过程，并且该过程是循环往复的，像呼吸一样那么有节奏。 呼吸灯通常是采用 PWM(Pulse Width Modulation，即脉冲宽度调制) 的方式实现，在 PWM 频率固定的情况下，通过调整其占空比来控制 LED 灯亮度的变化。
在固定周期的 PWM 信号下，如果其占空比为 0，则 LED 灯不亮；如果其占空比为100%，则 LED 灯最亮。将占空比从 0 到 100%，再从 100%到 0 不断变化，就可以实现 LED 灯的“呼吸”效果，PWM 占空比调节示意图如下所示：
在这里插入图片描述

PWM信号的产生

可以用1个周期计数器和1个比较值来控制 PWM 信号的产生，周期计数器进行周期计数，控制 PWM 的周期，在周期计数器计数过程中同时将计数值与比较值比较，当计数值小于比较值时输出低电平，否则输出高电平，此时通过调节比较值便可调节 PWM 占空比，调节周期计数器的最大计数值便可调节 PWM 的周期，PWM 信号产生原理如下图所示：
在这里插入图片描述

原理图

LED0 到 LED3 这 4 个发光二极管的阴极分别连到 S8050（NPN 三极管）的集电极上，阳极都与 3.3V 电压相连，三极管的基极分别与 FPGA 相连，这是由于 FPGA 的 IO 口的电压只有 1.5V，电压较低，所以此处连接三极管是为了起到放大电压的作用。这样就可以通过改变三极管的状态来控制 LED 的亮灭。当 FPGA 输出到为高电平时，三极管导通，LED 灯亮；当 FPGA 输出到为低电平时，三极管截止，LED 灯灭。
在这里插入图片描述
在这里插入图片描述
此实验中只用到了LED0

系统框图

系统框图如下，包括两部分，分别是产生PWM信号的PWM模块和控制PWM占空比的呼吸灯模块
在这里插入图片描述

编写代码

PWM信号生成模块

PWM信号生成模块包含一个周期计数器和一个比较值，比较值通过模块外部输入的占空比结合PWM周期转换得到（这里由呼吸灯模块进行占空比控制），模块代码如下：

`timescale 1ns / 1ns

module pwm_generate
(
	input sys_clk,							//系统时钟
	input sys_rst_n,						//系统复位，低电平有效

	input [31:0] period,					//PWM周期
	input [31:0] duty_cycle,				//PWM占空比

	output pwm_out							//输出的PWM信号
);

//PWM周期
wire [31:0] pwm_period;
//PWM比较值
wire [31:0] pwm_compare;
//周期计数器，用于控制PWM周期
reg [31:0] count;

//PWM周期，不能小于2
assign pwm_period = (period < 2) ? 2 : period;
//将PWM占空比转换为比较值
assign pwm_compare = (duty_cycle < pwm_period) ? (pwm_period - duty_cycle) : 0;

//周期计数器的值小于比较寄存器时输出低电平，否则输出高电平
assign pwm_out = (count < pwm_compare) ? 0 : 1;

//进行周期计数，用于控制PWM输出周期
always @(posedge sys_clk) begin
	if(!sys_rst_n)
		count <= 0;
	else if(count < (pwm_period - 1))
		count = count + 1;
	else
		count <= 0;
end

endmodule

PWM信号生成模块仿真激励代码

PWM信号生成模块仿真激励代码很简单，就是在周期产生时钟信号的同时调整PWM占空比即可，代码如下：

`timescale 1ns / 1ns	//仿真单位/仿真精度

module tb_pwm_generate();

reg sys_clk;					//时钟
reg sys_rst_n;					//复位
reg [31:0] duty_cycle;			//占空比
wire pwm_out;					//PWWM信号

initial begin
	sys_clk = 1'b0;
	sys_rst_n = 1'b0;
	duty_cycle = 0;
	#200
	sys_rst_n = 1'b1;

	//占空比为1
	#1000
	duty_cycle = 1;

	//占空比为2
	#1000
	duty_cycle = 2;

	//占空比为3
	#1000
	duty_cycle = 3;

	//占空比为4
	#1000
	duty_cycle = 4;

	//占空比为5
	#1000
	duty_cycle = 5;

	//占空比为6
	#1000
	duty_cycle = 6;

	//占空比为7
	#1000
	duty_cycle = 7;

	//占空比为8
	#1000
	duty_cycle = 8;

	//占空比为9
	#1000
	duty_cycle = 9;

	//占空比为10
	#1000
	duty_cycle = 10;
end

//产生时钟
always #10 sys_clk = ~sys_clk;

pwm_generate u_tb_pwm_generate_inst (
	.sys_clk(sys_clk),					//系统时钟
	.sys_rst_n(sys_rst_n),				//系统复位，低电平有效

	.period(10),						//PWM周期
	.duty_cycle(duty_cycle),			//PWM占空比

	.pwm_out(pwm_out)					//输出的PWM信号
);

endmodule

呼吸灯模块

呼吸灯模块用于向PWM模块输出一个占空比，内部包含以下几个部分：

  • 一个周期计数器，用于控制PWM占空比调节的间隔
  • 根据占空比调节方向调节占空比
  • 记录占空比调节次数
  • 当占空比连续递增（递减）到指定次数时说明占空比达到最大（最小），此时改变占空比调节方向标志
    完整的代码如下：
`timescale 1ns / 1ns

module breath_led #(
	parameter PWM_PERIOD = 100_000,				//pwm信号的周期
	parameter BREATH_PERIOD = 100_000_000,		//呼吸灯周期
	parameter BRIGHT_LEVEL = 100				//亮度等级
)
(
	input sys_clk,								//系统时钟
	input sys_rst_n,							//系统复位，低电平有效

	output reg [31:0] duty_cycle				//PWM占空比
);

//PWM占空比调节步进，分100个亮度等级进行占空比调节
localparam DUTY_CYCLE_STEP = PWM_PERIOD / BRIGHT_LEVEL;
//PWM占空比调节间隔，分100个亮度等级进行占空比调节
localparam STEP_INTERVAL = BREATH_PERIOD / BRIGHT_LEVEL;

//周期计数器，用于控制PWM占空比调节间隔
reg [31:0] period_count;
//占空比调节次数计数器，用于记录调节占空比的次数
reg [31:0] step_count;
//占空比调节方向控制，为0占空比加，为1占空比减
reg inc_dec_flag;

//进行周期计数，用于控制PWM占空比调节间隔
always @(posedge sys_clk) begin
	if(!sys_rst_n)
		period_count <= 0;
	else if(period_count < (STEP_INTERVAL - 1))
		period_count <= period_count + 1;
	else
		period_count <= 0;
end

//根据占空比调节方向标志进行占空比调节，控制LED亮度
always @(posedge sys_clk) begin
	if(!sys_rst_n)
		duty_cycle <= 0;
	else if(period_count == (STEP_INTERVAL - 1)) begin
		if((inc_dec_flag == 1'b0) && ((PWM_PERIOD - duty_cycle) >= DUTY_CYCLE_STEP))
			duty_cycle <= duty_cycle + DUTY_CYCLE_STEP;
		else if((inc_dec_flag == 1'b1) && (duty_cycle >= DUTY_CYCLE_STEP))
			duty_cycle <= duty_cycle - DUTY_CYCLE_STEP;
	end
end

//记录调节占空比的次数
always @(posedge sys_clk) begin
	if(!sys_rst_n)
		step_count <= 0;
	else if(period_count == (STEP_INTERVAL - 1)) begin
		if(step_count < (BRIGHT_LEVEL - 1))
			step_count <= step_count + 1;
		else
			step_count <= 0;
	end
end

//占空比调节方向控制，为0占空比加，为1占空比减
//当占空比连续递增（递减）到指定次数时说明占空比达到最大（最小），此时改变占空比调节方向标志
always @(posedge sys_clk) begin
	if(!sys_rst_n)
		inc_dec_flag <= 0;
	else if(period_count == (STEP_INTERVAL - 1)) begin
		if(step_count == (BRIGHT_LEVEL - 1))
			inc_dec_flag <= ~inc_dec_flag;
	end
end

endmodule

呼吸灯模块仿真激励代码

呼吸灯模块仿真激励代码非常简单，只需要产生激励时钟即可，代码如下：

`timescale 1ns / 1ns	//仿真单位/仿真精度

module tb_breath_led();

reg sys_clk;					//时钟
reg sys_rst_n;					//复位
wire [31:0] duty_cycle;			//占空比

initial begin
	sys_clk = 1'b0;
	sys_rst_n = 1'b0;
	#200
	sys_rst_n = 1'b1;
end

//产生时钟
always #10 sys_clk = ~sys_clk;

breath_led #(
	.PWM_PERIOD(100),				//pwm信号的周期
	.BREATH_PERIOD(10_000),			//呼吸灯周期
	.BRIGHT_LEVEL(10)				//亮度等级
)
u_tb_breath_led_inst(
	.sys_clk(sys_clk),					//系统时钟
	.sys_rst_n(sys_rst_n),				//系统复位，低电平有效

	.duty_cycle(duty_cycle)				//PWM占空比
);

endmodule

顶层模块

顶层模块主要用于例化PWM生成模块和呼吸灯模块，并将两个模块进行关联，代码如下：

`timescale 1ns / 1ns

module top_breath_led #(
	parameter PWM_PERIOD = 100_000,				//pwm信号的周期
	parameter BREATH_PERIOD = 100_000_000,		//呼吸灯周期
	parameter BRIGHT_LEVEL = 100				//亮度等级
)
(
	input sys_clk,								//系统时钟
	input sys_rst_n,							//系统复位，低电平有效

	output led									//LED
);

//PWM占空比
wire [31:0] duty_cycle;

//例化呼吸灯模块
breath_led #(
	.PWM_PERIOD(PWM_PERIOD),				//pwm信号的周期
	.BREATH_PERIOD(BREATH_PERIOD),			//呼吸灯周期
	.BRIGHT_LEVEL(BRIGHT_LEVEL)				//亮度等级
)
u_breath_led_inst (
	.sys_clk(sys_clk),						//系统时钟
	.sys_rst_n(sys_rst_n),					//系统复位，低电平有效

	.duty_cycle(duty_cycle)					//PWM占空比
);

//例化PWM发生模块
pwm_generate u_pwm_generate_inst (
	.sys_clk(sys_clk),						//系统时钟
	.sys_rst_n(sys_rst_n),					//系统复位，低电平有效

	.period(PWM_PERIOD),					//PWM周期
	.duty_cycle(duty_cycle),				//PWM占空比

	.pwm_out(led)							//PWM，用于控制LED
);

endmodule

顶层模块仿真激励代码

顶层模块仿真激励代码非常简单，只需要产生激励时钟即可，代码如下：

`timescale 1ns / 1ns	//仿真单位/仿真精度

module tb_top_breath_led();

reg sys_clk;					//时钟
reg sys_rst_n;					//复位
wire led;						//LED

initial begin
	sys_clk = 1'b0;
	sys_rst_n = 1'b0;
	#200
	sys_rst_n = 1'b1;
end

//产生时钟
always #10 sys_clk = ~sys_clk;

top_breath_led #(
	.PWM_PERIOD(10),					//pwm信号的周期
	.BREATH_PERIOD(1000),				//呼吸灯周期
	.BRIGHT_LEVEL(10)					//亮度等级
)
u_tb_top_breath_led_inst (
	.sys_clk(sys_clk),					//系统时钟
	.sys_rst_n(sys_rst_n),				//系统复位，低电平有效

	.led(led)							//LED
);

endmodule

约束输入

管脚分配如下：
在这里插入图片描述
XDC 约束语句如下：

#时序约束
create_clock -period 20.000 -name sys_clk [get_ports sys_clk]

#IO 管脚约束
set_property -dict {PACKAGE_PIN R4 IOSTANDARD LVCMOS15} [get_ports sys_clk]
set_property -dict {PACKAGE_PIN U7 IOSTANDARD LVCMOS15} [get_ports sys_rst_n]
set_property -dict {PACKAGE_PIN V9 IOSTANDARD LVCMOS15} [get_ports led]
lf282481431
关注
专栏目录
（27）呼吸灯verilog与VHDL编码（学无止境）
m0_46498597的博客
11-21 391
5 呼吸灯verilog与VHDL编码 1 本章目录 1）FPGA简介 2）Verilog简介 3）VHDL简介 4）呼吸灯verilog编码 5）呼吸灯VHDL编码 6）结束语 2 FPGA简介 FPGA（Field Programmable Gate Array）是在PAL、GAL等可编程器件的基础上进一步发展的产物。它是作为专用集成电路（ASIC）领域中的一种半定制电路而出现的，既解决了定制电路的不足，又克服了原有可编程器件门电路数有限的缺点。 FPGA设计不是简单的芯片研究，主要
51xx 增加呼吸灯功能
Alex_886的博客
05-06 1126
51xx 增加呼吸灯功能diff --git a/adk/src/domains/peripheral/led_manager/led_manager.c b/adk/src/domains/peripheral/led_manager/led_manager.c index 1cd3d3a1..10862be8 100644 --- a/adk/src/domains/peripheral/led_manager/led_manager.c +++ b/adk/src/domains/peripheral
PWM输出实现呼吸灯控制
houlile_sunny的博客
10-29 3468
脉宽调制（PWM，Pulse Width Modulation）是利用微处理器的数字输出来对模拟电路进行控制的一种非常有效的技术，广泛应用在从测量、通信到功率控制与变换的许多领域中。通俗的说，就是控制在一个周期内，控制高电平多长时间，低电平多长时间（前面文章种有说过IO口就只有两种状态，0和1，对应就是0和5V或者0和3.3V）。也就是说通过调节高低电平时间的变化来调节信号、能量等的变化。
PWM控制LED呼吸灯技术解析与应用
最新发布
CSmN_gsu_buqgsm的博客
06-11 2665
本文将从PWM控制LED呼吸灯的原理、优势、设计、实现、应用以及未来发展趋势等方面进行详细介绍。
LED呼吸灯
Bit_Dong的博客
05-21 1574
基于51单片机下 利用调整PWM输出脉宽进而控制 led灯的输出频率，使得 led 灯出现所谓“呼吸灯”的状况
stm32成长记之LED呼吸灯
wenke8619的博客
08-13 2148
呼吸灯
【FPGA】二、LED呼吸灯控制
weixin_62912626的博客
11-08 1742
Verilog实现LED呼吸灯控制
CSS的transition,animation两种方法实现呼吸灯动态效果
qq_42760090的博客
10-06 2949
HTML+CSS实现呼吸灯效果呼吸灯原理呼吸灯主体部分三级目录二级目录 呼吸灯原理 呼吸灯抽象过来就像呼吸一样，实现的效果是一种渐变循环的，从明亮到微弱以此无限循环的一种效果。那么用HTML写出基本框架，CSS实现样式，效果。两种方法的HTML代码是一样的 呼吸灯主体部分 两种方法的HTML代码是一样的，先贴代码。 <body> <div class="container"> <div class="outer"> <
MT6572平台加入呼吸灯功能——编写linux驱动
vipwming的专栏
12-20 1812
上一篇介绍了本实验所使用的主要IC及其通信方式，这里开始记录正式的开发过程。所选用的平台为MTK的MT6572，做过MTK智能平台研发的亲们都知道，MTK将自己的东西都添加在自加的包mediatek下面，kernel部分也不例外。然而为了体现普遍性，本实验我严格按照google提供的Android框架结构来进行相应添加的，即驱动程序添加在kernel/drivers/目录下。
【花雕动手做】ASRPRO语音识别（34）--WS2812B直条彩虹呼吸灯
雕爷学编程
01-13 1137
数据协议采用单线归零码的通讯方式，像素点在上电复位以后，DIN端接受从控制器传输过来的数据，首先送过来的24bit数据被第一个像素点提取后，送到像素点内部的数据锁存器，剩余的数据经过内部整形处理电路整形放大后通过DO端口开始转发输出给下一个级联的像素点，每经过一个像素点的传输，信号减少24bit。具有低电压驱动，环保节能，亮度高，散射角度大，一致性好，超低功率，超长寿命等优点。主要应用领域，LED全彩发光字灯串，LED全彩模组， LED全彩软灯条硬灯条，LED护栏管。10、数据发送速度可达800Kbps。
通过串口控制呼吸灯的频率
07-20
通过串口usart控制呼吸灯(pwm方波)的频率闪烁的快慢，该程序是基于stm32f407单片机的。
呼吸灯原理图
10-10
呼吸灯原理仿真图，基于proteus的仿真原理图
可调速率的呼吸灯
12-11
在变化曲线的斜率为0.5的基础上，进行亮灯速率的调整
简单呼吸灯电路图_呼吸灯电路图设计原理
07-15
本文主要讲了呼吸灯电路图设计原理，希望对你的学习有所帮助。
一个简单的单片机呼吸灯程序
04-10
这个程序简单，能让你的led呼吸起来！很好用，希望能帮大家啊
呼吸灯实现
xxz1445的博客
02-04 1563
本节实验任务是使用正点原子FPGA开发板上的LED，实现呼吸灯效果，即由灭渐亮，再由亮渐灭（渐亮和渐灭的时间为2s）。在一定周期内改变高低电平占空比达到亮度渐变效果，高电平占比越多，LED灯越亮。在modulesim仿真，以500ns为周期（减少仿真时间），下图为部分放大后仿真结果。呼吸灯原理：PWM（Pulse Width Modulation），脉冲宽度调制。呼吸灯：由灭渐亮，再由亮渐灭，模仿人呼吸方式的LED灯。cnt_2s缩小后为2000ns。cnt_2ms缩小后为200ns。实验验证为预期输出。
51单片机的PWM控制呼吸灯
congfen214的博客
10-26 2677
51单片机的PWM控制呼吸灯
呼吸灯
qq_40374303的博客
03-17 362
int lenpin = 9;//LED connected to digital pin 9  端口频率void setup(){    //nothing happens in setup }void loop(){       // fade in from min to max in icrements of 5 points ;    for(int fadevalue = 0;fade...
单片机实现LED呼吸灯功能
weixin_42096084的博客
03-07 2206
** 程序名： 　　 两键控制亮度 编写人： 　　　 编写时间：　　2017年12月15日 硬件支持：　　STC12C2052　内部RC或外部12MHZ晶振 接口说明：　　8个LED彩灯接P1口，按键接P3.7和P3.3 修改日志：　　 　　NO.1- /************************************************************************...
自制呼吸灯电路设计与解析
"硬件呼吸灯的设计很好很全" 呼吸灯是一种具有独特视觉效果的照明装置，常见于电子设备中，如笔记本电脑、手机、音响等，它通过模拟呼吸节奏的明暗变化来提供一种动态的指示效果，既具有装饰性又具有功能性。在硬件...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值