Codesys.运动控制修改凸轮点

已于 2024-04-01 23:54:32 修改
阅读量2.4k 收藏 31
点赞数 37
分类专栏： 工业自动化文章 文章标签： 制造
于 2024-03-21 02:04:26 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/lx473774000/article/details/136893083
版权

案例链接：运动控制修改凸轮点案例包资源-CSDN文库

文章目录

运动控制之电子凸轮修改凸轮点

一. 根据制袋机双切R角工艺需求

二.凸轮曲线修改常用方法

三. Cam表MC_CAM_REF类型

四. 修改电子曲线的原则总结

五. 曲线规划以及修改凸轮表

5.1. 轴配置设计

5.2. 凸轮表设计

5.3. 代码框架设计

5.4. 修改凸轮曲线

5.4.1. 通过修改从轴比例缩放修改凸轮曲线

5.4.2. 通过切换Cam表修改凸轮曲线

5.5. 修改凸轮曲线关键点

5.5.1.凸轮周期末点或停机修改关键点

5.5.2. 运行中修改非当前段关键点

5.5.3. 修改凸轮曲线关键点个数

5.5.2. 修改凸轮曲线末尾长度

运动控制之电子凸轮修改凸轮点

一. 根据制袋机双切R角工艺需求

  • 工艺背景：

制袋行业有切圆角袋工艺需求(切废边-行业内称为R角)切刀是0到360度变化，电机旋转转换成切刀上下运动。

                                                         

双切工艺需求：

  • 切刀第一个周期，切前一个袋子的边;切刀第二个周期且后一个袋子的边。

  • 也就是说移刀第一个周期不动，第二个周期微动，微动到位后等待切刀切下，然后再等刀抬起后，返回原来位置。

  • 切刀切料角度120度-240度，在此区间移刀不能运动。

  • 移刀微动距离一般是1-5mm，客户要求可根据实际情况自行修改设置。

根据上面要求呢，我们一般将主轴设置周期从360改成720，方便规划电子凸轮曲线。

使用电子凸轮后，将客户设备双切速度从原来80刀/min提升刀160刀/min，达到机械极限。

二.凸轮曲线修改常用方法

注意 : 仅针对编译为多项式(XYVA)。

  • 通过改凸轮曲线的主从轴缩放比例或者偏置。

  • 新建多个凸轮曲线，对CAM曲线进行切换。

  • 程序中动态修改，仅修改中间的关键点(凸轮末点修改or凸轮曲线运行中修改)。

  • 程序中动态修改，修改首未关键点及关键点个数，需要重新触发MC_TableSelect。

  • 使用程序新建凸轮表代码，实现电子凸轮基本运动。

我们讲的凸轮表切换、关键点修改、程序新建电子凸轮，这些方法没有本质区别，总之都是“趁曲线不注意，把凸轮表改了。

学习目标

  • 通过修改从轴缩放比例，实现移刀曲线修改。

  • 在静态状态切换凸轮表 。

  • 在来点时动态切换凸轮表。

  • 在凸轮末点修改关键点，下一周期生效 。

  • 在凸轮运行中修改关键点，当前周期生效。

  • 凸轮末点修改 凸轮关键点个数，不修改首末关键点,不需要重新触发MC CamTableselect。

三. Cam表MC_CAM_REF类型

在Codesys中，对每一个CAM 表都有描述该CAM 表的数据结构，描述该CAM 表的特征数据。下图为“CAM”凸轮表的描述数据结构，请注意其结构各变量名称：

注意：:我们在声明CAM 凸轮表时，系统自动默认声明了全局变量类型的CAM 数据结构，同时声明了CAM_A[i] 数组。可以在用户程序中，修改CAM 凸轮表关键点个数或坐标:

总结：我们其实可以不通过application右键添加凸轮表，而是通过程序手动新建凸轮表数据结构，然后新建对应的数组，给当前数据结构赋值。

四. 修改电子曲线的原则总结

什么是好的凸轮曲线?

  • 适合的凸轮由线就是好的凸轮曲线。

什么样算“适合”?

  • 满足精度要求的。

  • 满足效率要求。

  • 满足工艺功能要求。

  • 噪音小，运行流畅的。

位置是描述的运行轨迹 (精度)，速度是描述的移动快慢 (效率)，加速度是描述的力的变化 (振动和噪音)，加加速度是描述的力的变化速度 (振动和噪音的频率)。

好的凸轮曲线特点:

  • 位置连续。

  • 速度连续，且速度比较小。

  • 加速度连续，且幅度较小。

  • 加加速度幅度小。

五. 曲线规划以及修改凸轮表

5.1. 轴配置设计

5.2. 凸轮表设计

 

5.3. 代码框架设计

这里展示出所有的相关变量、已经目录结构。

  • GVL_Var

// {attribute 'qualified_only'}
VAR_GLOBAL
	gsc_InnerIO					: SCTY_INNER_IO;	
	gf_TotalAccDec				: REAL 		:= 100; 			// 全局加速度/减速度
	
	gb_MasterVelocityExecute	: BOOL;							// 虚拟主轴：速度运行命令
	gf_MasterVelocityValue		: REAL 		:= 100;				// 虚拟主轴：速度运行参数
	gi_MasterDirection			: INT 		:= 1;				// 虚拟主轴：速度运行方向
	gb_MasterStop				: BOOL;							// 虚拟主轴：停止命令
	gb_MasterStopDone			: BOOL;							// 虚拟主轴：停止命令完成

	gb_FilmGearExecute			: BOOL;							// 实际主轴：电子齿轮耦合
	gb_FilmGearSyn				: BOOL;							// 实际主轴：电子齿轮同步中
	gdi_FilmNumerator			: DINT		:= 10000;			// 实际主轴：电子齿轮比分子
	gudi_FilmRightDenominator	: UDINT		:= 10000;			// 实际主轴：电子齿轮比分母
	gb_FilmGearOutExecute		: BOOL;							// 实际主轴：电子齿轮解耦合
	gb_FilmGearOutDone			: BOOL;							// 实际主轴：电子齿轮解耦合完成
	gb_FilmStop					: BOOL;							// 实际主轴：停止命令
	gb_FilmStopDone				: BOOL;                         // 实际主轴：停止命令完成

	gb_KnifeCamTabExecute		: BOOL;							// 实际刀轴：电子凸轮Cam表选择
	gb_KnifeCamTabDone			: BOOL;							// 实际刀轴：电子凸轮Cam表选择完成
	gb_KnifeCamExecute			: BOOL;							// 实际刀轴：电子凸轮耦合
	gb_KnifeCamSyn				: BOOL;                         // 实际刀轴：电子凸轮同步中
	gb_EndOfProfile				: BOOL;							// 实际刀轴：电子凸轮凸轮周期完成信号
	gb_KnifeCamOutExecute		: BOOL;							// 实际刀轴：电子凸轮解耦合
	gb_KnifeCamOutDone			: BOOL;							// 实际刀轴：电子凸轮解耦合完成
	gb_KnifeStop				: BOOL;							// 实际刀轴：停止命令
	gb_KnifeStopDone			: BOOL;	                        // 实际刀轴：停止命令完成

	gf_SlaveScaling				: REAL;							// 电子凸轮：从轴缩放比例
	gf_KnifeMoveDistance		: REAL		:= 1;				// 电子凸轮：从轴移刀距离
	
	gmc_Cam_Ref					: MC_CAM_REF;
	
	
	gi_ModifiCamTableMode       : INT		:= 1;	           	// 凸轮表修改模式：1=通过从轴比例缩放	
	gi_CamTableId				: INT		:= 1;				// 凸轮表ID选择
	gb_CamSwitchTest			: BOOL;
	gb_CamTest					: bool;	
END_VAR

  • SCTY_INNER_IO

TYPE SCTY_INNER_IO :
STRUCT
	gb_FirstOn				: BOOL;		// 首次执行
	gb_PowerOn				: BOOL;		// 持续执行
	gb_SingleStep			: BOOL;		// 单步执行
	gb_MaskSingleStep		: BOOL;		// 屏蔽单步执行
	gb_Reset				: BOOL;		// 复位
	gb_Pause				: BOOL;		// 暂停
	gb_JerkStop				: BOOL;		// 急停
	
	gb_Start				: BOOL;		// 启动
	gb_Stop					: BOOL;		// 停止
	
	gi_SystemState			: SINT;	
END_STRUCT
END_TYPE

  • PRG_TaskEct_No3、PRG_TaskEct_No2、PRG_TaskEct_No1局部变量

PROGRAM PRG_TaskEct_No3
VAR
	vmc_MasterPower					: MC_Power;
	vmc_FilmPower					: MC_Power;
	vmc_KnifePower					: MC_Power;

	vmc_MasterStop					: MC_Stop;
	vmc_FilmStop					: MC_Stop;
	vmc_KnifeStop					: MC_Stop;
	
	vmc_MasterVelocity				: MC_MoveVelocity;
	vmc_FilmGearIn					: MC_GearIn;
	vmc_FilmGearOut					: MC_GearOut;
	vmc_KnifeCamTableSelect			: MC_CamTableSelect;
	vmc_KnifeCamIn					: MC_CamIn;
	vmc_KnifeCamOut					: MC_CamOut;
	
	vf_SlaveScalingBuffer 			: REAL;
	vf_EndBuffer					: REAL;
	
	vrp_Test						: R_TRIG;
END_VAR

5.4. 修改凸轮曲线

5.4.1. 通过修改从轴比例缩放修改凸轮曲线

  • PRG_TaskEct_No1.A03_LogicalCode逻辑代码：

// 逻辑程序编写
gi_ModifiCamTableMode := 1;
CASE gi_ModifiCamTableMode OF  
	01:
		gmc_Cam_Ref := Cam_1mm_No1;
		gf_SlaveScaling := gf_KnifeMoveDistance / 1.0; 		// 1.0是Cam_1mm_No1的基准
		
		IF (R_Slave_Knife.nAxisState = 3) OR gb_EndOfProfile THEN  
			gb_KnifeCamTabExecute := (NOT gb_KnifeCamSyn) OR (gf_SlaveScaling <> vf_SlaveScalingBuffer);
			vf_SlaveScalingBuffer := gf_SlaveScaling;
		END_IF
END_CASE

5.4.2. 通过切换Cam表修改凸轮曲线

新建MC_CAM_REF凸轮表类型的全局变量，在程序中根据需求进行切换，一般凸轮表直接切换，应用在工艺不复杂，情况比较少的场景中，一般也就是几个凸轮表切换就能满足工艺需求场景。

在程序中根据进行凸轮表的选择切换常用方法有两种方法:

  • 在整机待机，静止状态下切换电子凸轮表。

  • 在电子凸轮周期末点，切换电子凸轮表。

                                                      

  • PRG_TaskEct_No2.A03_LogicalCode逻辑代码：

// 逻辑程序编写
gi_ModifiCamTableMode := 02;
CASE gi_ModifiCamTableMode OF  		
	02:	
		// 手动启动凸轮
		IF (R_Slave_Knife.nAxisState = 3) OR gb_EndOfProfile THEN 
			IF gi_CamTableId = 1 THEN 
				gmc_Cam_Ref := Cam_1mm_No2;
			
			ELSIF gi_CamTableId = 2 THEN 
				gmc_Cam_Ref := Cam_2mm_No2;
				
			ELSIF gi_CamTableId = 3 THEN 
				gmc_Cam_Ref := Cam_3mm_No2;
				
			ELSIF gi_CamTableId = 4 THEN 
				gmc_Cam_Ref := Cam_4mm_No2;c
				
			ELSIF gi_CamTableId = 5 THEN c
				gmc_Cam_Ref := Cam_5mm_No2;
			END_IF
		END_IF	
END_CASE

5.5. 修改凸轮曲线关键点

5.5.1.凸轮周期末点或停机修改关键点

我们在声明CAM凸轮表时，系统自动默认声明了全局变量类型的CAM数据结构，同时声明了CAM_A[i]数组，可以在用户程序中，修改CAM凸轮关键点个数或者坐标。

  • PRG_TaskEct_No3.A03_LogicalCode逻辑代码：

// 逻辑程序编写
gi_ModifiCamTableMode := 03;
CASE gi_ModifiCamTableMode OF  		
	03:	
		gmc_Cam_Ref := Cam_1mm_No1;
		
		// 凸轮末点信号时修改关键点，下一个凸轮周期生效（注意不是扫描周期，是凸轮周期）。
		IF (R_Slave_Knife.nAxisState = 3) OR gb_EndOfProfile THEN  
			gb_KnifeCamTabExecute := (NOT gb_KnifeCamSyn) ;	
		
			// 第一个关键点
			Cam_1mm_No1_A[0].dX := 0.0;
			Cam_1mm_No1_A[0].dY := 0.0;
			Cam_1mm_No1_A[0].dV := 0.0;
			Cam_1mm_No1_A[0].dA := 0.0;
			
			// 第二个关键点
			Cam_1mm_No1_A[1].dX := 360.0;
			Cam_1mm_No1_A[1].dY := 0.0;
			Cam_1mm_No1_A[1].dV := 0.0;
			Cam_1mm_No1_A[1].dA := 0.0;
			
			// 第三个关键点
			Cam_1mm_No1_A[2].dX := 440.0;
			Cam_1mm_No1_A[2].dY := gf_KnifeMoveDistance;
			Cam_1mm_No1_A[2].dV := 0.0;
			Cam_1mm_No1_A[2].dA := 0.0;
			
			// 第四个关键点
			Cam_1mm_No1_A[3].dX := 640.0;
			Cam_1mm_No1_A[3].dY := gf_KnifeMoveDistance;
			Cam_1mm_No1_A[3].dV := 0.0;
			Cam_1mm_No1_A[3].dA := 0.0;
			
			// 第五个关键点
			Cam_1mm_No1_A[4].dX := 720.0;
			Cam_1mm_No1_A[4].dY := 0.0;
			Cam_1mm_No1_A[4].dV := 0.0;
			Cam_1mm_No1_A[4].dA := 0.0;
		END_IF;
END_CASE

5.5.2. 运行中修改非当前段关键点

总共有5个关键点，除掉首末关键点(一般也不改首末关键点)，不需要重新触发MCCamTableSelect如果要改首末关键点的话，要重新触发MC CamTableSelect。

  • 当从轴运行在第一段，可以修改第三个或者第四个关键点的XYVZ坐标。

  • 当从轴运行在第二段，可以修改第四个关键点的 XYVA坐标。

  • 当从轴运行在第三段，可以修改的第二个关键点的XYVA坐标。

  • 当从轴运行在第四段，可以修改第二个或者第三个关键点的XYVZ坐标。

总结一下：“趁曲线不注意的时候，修改掉关键点”，实际上就是修改关键点时，别影响到当前正在运行的段，因为程序是周期扫描的，每个周期其实都会根据主轴位置以及电子凸轮曲线对应的数学函数(一般是五次曲线 poy)取解算从轴位置，所以一般我们修改电子凸轮曲线，只需要保证当前关键点 不在当前运行段就能修改了:

  • PRG_TaskEct_No3.A03_LogicalCode逻辑代码：

// 逻辑程序编写
gi_ModifiCamTableMode := 04;
CASE gi_ModifiCamTableMode OF  			
	04:	
		// 当前凸轮周期，修改非运行段凸轮关键点，当前凸轮周期生效
		gmc_Cam_Ref := Cam_1mm_No1;
		
		IF (R_Slave_Knife.nAxisState = 3) THEN 
			gb_KnifeCamTabExecute := (NOT gb_KnifeCamSyn) ;	
		END_IF
		
		// 运行在第三个关键点之前，此时可以修改第四个关键点。
		IF (V_Master.fSetPosition < 440.0) THEN 
			// 第四个关键点
			Cam_1mm_No1_A[3].dX := 640.0;
			Cam_1mm_No1_A[3].dY := gf_KnifeMoveDistance;
			Cam_1mm_No1_A[3].dV := 0.0;
			Cam_1mm_No1_A[3].dA := 0.0;
			
		// 运行在第一段凸轮曲线或者第四段凸轮曲线
		ELSIF (V_Master.fSetPosition < 360.0) OR (V_Master.fSetPosition > 640) THEN 
			// 第三个关键点
			Cam_1mm_No1_A[2].dX := 440.0;
			Cam_1mm_No1_A[2].dY := gf_KnifeMoveDistance;
			Cam_1mm_No1_A[2].dV := 0.0;
			Cam_1mm_No1_A[2].dA := 0.0;
		END_IF
END_CASE

注意：运行时修改，在修改时，当前的凸轮周期会发生形变，不能保证对每一种工艺都有效果，索引要慎用。

5.5.3. 修改凸轮曲线关键点个数

我们一般情况下，很少会修改关键点的个数。

  • PRG_TaskEct_No3.A03_LogicalCode逻辑代码：

gi_ModifiCamTableMode := 05;
CASE gi_ModifiCamTableMode OF  		
	05:
		// 凸轮末点修改，关键点个数，不修改末点关键点，不需要重新触发MC_CamTableSelect
	
		IF (R_Slave_Knife.nAxisState = 3) THEN 
			gb_KnifeCamTabExecute := (NOT gb_KnifeCamSyn) ;	
		END_IF

		IF gb_EndOfProfile  AND gb_CamSwitchTest THEN 
			Cam_1mm_No1.nElements := 5;
			Cam_1mm_No1.byType := 3;
			Cam_1mm_No1.xStart := 0.0;
			Cam_1mm_No1.xEnd := 720.0; 
			
			// 第一个关键点
			Cam_1mm_No1_A[0].dX := 0.0;
			Cam_1mm_No1_A[0].dY := 0.0;
			Cam_1mm_No1_A[0].dV := 0.0;
			Cam_1mm_No1_A[0].dA := 0.0;
			
			// 第二个关键点
			Cam_1mm_No1_A[1].dX := 360.0;
			Cam_1mm_No1_A[1].dY := 0.0;
			Cam_1mm_No1_A[1].dV := 0.0;
			Cam_1mm_No1_A[1].dA := 0.0;
			
			// 第三个关键点
			Cam_1mm_No1_A[2].dX := 440.0;
			Cam_1mm_No1_A[2].dY := 1;
			Cam_1mm_No1_A[2].dV := 0.0;
			Cam_1mm_No1_A[2].dA := 0.0;
			
			// 第四个关键点
			Cam_1mm_No1_A[3].dX := 640.0;
			Cam_1mm_No1_A[3].dY := 1;
			Cam_1mm_No1_A[3].dV := 0.0;
			Cam_1mm_No1_A[3].dA := 0.0;
			
			// 第五个关键点
			Cam_1mm_No1_A[4].dX := 720.0;
			Cam_1mm_No1_A[4].dY := 0.0;
			Cam_1mm_No1_A[4].dV := 0.0;
			Cam_1mm_No1_A[4].dA := 0.0;
			
		ELSIF gb_EndOfProfile  AND (NOT gb_CamSwitchTest) THEN 
			Cam_1mm_No1.nElements := 3;
			Cam_1mm_No1.byType := 3;
			Cam_1mm_No1.xStart := 0.0;
			Cam_1mm_No1.xEnd := 720.0; 
			
			// 第一个关键点
			Cam_1mm_No1_A[0].dX := 0.0;
			Cam_1mm_No1_A[0].dY := 0.0;
			Cam_1mm_No1_A[0].dV := 0.0;
			Cam_1mm_No1_A[0].dA := 0.0;
			
			// 第二个关键点
			Cam_1mm_No1_A[1].dX := 360.0;
			Cam_1mm_No1_A[1].dY := 1.0;
			Cam_1mm_No1_A[1].dV := 0.0;
			Cam_1mm_No1_A[1].dA := 0.0;
			

			// 第三个关键点
			Cam_1mm_No1_A[2].dX := 720.0;
			Cam_1mm_No1_A[2].dY := 0.0;
			Cam_1mm_No1_A[2].dV := 0.0;
			Cam_1mm_No1_A[2].dA := 0.0;
		END_IF;
		
		gmc_Cam_Ref := Cam_1mm_No1;
END_CASE

5.5.2. 修改凸轮曲线末尾长度

如果需要修改首末关键点的坐标，需要重新触发MC_CamTableSelect。

  • PRG_TaskEct_No3.A03_LogicalCode逻辑代码：

gi_ModifiCamTableMode := 06;
CASE gi_ModifiCamTableMode OF  		
	06:
		IF gb_EndOfProfile  AND gb_CamSwitchTest THEN 
			Cam_1mm_No1.nElements := 5;
			Cam_1mm_No1.byType := 3;
			Cam_1mm_No1.xStart := 0.0;
			Cam_1mm_No1.xEnd := 720.0; 
			
			// 第一个关键点
			Cam_1mm_No1_A[0].dX := 0.0;
			Cam_1mm_No1_A[0].dY := 0.0;
			Cam_1mm_No1_A[0].dV := 0.0;
			Cam_1mm_No1_A[0].dA := 0.0;
			
			// 第二个关键点
			Cam_1mm_No1_A[1].dX := 360.0;
			Cam_1mm_No1_A[1].dY := 0.0;
			Cam_1mm_No1_A[1].dV := 0.0;
			Cam_1mm_No1_A[1].dA := 0.0;
			
			// 第三个关键点
			Cam_1mm_No1_A[2].dX := 440.0;
			Cam_1mm_No1_A[2].dY := 1;
			Cam_1mm_No1_A[2].dV := 0.0;
			Cam_1mm_No1_A[2].dA := 0.0;
			
			// 第四个关键点
			Cam_1mm_No1_A[3].dX := 640.0;
			Cam_1mm_No1_A[3].dY := 1;
			Cam_1mm_No1_A[3].dV := 0.0;
			Cam_1mm_No1_A[3].dA := 0.0;
			
			// 第五个关键点
			Cam_1mm_No1_A[4].dX := 720.0;
			Cam_1mm_No1_A[4].dY := 0.0;
			Cam_1mm_No1_A[4].dV := 0.0;
			Cam_1mm_No1_A[4].dA := 0.0;
			
		ELSIF gb_EndOfProfile  AND (NOT gb_CamSwitchTest) THEN 
			Cam_1mm_No1.nElements := 5;
			Cam_1mm_No1.byType := 3;
			Cam_1mm_No1.xStart := 0.0;
			Cam_1mm_No1.xEnd := 360.0; 
			
			// 第一个关键点
			Cam_1mm_No1_A[0].dX := 0.0;
			Cam_1mm_No1_A[0].dY := 0.0;
			Cam_1mm_No1_A[0].dV := 0.0;
			Cam_1mm_No1_A[0].dA := 0.0;
			
			// 第二个关键点
			Cam_1mm_No1_A[1].dX := 180.0;
			Cam_1mm_No1_A[1].dY := 0.0;
			Cam_1mm_No1_A[1].dV := 0.0;
			Cam_1mm_No1_A[1].dA := 0.0;
			
			// 第三个关键点
			Cam_1mm_No1_A[2].dX := 240.0;
			Cam_1mm_No1_A[2].dY := 1;
			Cam_1mm_No1_A[2].dV := 0.0;
			Cam_1mm_No1_A[2].dA := 0.0;
			
			// 第四个关键点
			Cam_1mm_No1_A[3].dX := 340.0;
			Cam_1mm_No1_A[3].dY := 1;
			Cam_1mm_No1_A[3].dV := 0.0;
			Cam_1mm_No1_A[3].dA := 0.0;
			
			// 第五个关键点
			Cam_1mm_No1_A[4].dX := 360.0;
			Cam_1mm_No1_A[4].dY := 0.0;
			Cam_1mm_No1_A[4].dV := 0.0;
			Cam_1mm_No1_A[4].dA := 0.0;
		
		END_IF;
		
		// 赋值凸轮表
		gmc_Cam_Ref := Cam_1mm_No1;
		
		vrp_Test(CLK:= gb_CamTest);
		gb_KnifeCamTabExecute := (vf_EndBuffer <> Cam_1mm_No1.xEnd) OR vrp_Test.Q;
		vf_EndBuffer := Cam_1mm_No1.xEnd;
END_CASE

Svipi_追随
关注
专栏目录
Codesys.运动控制电子凸轮案例包
03-10
Codesys.运动控制电子凸轮案例包
电子凸轮.pdf
10-09
利用倍福TwinCAT2实现电子凸轮控制，介绍如何配置Twincat以及如何利用程序生成凸轮表。
Codesys电子凸轮追剪模型
01-14
Codesys使用电子凸轮实现三轴联动追剪功能，并通过可视化仿真验证结果 参考博客地址：https://blog.csdn.net/qq_19979629/article/details/122472554 codesys版本V3.5 .14.10,最新版的V3.5 .17.20可以查看程序，可能编译通不过，无法仿真
Codesys电子凸轮功能实现旋切（飞剪）及可视化仿真（附源程序）.rar
01-18
Codesys V3.5.14.10使用电子凸轮功能，编写cam表，绘制cam曲线，通过CFc模式编写程序，实现飞剪功能，并使用Codesys自带的可视化与仿真功能进行模拟
CODESYS运动控制之编写凸轮控制程序.doc
06-06
CODESYS运动控制之编写凸轮控制程序 1：新建工程，添加主从轴，添加配置凸轮表等，可参照前面轴控制系列文章
codesys电子凸轮曲线规划与调整方法
01-11
codesys电子凸轮曲线的规划与调整方法，想要丝般顺滑的凸轮曲线，就来参考下吧，嘿嘿 参考博客地址：https://blog.csdn.net/qq_19979629/article/details/122426709 codesys版本V3.5 .14.10,最新版的V3.5 .17.20可以查看程序，可能编译通不过，无法仿真
Codesys.运动控制电子凸轮
傻响雨
03-10 3349
电子凸轮到底是什么？ 机械图伦的推杆位置跟随凸轮角度的周期性变化而变化，其运动特性与机械凸轮的外形相关，定义凸轮为主轴，推杆为从周，那么凸轮的实质就是从周对应主轴的一种位置函数关系。 机械电子化，硬件软件化成为当今工业自动化发展趋势，随着制造装备的技术升级，伺服的应用日渐普及，应用系统要求多轴同步运动控制功能，在包装、印刷、鲤电等行业应用极其广泛，采用多伺服轴代替传统机械凸轮，已成为主流趋势。 电子凸轮是利用软件数字方式的“凸轮表”来代替机械凸轮，因此也称电子凸轮控制。
Codesys平台实现电子凸轮功能二：电子凸轮程序编写
weixin_54353890的博客
08-25 1835
输入：主轴、从轴，Cam表名称，触发信号（定义BOOL变量给定），有周期性，根据上面的主从轴坐标系确定，选择相对坐标（这个点相对上一个点的坐标，例如a(200,0)--->b(100,0)右键输入助手，文本搜索MC_CamOut，声明，另起名，定义触发信号BOOL类型变量（v_b_camout），上升沿有效。MC_Power_1作为主轴使能，MC_Power_2作为从轴使能，将再将输入（：=为输入，=>输出）补上波浪线就会消失，如下。同理，输入助手搜索双击，再声明，命名为MC_Jog_1。
Codesys平台实现电子凸轮功能一：电子凸轮功能介绍
weixin_54353890的博客
08-23 2556
挺杆的作用是主轴从正反经过一个点时可以输出一个开关量信号，该信号输出取决于挺杆设置的设置值，例如我这边设置120左右正向打开，反向不动作，240左右正向通过关闭，反向通过无动作，则主轴从0转到360度时，挺杆值会先置位，再复位，而如果主轴反向运行，从360度转到0度，反向动作是没有挺杆值输出的。为实现零速等待-->加速-->同步运行-->减速-->高速返回-->零速等待的周期性，这个是追剪的曲线，飞剪的不一样，其实也就是调整CAM表的关键点罢了。将其调节成下图，挺杆表可修改其坐标值。
codesys所有函数的详细说明
11-16
codesys所有函数的详细说明
电子凸轮做追剪飞剪
02-14
如何使用PLC 做飞剪控制，以汇川PLC 为例子。详细介绍控制配置等信息
CODESYS运动控制之添加凸轮表.docx
06-06
1： 凸轮机构(cam mechanism)一般是由凸轮，从动件(follower)和机架三个构件组成的高副机构。凸轮通常作连续等速转动，从动件根据使用要求设计使它获得一定规律的运动.凸轮机构能实现复杂的运动要求，广泛用于各种自动化和半自动化机械装置中。
基于网络的多轴运动控制技术及电子凸轮实现
06-07
基于网络的多轴运动控制技术及电子凸轮实现
codesys电子凸轮功能设计与实现
01-07
codesys实现电子凸轮，画凸轮cam表，设置挺杆点，编写程序，可视化仿真 参考博客地址：https://blog.csdn.net/qq_19979629/article/details/122373387 codesys版本V3.5 .14.10,最新版的V3.5 .17.20可以查看程序，可能编译通不过，无法仿真
Cam1_电子凸轮_CODESYS凸轮_CODESYS电子凸轮_Codesys练习电子凸轮例程_CoDeSys.zip
10-10
CODESYS是一款基于IEC 61131-3标准的工业自动化编程软件，广泛应用于PLC、运动控制、机器视觉等领域。本资料包“Cam1_电子凸轮_CODESYS凸轮_CODESYS电子凸轮_Codesys练习电子凸轮例程_CoDeSys.zip”主要聚焦于使用...
codesys运动控制之添加凸轮表.zip
最新发布
08-05
codesys codesys运动控制之添加凸轮表.zip
CODESYS开发的多轴运动控制程序框架：封装单轴控制功能块，实现归零、点动、相对定位、绝对定位等功能，支持伺服模式切换，程序框架完善的状态调用和变量规划帮助快速开发
tGQMMrokOvMe的博客
05-19 797
通过使用这个框架，开发者可以更加专注于业务逻辑的实现，将更多的时间和精力投入到程序的优化和调试上，从而提高开发效率和程序的质量。基于codesys开发的多轴运动控制程序框架，将逻辑与运动控制分离，将单轴控制封装成功能块，对该功能块的操作包含了所有的单轴控制（归零、点动、相对定位、绝对定位、设置当前位置、伺服模式切换等等）。程序框架由主程序按照状态调用分归零模式、手动模式、自动模式、故障模式，程序状态的跳转都已完成，只需要根据不同的工艺要求完成所需的动作即可。
Codesys使用电子凸轮实现追剪功能
qq_19979629的博客
01-14 8018
追剪是对运动中的材料进行垂直切割的工艺。从轴刀架由等待位置开始加速，其速度达到同步速 度后，刀架与材料的运动速度相等，两者相对静止，由刀架上的切刀对材料进行剪切。追剪在管材，型材的裁切中十分常见，即避免了材料的变形，又可以减小电机功率，降低成本 。
codesys凸轮曲线描点
12-22
CODESYS是一款用于工业自动化控制系统的编程软件。在CODESYS中，可以使用凸轮曲线描点技术来实现驱动机械设备的运动控制。凸轮曲线描点是一种控制系统，通过改变凸轮的形状，来控制机械臂或其他设备的运动轨迹。 在CODESYS中，可以通过编写PLC程序，结合使用凸轮曲线描点功能块，来实现对凸轮轨迹运动的控制。首先需要定义凸轮的形状和运动规律，然后在程序中使用相应的函数块来描点并控制设备的运动。 通过凸轮曲线描点技术，可以实现复杂的非线性运动轨迹，例如椭圆或者其他非规则形状的轨迹。这种技术可以应用于各种工业领域，例如自动装配线、包装机械、机器人等设备的运动控制。 凸轮曲线描点在CODESYS中的应用，使得工程师可以更加灵活地设计和实现机械设备的运动控制，并且可以根据实际需要进行调整和优化。这种技术的应用可以提高设备运动的精度和效率，同时也为工业生产的自动化提供了更多可能性。通过合理的凸轮设计和程序编写，可以实现各种复杂的运动轨迹控制，为工业生产带来更多的便利和效益。
评论 2
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值