题目描述
在河上有一座独木桥,一只青蛙想沿着独木桥从河的一侧跳到另一侧。在桥上有一些石子,青蛙很讨厌踩在这些石子上。由于桥的长度和青蛙一次跳过的距离都是正整数,我们可以把独木桥上青蛙可能到达的点看成数轴上的一串整点:0,1,……,L(其中L是桥的长度)。坐标为0的点表示桥的起点,坐标为L的点表示桥的终点。青蛙从桥的起点开始,不停的向终点方向跳跃。一次跳跃的距离是S到T之间的任意正整数(包括S,T)。当青蛙跳到或跳过坐标为L的点时,就算青蛙已经跳出了独木桥。
题目给出独木桥的长度L,青蛙跳跃的距离范围S,T,桥上石子的位置。你的任务是确定青蛙要想过河,最少需要踩到的石子数。
输入输出格式
输入格式:
输入文件river.in的第一行有一个正整数L(1 <= L <= 10^9),表示独木桥的长度。第二行有三个正整数S,T,M,分别表示青蛙一次跳跃的最小距离,最大距离,及桥上石子的个数,其中1 <= S <= T <= 10,1 <= M <= 100。第三行有M个不同的正整数分别表示这M个石子在数轴上的位置(数据保证桥的起点和终点处没有石子)。所有相邻的整数之间用一个空格隔开。
输出格式:
输出文件river.out只包括一个整数,表示青蛙过河最少需要踩到的石子数。
输入输出样例
输入样例#1:
10
2 3 5
2 3 5 6 7
输出样例#1:
2
说明
对于30%的数据,L <= 10000;
对于全部的数据,L <= 109。
2005提高组第二题
分析:
(1)如果s=t,说明路径唯一,直接模拟。有20分。
(2)
方法一:
当s不等于t时,设f[i]为到i时最少碰到石头数,有
f[i]=min(f[i-j])+b[i] {i处有石头,b[i]=1,否则为0}
我们可以开一个单调队列来完成。当一个队列中的结果已经达到稳态,那么对下一次计算,它只能产生两种结果:如果计算位置没有石子,那么队列仍然保持稳定;如果有石子,那么加一的结果将使得队列再次出现不稳定。我们发现,在t个单位若无石头,则这个单调队列不会改变,每次直接跳到下一位置即可。
方法二:
如果把这些石子数放到长度为10亿单位的桥上,那是多么的稀疏呀,这就为我们提供了可能。
设第k个石子座标为x,第k-1个石子和第k个石子间距离足够大,则青蛙从两个石子间跳到第k个石子及之后的位置有:x、x+1、x+2、x+3……x+t-1。如果我们能保证,将石子k-1和石子k之间的距离缩短(即减少状态)后,青蛙依然能跳到这些位置,则可以平移。而这一点我们可以通过在两个石子间保留1个最小公倍数单位长度得到保证。
我们先来看一组数据。s=4,t=5。
从数据中我们看到,12以后的点全部都是可以到达的了。如果s=4,t=5,在一段100000的距离中没有石头,其实12以后的点都是不用递推就知道肯定能到达的。那么我们用原始的方法做就会浪费很大的资源。
所以当s=4,t=5时,如果一段没有石头的区间长度在4*5=20以外,那么我们只要递推前20就可以了,因为20后面的情况是一样的。
代码:
var
f:array [0..1000001] of longint;
b:array [0..1000001] of boolean;
a:array [0..100] of longint;
s,t,n,l,q,i,j,d,ans,x:longint;
procedure qsort(l,r:longint);
var
i,j,key,temp:longint;
begin
if l>=r then exit;
i:=l;j:=r;
key:=a[l+random(r-l+1)];
repeat
while (a[i]<key) do inc(i);
while (a[j]>key) do dec(j);
if i<=j then
begin
temp:=a[i];a[i]:=a[j];a[j]:=temp;
inc(i);dec(j);
end;
until i>j;
qsort(l,j);
qsort(i,r);
end;
function min(x,y:longint):longint;
begin
if x>y then exit(y)
else exit(x);
end;
begin
readln(l);
readln(s,t,n);
q:=s*t;
for i:=1 to n do
read(a[i]);
qsort(1,n);
if s=t then
begin
for i:=1 to n do
if a[i] mod s=0 then
inc(ans);
writeln(ans);
exit;
end;
for i:=1 to n do
begin
d:=a[i]-a[i-1];
if d>q then
begin
for j:=i to n do
a[j]:=a[j]-(d-q);
end;
b[a[i]]:=true;
end;
l:=a[n]+t;
fillchar(f,sizeof(f),$7f);
f[0]:=0;
for i:=1 to l do
for j:=s to t do
if i-j>=0 then
begin
if b[i] then x:=1 else x:=0;
f[i]:=min(f[i-j]+x,f[i]);
end;
ans:=maxlongint;
for i:=a[n]+1 to l do
ans:=min(ans,f[i]);
writeln(ans);
end.