CMakeList.txt的指令以及实例介绍

一、Cmake 简介
cmake（Cross platform make） 是一个开源的跨平台自动化构建系统，用来管理程序构建，不依于特定的编译器。所谓的跨平台就是可以在Windows，Linux，MacOS，安卓等平台均可用。

它是一个集软件构建、测试、打包于一身的软件。它使用与平台和编译器独立的配置文件来对软件编译过程进行控制。

Cmake中最重要的是CMakeList.txt文件，在该文件中可以自己设定并自动化编译生成库文件还是可执行文件等等，能为开发者节省大量时间。

优点：开源，有BSD许可证，跨平台使用，根据需求生成Makefile和工程文件，如果你自己去写Makefile文件，你会崩溃的；能够综合管理大型项目，像Opencv，Caffe等，能够高效率的构建项目，自动化编译。

Linux安装命令：sudo apt-get install cmake

                          sudo apt-get install cmake-gui

CMakeList.txt使用注意事项

CMakeList.txt是CMake构建专用定义文件，文件名严格区分大小，在工程中有很多个目录，可以每个目录都存放一个CMakeList.txt文件；也可以只使用一个CMakeList.txt文件管理。

CMakeList.txt中指令不区分大小写，大小写都可以，根据自己习惯编写

CMakeList.txt中的参数和变量是区分大小写的，名称只能用字母，数字，下划线，破折号；

一般用${}来引用变量，并且参数之间使用空格进行间隔。

二、常用命令介绍
1. 指定 cmake 的最小版本
cmake_minimum_required(VERSION 3.4.1)
指定要求最小的cmake版本，如果小于这个版本，程序终止。这行命令是可选的，我们可以不写这句话，但在有些情况下，如果 CMakeLists.txt 文件中使用了一些高版本 cmake 特有的一些命令的时候，就需要加上这样一行，提醒用户升级到该版本之后再执行 cmake。

2. 设置项目名称
project(test)
设置当前项目名称为test，这个命令不是强制性的，但最好都加上。它会引入两个变量 demo_BINARY_DIR 和 demo_SOURCE_DIR，同时，cmake 自动定义了两个等价的变量 PROJECT_BINARY_DIR 和 PROJECT_SOURCE_DIR。

3. 设置编译类型
add_executable(demo demo.cpp) # 用指定的源文件生成可执行文件
add_library(common STATIC util.cpp) # 生成静态库
add_library(common SHARED util.cpp) # 生成动态库或共享库
add_library 默认生成是静态库，通过以上命令生成文件名字

4. CMAKE_BUILD_TYPE构建类型

构建类型有四种分别为：

Debug 调试模式，输出调试信息，不做优化

Release：发布模式，内有调试信息，全优化

RelWithDebinfo 类似于Release，但是有输出调试信息

MinSizeRel 一种特殊的Release模式，对优化库内存有要求

5.设置变量
5.1 set 直接设置变量的值

set(SRC_LIST main.cpp test.cpp)
add_executable(demo ${SRC_LIST})
5.2 set 追加设置变量的值

set(SRC_LIST main.cpp)
set(SRC_LIST ${SRC_LIST} test.cpp)
add_executable(demo ${SRC_LIST})
5.3 list 追加或者删除变量的值

set(SRC_LIST main.cpp)
list(APPEND SRC_LIST test.cpp)
list(REMOVE_ITEM SRC_LIST main.cpp)
add_executable(demo ${SRC_LIST})
6. 指定编译包含的源文件
6.1 明确指定包含哪些源文件

add_library(demo demo.cpp test.cpp util.cpp)

在 Linux 下是：
demo
libcommon.a
libcommon.so
在 Windows 下是：
demo.exe
common.lib
common.dll
6.2 搜索所有的 cpp 文件

aux_source_directory(dir VAR) 发现一个目录下所有的源代码文件并将列表存储在一个变量中。

aux_source_directory(. SRC_LIST) # 搜索当前目录下的所有.cpp文件
add_library(demo ${SRC_LIST})
6.3 自定义搜索规则

file(GLOB SRC_LIST "*.cpp" "protocol/*.cpp")
add_library(demo ${SRC_LIST})
# 或者
file(GLOB SRC_LIST "*.cpp")
file(GLOB SRC_PROTOCOL_LIST "protocol/*.cpp")
add_library(demo ${SRC_LIST} ${SRC_PROTOCOL_LIST})
# 或者
aux_source_directory(. SRC_LIST)
aux_source_directory(protocol SRC_PROTOCOL_LIST)
add_library(demo ${SRC_LIST} ${SRC_PROTOCOL_LIST})

 

7. 添加依赖项

add_dependencies(target-name depend)

为target添加依赖项，如果只有一个target有依赖项，一般使用target_link_libraries，如果有两个有依赖，而且依赖库也是由编译源码产生，这个时候用该指令可以在编译上层target时，自动检查下层依赖库是否已经生成。没有的话先编译下层依赖库，然后再编译上层target，最后link depend target。

8. 添加子目录

add_subdirectory(path)

想当前工程添加子目录

9. 查找指定的库文件
find_library(VAR name path)查找到指定的预编译库，并将它的路径存储在变量中。
默认的搜索路径为 cmake 包含的系统库，因此如果是 NDK 的公共库只需要指定库的 name 即可。

find_library( # Sets the name of the path variable.
              log-lib
 
              # Specifies the name of the NDK library that
              # you want CMake to locate.
              log )
类似的命令还有 find_file()、find_path()、find_program()、find_package()。

10. 设置包含的目录
include_directories(
    ${CMAKE_CURRENT_SOURCE_DIR}
    ${CMAKE_CURRENT_BINARY_DIR}
    ${CMAKE_CURRENT_SOURCE_DIR}/include
)
Linux 下还可以通过如下方式设置包含的目录

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -I${CMAKE_CURRENT_SOURCE_DIR}")

这里采用追加的形式设置参数
11. 设置链接库搜索目录
link_directories(
    ${CMAKE_CURRENT_SOURCE_DIR}/libs
)
Linux 下还可以通过如下方式设置包含的目录

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -L${CMAKE_CURRENT_SOURCE_DIR}/libs")
12. 设置 target 需要链接的库
target_link_libraries( # 目标库
                       demo
 
                       # 目标库需要链接的库
                       # log-lib 是上面 find_library 指定的变量名
                       ${log-lib} )
在 Windows 下，系统会根据链接库目录，搜索xxx.lib 文件，Linux 下会搜索 xxx.so 或者 xxx.a 文件，如果都存在会优先链接动态库（so 后缀）。一般用在add_executable之后

12.1 指定链接动态库或静态库

target_link_libraries(demo libface.a) # 链接libface.a
target_link_libraries(demo libface.so) # 链接libface.so
12.2 指定全路径

target_link_libraries(demo ${CMAKE_CURRENT_SOURCE_DIR}/libs/libface.a)
target_link_libraries(demo ${CMAKE_CURRENT_SOURCE_DIR}/libs/libface.so)
12.3 指定链接多个库target_link_libraries(demo
    ${CMAKE_CURRENT_SOURCE_DIR}/libs/libface.a
    boost_system.a
    boost_thread
    pthread)
13. 条件控制
13.1 if…elseif…else…endif

逻辑判断和比较：
if (expression)：expression 不为空（0,N,NO,OFF,FALSE,NOTFOUND）时为真
if (not exp)：与上面相反
if (var1 AND var2)
if (var1 OR var2)
if (COMMAND cmd)：如果 cmd 确实是命令并可调用为真
if (EXISTS dir) if (EXISTS file)：如果目录或文件存在为真
if (file1 IS_NEWER_THAN file2)：当 file1 比 file2 新，或 file1/file2 中有一个不存在时为真，文件名需使用全路径
if (IS_DIRECTORY dir)：当 dir 是目录时为真
if (DEFINED var)：如果变量被定义为真
if (var MATCHES regex)：给定的变量或者字符串能够匹配正则表达式 regex 时为真，此处 var 可以用 var 名，也可以用 ${var}
if (string MATCHES regex)

数字比较：
if (variable LESS number)：LESS 小于
if (string LESS number)
if (variable GREATER number)：GREATER 大于
if (string GREATER number)
if (variable EQUAL number)：EQUAL 等于
if (string EQUAL number)

字母表顺序比较：
if (variable STRLESS string)
if (string STRLESS string)
if (variable STRGREATER string)
if (string STRGREATER string)
if (variable STREQUAL string)
if (string STREQUAL string)
示例：

if(MSVC)
    set(LINK_LIBS common)
else()
    set(boost_thread boost_log.a boost_system.a)
endif()
target_link_libraries(demo ${LINK_LIBS})
# 或者
if(UNIX)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -fpermissive -g")
else()
    add_definitions(-D_SCL_SECURE_NO_WARNINGS
    D_CRT_SECURE_NO_WARNINGS
    -D_WIN32_WINNT=0x601
    -D_WINSOCK_DEPRECATED_NO_WARNINGS)
endif()
 
if(${CMAKE_BUILD_TYPE} MATCHES "debug")
    ...
else()
    ...
endif()
13.2 while…endwhile

while(condition)
    ...
endwhile()
13.3 foreach…endforeach

foreach(loop_var RANGE start stop [step])
    ...
endforeach(loop_var)
start 表示起始数，stop 表示终止数，step 表示步长，示例：

foreach(i RANGE 1 9 2)
    message(${i})
endforeach(i)

14. 打印信息
message(${PROJECT_SOURCE_DIR})
message("build with debug mode")
message(WARNING "this is warnning message")
message(FATAL_ERROR "this build has many error") # FATAL_ERROR 会导致编译失败
15. 包含其它 cmake 文件
include(./common.cmake) # 指定包含文件的全路径
include(def) # 在搜索路径中搜索def.cmake文件
set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake) # 设置include的搜索路径

16.查找第三方库（重要）

find_package(package version EXACT/QUIET/REQUIRED)

version :查找指定的库版本号，如果是EXACT，则要求必须精确匹配该版本号，如果是QUIET，则是禁掉没有找到的警告信息。如果是REQUIRED，没有找到包，CMake终止，并发出警告。

例如：find_package(OpenCV 3.4 REQUIRED)，如果系统没有找到，则编译终止，输出警告。

采用两种模式Findxxx.cmake和XXXConfig.cmake搜索外部库，优先采用Module模式，如果没有找到，则采用Config模式

Module模式/Config模式：搜索CMAKE_MODULE_PATH指定路径下的FindXXX.cmake文件，执行改文件从而找到XXX库，并给XXX_INCLUDE_DIRS和XXX_LIBRARIES两个变量赋值,这一步操作由FindXXX.cmake模块完成。

如果没找到，则需要在CMakeLists.txt最前面添加XXX搜索路径，例如：

set(XXX_DIR /home/lll/project/OpenCV3.2/build)#添加OpenCV3.2的搜索路径

当find_package找到库之后，下面四个变量会自动初始化

<NAME>_FOUND:显示是否找到库的标记

<NAME>_LIBRARIES或者<NAME>_INCLUDES:头文件路径

<NAME>_LIBRARIES或者<NAME>_LIBS：库文件

<NAME>_DEFINITIONS:

三、常用变量
1. 预定义变量
PROJECT_SOURCE_DIR：工程的根目录,即内含project()指令的CMakeList所在的文件夹
PROJECT_BINARY_DIR：运行 cmake 命令的目录，通常是 ${PROJECT_SOURCE_DIR}/build
PROJECT_NAME：返回通过 project 命令定义的项目名称，即project(xxxx)中的xxxx
CMAKE_CURRENT_SOURCE_DIR：当前处理的 CMakeLists.txt 所在的路径
CMAKE_CURRENT_BINARY_DIR：target 编译目录
CMAKE_CURRENT_LIST_DIR：CMakeLists.txt 的完整路径
CMAKE_CURRENT_LIST_LINE：当前所在的行
CMAKE_MODULE_PATH：定义自己的 cmake 模块所在的路径，SET(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)，然后可以用INCLUDE命令来调用自己的模块

CMAKE_BINARY_DIR：默认build文件夹所在的绝对路径

CMAKE_SOURCE_DIR：源文件所在的绝对路径
EXECUTABLE_OUTPUT_PATH：可执行文件的存放位置
LIBRARY_OUTPUT_PATH：链接库文件的存放位置

2. 环境变量
使用环境变量

 $ENV{Name}
写入环境变量

 set(ENV{Name} value) # 这里没有“$”符号
3. 系统信息
­CMAKE_MAJOR_VERSION：cmake 主版本号，比如 3.4.1 中的 3
­CMAKE_MINOR_VERSION：cmake 次版本号，比如 3.4.1 中的 4
­CMAKE_PATCH_VERSION：cmake 补丁等级，比如 3.4.1 中的 1
­CMAKE_SYSTEM：系统名称，比如 Linux-­2.6.22
­CMAKE_SYSTEM_NAME：不包含版本的系统名，比如 Linux
­CMAKE_SYSTEM_VERSION：系统版本，比如 2.6.22
­CMAKE_SYSTEM_PROCESSOR：处理器名称，比如 i686
­UNIX：在所有的类 UNIX 平台下该值为 TRUE，包括 OS X 和 cygwin
­WIN32：在所有的 win32 平台下该值为 TRUE，包括 cygwin

4. 主要开关选项
BUILD_SHARED_LIBS：这个开关用来控制默认的库编译方式，如果不进行设置，使用 add_library 又没有指定库类型的情况下，默认编译生成的库都是静态库。如果 set(BUILD_SHARED_LIBS ON) 后，默认生成的为动态库
CMAKE_C_FLAGS：设置 C 编译选项，也可以通过指令 add_definitions() 添加
CMAKE_CXX_FLAGS：设置 C++ 编译选项，编译CXX设置标志，例如：-std=c++11,-Wall,-O3(优化，使用向量化，CPU流水线，cache等提高代码速度)；如果编译过程输出警告：set(CMAKE_CXX_FLAGS "-Wall");也可以采用追加的模式，不会丢失之前的定义，例如：set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS }” "-Wall")。也可以通过指令 add_definitions() 添加

add_definitions(-DENABLE_DEBUG -DABC) # 参数之间用空格分隔
 

四、项目示例
1. 简单项目（单个源文件）
一个经典的 C 程序，如何通过 cmake 来编译呢？

1.1 新建文件 main.c

#include <stdio.h>
int main() {
    printf("Hello World!\n");
    return 0;
}
1.2 新建文件 CMakeLists.txt（命名必须是 CMakeLists.txt，注意大小写和不要漏字母）

project(HELLO)
add_executable(hello main.c)
1.3 编译和运行

新建一个 build 文件夹，目录情况如下：

为什么要新建一个 build 文件夹？
        一般我们采用 cmake 的 out-of-source 方式来构建（即生成的中间产物和源代码分离），这样做可以让生成的文件和源文件不会弄混，且目录结构看起来也会清晰明了。所以推荐使用这种方式，至于这个文件夹的命名并无限制，我们习惯命名为 build。

依次执行以下命令：

cd build
cmake ..
首先进入到 build 目录，然后就是 cmake .. 命令，另外要注意将 cmake 配置到环境变量中去才可直接使用，否则需要使用绝对路径，.. 表示上一级目录，cmake 会在上一级目录下找到 CMakeLists.txt 文件并编译，并生成如下图所示的一些中间文件：

直接执行 make 命令，生成可执行程序，如下图：

运行程序，如下所示：运行程序，如下所示：

2. 复杂项目（多个目录，多个源文件，多个项目）
目录结构如下：

demo 根目录下的 CMakeLists.txt 文件如下：

cmake_minimum_required (VERSION 2.8)
project(demo)
aux_source_directory(. DIR_SRCS)
# 添加math子目录
add_subdirectory(math)
# 指定生成目标
add_executable(demo ${DIR_SRCS})
# 添加链接库
target_link_libraries(demo MathFunctions)
math 目录下的 CMakeLists.txt 文件如下：

aux_source_directory(. DIR_LIB_SRCS)
# 生成链接库
add_library(MathFunctions ${DIR_LIB_SRCS})
3. 自定义编译选项
cmake 允许为项目增加编译选项，从而可以根据用户的环境和需求选择最合适的编译方案。
例如，可以将 MathFunctions 库设为一个可选的库，如果该选项为 ON ，就使用该库定义的数学函数来进行运算，否则就调用标准库中的数学函数库。
修改根目录下的 CMakeLists.txt 文件如下：# CMake 最低版本号要求
cmake_minimum_required (VERSION 2.8)
# 项目信息
project (Demo)
# 加入一个配置头文件，用于处理 CMake 对源码的设置
configure_file (
    "${PROJECT_SOURCE_DIR}/config.h.in"
    "${PROJECT_BINARY_DIR}/config.h"
    )
# 是否使用自己的 MathFunctions 库
option (USE_MYMATH
        "Use provided math implementation" ON)
# 是否加入 MathFunctions 库
if (USE_MYMATH)
    include_directories ("${PROJECT_SOURCE_DIR}/math")
    add_subdirectory (math)
    set (EXTRA_LIBS ${EXTRA_LIBS} MathFunctions)
endif (USE_MYMATH)
# 查找当前目录下的所有源文件
# 并将名称保存到 DIR_SRCS 变量
aux_source_directory(. DIR_SRCS)
# 指定生成目标
add_executable(Demo ${DIR_SRCS})
target_link_libraries (Demo ${EXTRA_LIBS})
configure_file 命令用于加入一个配置头文件 config.h ，这个文件由 cmake 从 config.h.in 生成，通过这样的机制，将可以通过预定义一些参数和变量来控制代码的生成。
option 命令添加了一个 USE_MYMATH 选项，并且默认值为 ON 。根据 USE_MYMATH 变量的值来决定是否使用我们自己编写的 MathFunctions 库。