汇编语言：键盘中断

最新推荐文章于 2024-03-10 14:31:36 发布
最新推荐文章于 2024-03-10 14:31:36 发布
阅读量8.1k 收藏 85
点赞数 71
文章标签： 编程语言 其他 嵌入式
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/m0_49448277/article/details/116743111
版权

汇编语言：键盘中断

友情提示，本篇文章较长，如果仅需要代码可以点击此处下载源代码

一、实验目的

  1. 了解 Intel8086CPU的中断处理功能以及IBM-PC的中断结构
  2. 了解8259中断控制器的使用。
  3. 掌握键盘中断的编程，观察中断的执行情况。

二、实验任务

  1. 基本要求：每按下任意一个键就向CPU发出中断请求信号，该信号由8259的IRQ1引入，中断类型号为09， CPU响应中断后转入执行KEYINTS中断服务程序，并在屏幕上显示“OK！”，按下10次键后返回DOS。

  2. 附加功能

    1. 通过DOS系统功能调用的25H，35H功能实现中断向量的设置和读取；
    2. 在显示”OK！”的前面增加显示按键次数
    3. 按键10次后，不等25行太阳图标显示完，立即返回DOS；
    4. 修改显示字符的属性，如，红底白字，蓝底黄字……

三、实验原理

    键盘与主机是通过5芯螺旋形的电缆相连的，其中包括数据线、时钟线、复位线、+5v电源线和地线（电缆插入系统板后部的插座）
   每当有键按下或释放时，键盘以串行方式向系统板的键盘接口电路传送数据，即扫描码。一个扫描码移位传送完，键盘接口电路便向主机发岀中断请求信号IRQ1（中断类型码为09H，此信号送到8259A产生中断请求。
   CPU响应中断请求时，查中断向量表，从09H×4开始的连续四个单元中取出中断向量（IRQ1中断服程序 KEYINTS的入口地址指针），转去执行中断服务程序 KEYINTS。
  在键盘中断程序 KEYINTS中，保护现场、开中断之后，就通过8255A的PA口（PA口地址为60H）读取键盘扫描码，接着从8255A的PB口（PB口地址为61H）的PB7输出一个正脉冲（即PB7先输出髙电平，再输出低电平），先输出的高电平信号反相之后控制键盘状态触发器的清零端，使IRQI清零，撤消中断请求信号。再输出的低电平信号允许位寄存器输出数据，这样就为传递下一个键盘扫描码作好了准备。

以上内容是为了让大家对程序功能有一些基本认识，接下来开始正式编程

四、编写程序

首先先放几张程序运行时的动图

  1. 基本程序
    在这里插入图片描述
  2. 附加任务二（在显示”OK！”的前面增加显示按键次数）：
    在这里插入图片描述
  3. 附加任务三（按键10次后，不等25行太阳图标显示完，立即返回DOS）
    在这里插入图片描述
  4. 附加任务四（修改显示字符的属性，如，红底白字，蓝底黄字……）
    在这里插入图片描述

看完程序运行动态图后，我们再通过程序流程图来观察程序是如何运行的。

在这里插入图片描述
通过流程图可以看出程序的基本结构，现在将其中几个重要的程序段单独呈现出来

  1. 延时程序
  DELAY PROC         ; 延时程序
      PUSH CX
      PUSH DX
      MOV DX,36H
 	  DL500:MOV CX, 0FFFFH
 	  DL10MS:LOOP DL10MS
      DEC DX
      JNZ DL500
      POP DX
      POP CX    
      RET
  DELAY ENDP

对于延时程序也可以使用我写的上一篇文章汇编语言：时钟实验中的延时程序，如果需要修改延时时间的话，直接修改DX或者CX的值即可

  1. 显示太阳字符
DISP1 PROC FAR     ; 显示太阳
       	PUSH AX
       	PUSH BX
       	PUSH CX
       	PUSH DX
       	MOV AH,15     ; 读当前显示状态
       	INT 10H
       	MOV AH,0      ; 设置显示方式
       	INT 10H
       	MOV DX,0      ; 行号为0，列号为0
	REPT: MOV AH,2      ; 设置光标位置
      	INT 10H  
       	MOV AL,0FH    ; OFH一太阳图形的ASCII码
        MOV CX,1      ; 显示字符个数
       	MOV AH,10     ; 写字符
       	INT 10H
       	CALL DELAY
       	SUB AL,AL
       	MOV AH,0      ; 清除原图形
       	INT 10H
       	INC DH        ; 行号+1
       	ADD DL,2      ; 列号+1
       	CMP DH,25     ; 判断是否到25行，不等继续显示太阳，相等返回
       	JNE REPT
       	POP DX
       	POP CX
       	POP BX
       	POP AX
       	RET
  DISP1 ENDP
  1. 显示OK！
DISP2 PROC FAR      ; 显示OK
        PUSH CX
       	PUSH BX
       	PUSH AX
     	  MOV CX,3
	      NEXTC: LODSB  ; 字符串"OK!"在数据段中定义，AL<—[SI]
	      MOV AH, 0EH   ; 写字符， 并移动鼠标
        MOV BX,01
	      INT 10H
        CALL DELAYL
        LOOP NEXTC
    	  POP AX
    	  POP BX
    	  POP CX
    	  RET
	DISP2 ENDP
  1. 中断程序
	KEYINT PROC FAR
       	PUSH AX
  	    PUSH SI  
  	    STI    
  	    IN AL,60H      ; 通过8255A的PA口(PA口地址为60H）读取键盘扫描码
  	    MOV AH,AL
      	IN AL,61H      ; 从8255APB口(PB口地址为61H）的PB7输出一个正脉冲（即PB7先输出高电平，再输出低电平）
       	OR AL,80H      ; PB7置1
  	    OUT 61H,AL
       	AND AL,7FH
       	OUT 61H,AL     ; PB7清零
       	TEST AH,80H    ; 相等时代表键被释放，开中断，显示字符
       	JNE GO         ; 不等，中断结束返回
       	STI  
       	INC KEY
       	MOV SI,OFFSET BUF   ; 初始化SI，在DISP2中不再对SI进行初始化
       	CALL DISP2
	    GO:MOV AL,20H
       	OUT 20H,AL
       	POP SI
       	POP AX
       	IRET
	KEYINT ENDP

1. 基本程序

完整的代码如下：

STACK  SEGMENT
	DW 200H DUP(?)
STACK ENDS
DATA SEGMENT
  	KEY DB ?           ; ?表示占用空间
  	BUF DB "OK!"
DATA ENDS
CODE SEGMENT
      ASSUME CS:CODE,SS:STACK,DS:DATA
  	DELAY PROC         ; 延时程序
     	PUSH CX
      	PUSH DX
      	MOV DX,36H
 	  	DL500:MOV CX, 0FFFFH
 	  	DL10MS:LOOP DL10MS
      	DEC DX
      	JNZ DL500
      	POP DX
      	POP CX    
      	RET
  	DELAY ENDP
 	DELAYL PROC
     	PUSH CX
      	PUSH DX
      	MOV DX,02H
      	DL500L:MOV CX, 0FFFFH
      	DL10MSL:LOOP DL10MSL
      	DEC DX
      	JNZ DL500L
      	POP DX
      	POP CX    
      	RET
  	DELAYL ENDP
  	DISP1 PROC FAR     ; 显示太阳
       	PUSH AX
       	PUSH BX
       	PUSH CX
       	PUSH DX
       	MOV AH,15     ; 读当前显示状态
       	INT 10H
       	MOV AH,0      ; 设置显示方式
       	INT 10H
       	MOV DX,0      ; 行号为0，列号为0
	REPT: MOV AH,2      ; 设置光标位置
      	INT 10H  
       	MOV AL,0FH    ; OFH一太阳图形的ASCII码
        MOV CX,1      ; 显示字符个数
       	MOV AH,10     ; 写字符
       	INT 10H
       	CALL DELAY
       	SUB AL,AL
       	MOV AH,0      ; 清除原图形
       	INT 10H
       	INC DH        ; 行号+1
       	ADD DL,2      ; 列号+1
       	CMP DH,25     ; 判断是否到25行，不等继续显示太阳，相等返回
       	JNE REPT
       	POP DX
       	POP CX
       	POP BX
       	POP AX
       	RET
  	DISP1 ENDP
	DISP2 PROC FAR      ; 显示OK
        PUSH CX
       	PUSH BX
       	PUSH AX
     	  MOV CX,3
	      NEXTC: LODSB  ; 字符串"OK!"在数据段中定义，AL<—[SI]
	      MOV AH, 0EH   ; 写字符， 并移动鼠标
        MOV BX,01
	      INT 10H
        CALL DELAYL
        LOOP NEXTC
    	  POP AX
    	  POP BX
    	  POP CX
    	  RET
	DISP2 ENDP
	KEYINT PROC FAR
       	PUSH AX
  	    PUSH SI  
  	    STI    
  	    IN AL,60H      ; 通过8255A的PA口(PA口地址为60H）读取键盘扫描码
  	    MOV AH,AL
      	IN AL,61H      ; 从8255APB口(PB口地址为61H）的PB7输出一个正脉冲（即PB7先输出高电平，再输出低电平）
       	OR AL,80H      ; PB7置1
  	    OUT 61H,AL
       	AND AL,7FH
       	OUT 61H,AL     ; PB7清零
       	TEST AH,80H    ; 相等时代表键被释放，开中断，显示字符
       	JNE GO         ; 不等，中断结束返回
       	STI  
       	INC KEY
       	MOV SI,OFFSET BUF   ; 初始化SI，在DISP2中不再对SI进行初始化
       	CALL DISP2
	    GO:MOV AL,20H
       	OUT 20H,AL
       	POP SI
       	POP AX
       	IRET
	KEYINT ENDP
	START:MOV AX,STACK
       	MOV SS,AX
       	MOV AX,DATA
       	MOV DS,AX
       	MOV AX,0          ; 将AX置0，后将其赋给ES，进行原09H中断向量的保存
       	MOV ES,AX
       	MOV AX,ES:[24H]   ; 09H*4=24H
       	PUSH AX
       	MOV AX,ES:[26H]   ; 
       	PUSH AX
       	CLI               ; 关中断，进行中断向量的设置
       	MOV AX,OFFSET KEYINT
       	MOV ES:[24H],AX
       	MOV AX,SEG KEYINT
       	MOV ES:[26H],AX    
       	STI               ; 同意下方程序接受中断
       	MOV  KEY,0
	AGAIN:CAll DISP1        ; 显示太阳
       	CMP KEY,10        ; 判断显示25行太阳后，是否已经按下了十次键
       	JB AGAIN
       	CLI               ; 禁止下方程序中断发生，保护代码运行
       	POP AX
       	MOV ES:[26H],AX
       	POP AX
       	MOV ES:[24H],AX
       	STI               ; 开中断
       	MOV AH,4CH
       	INT 21H
CODE ENDS
  END START

完整程序中有一个程序段为DELAYL，该程序段的功能也是延时，但是是在显示0K!时使用的。

2. 附加任务1

通过DOS系统功能调用（INT 21H）的25H，35H功能实现中断向量的设置和读取

功能号（AH）功能调用参数返回参数
25H设置中断向量DS: 段地址 DX: 偏移地址
AL: 中断类型号
35H获取中断向量AL: 中断类型号ES: 段地址 BX: 偏移地址

只需要修改START中的设置和读取中断向量的程序段即可，具体修改如下：

START:MOV AX,STACK
       	MOV SS,AX
       	MOV AX,DATA
       	MOV DS,AX
       	; MOV AX,0          ; 将AX置0，后将其赋给ES，进行原09H中断向量的保存
       	; MOV ES,AX
       	; MOV AX,ES:[24H]   ; 中断向量
       	; PUSH AX
       	; MOV AX,ES:[26H]   ; 中断向量
       	; PUSH AX
        MOV AH, 35H
        MOV AL, 09H         ; 使用DOS系统功能实现中断向量的读取
        INT 21H
        PUSH BX
        PUSH ES
       	CLI               ; 关中断，进行中断向量的设置
       	; MOV AX,OFFSET KEYINT
       	; MOV ES:[24H],AX
       	; MOV AX,SEG KEYINT
       	; MOV ES:[26H],AX 
        PUSH DS
        MOV AX, SEG KEYINT   ; 使用DOS系统功能实现中断向量的设置
        MOV DS, AX
        MOV DX, OFFSET KEYINT
        MOV AH, 25H
        MOV AL, 09H
        INT 21H 
        pop DS
       	STI               ; 同意下方程序接受中断
       	MOV  KEY,0
	AGAIN:CAll DISP1      ; 显示太阳
       	CMP KEY,10        ; 判断显示25行太阳后，是否已经按下了十次键
       	JB AGAIN
       	CLI               ; 禁止下方程序中断发生，保护代码运行
       	POP DS
       	POP DX
        MOV AH, 25H
        MOV AL, 09H
        INT 21H
       	STI               ; 开中断
       	MOV AH,4CH
       	INT 21H
CODE ENDS
	END START

3. 附加任务2

在显示0K!前面加上次数

实现该功能需要修改DISP2的程序

	DISP2 PROC FAR      ; 显示OK
        PUSH DX
        PUSH CX
       	PUSH BX
       	PUSH AX
        MOV DL, KEY
        ADD DL, 30H
        CMP DL, 3AH   ; 比较DL和3AH，即确定DL是不是10
        JAE EQUALTEN
        MOV AH,2
        INT 21H
     	MOV CX,3
	    NEXTC: LODSB  ; 字符串"OK!"在数据段中定义，AL<—[SI]
	    MOV AH, 0EH   ; 写字符， 并移动鼠标
        MOV BX,01
	    INT 10H
        CALL DELAYL
        LOOP NEXTC
    	POP AX
    	POP BX
    	POP CX
        POP DX
    	RET
        EQUALTEN: MOV DL, 31H     ; 当KEY>=10时
        MOV AH, 2
        INT 21H
        MOV DL, KEY
        ADD DL, 26H               ; 显示KEY的个位数
        MOV AH,2
        INT 21H
        MOV CX, 3
        NEXTCE: LODSB             ; 字符串"OK!"在数据段中定义，AL<—[SI]
        MOV AH, 0EH               ; 写字符， 并移动鼠标
        MOV BX,01
        INT 10H
        CALL DELAYL
        LOOP NEXTCE
        POP AX
        POP BX
        POP CX
        POP DX
        RET
	DISP2 ENDP

附加功能2中比较棘手的是需要在按键次数为10时对其进行正确显示，需要将其分为1和0来显示，这里我写的程序其实不够好，因为当按键次数超过20次后，又会出现字符显示错误的情况，不过由于只需要按下10次键盘就停止程序，也就没过多研究了。

4. 附加任务3

按键10次后，直接结束程序

这个功能容易实现，在附加任务2中我们在按键10次时跳转到EQUALTEN标号处，只需要在结尾加上返回DOS系统的命令即可

DISP2 PROC FAR      ; 显示OK
        PUSH DX
        PUSH CX
       	PUSH BX
       	PUSH AX
        MOV DL, KEY
        ADD DL, 30H
        CMP DL, 3AH
        JAE EQUALTEN
        MOV AH,2
        INT 21H
     	MOV CX,3
	    NEXTC: LODSB  ; 字符串"OK!"在数据段中定义，AL<—[SI]
	    MOV AH, 0EH   ; 写字符， 并移动鼠标
        MOV BX,01
	    INT 10H
        CALL DELAYL
        LOOP NEXTC
    	POP AX
    	POP BX
    	POP CX
        POP DX
    	RET
        EQUALTEN: MOV DL, 31h     ; 当KEY==10时
        MOV AH, 2
        INT 21H
        MOV DL, KEY
        ADD DL, 26H               ; 显示KEY的个位数
        MOV AH,2
        INT 21H
        MOV CX, 3
        NEXTCE: LODSB             ; 字符串"OK!"在数据段中定义，AL<—[SI]
        MOV AH, 0EH               ; 写字符， 并移动鼠标
        MOV BX,01
        INT 10H
        CALL DELAYL
        LOOP NEXTCE
        POP AX
        POP BX
        POP CX
        POP DX            ; 此时直接结束程序
        CLI               ; 禁止下方程序中断发生，保护代码运行
        POP DS
        POP DX
        MOV AH, 25H
        MOV AL, 09H
        INT 21H
        STI               ; 开中断
        MOV AH,4CH
        INT 21H
	DISP2 ENDP

与附加任务2中的代码进行比对后可以发现在DISP2的结尾删除了RET这一命令，加上了返回DOS系统的命令

5. 附加任务4

修改显示字符的属性，如红底白字，蓝底黄字…

个人感觉这个附加任务并不简单，也有可能是我理解错了，写得比较复杂。

首先先定义了一个宏过程(macro procedure)，代码如下：

OUTPUTOK MACRO STR    ; 定义了一个宏，STR 为参数
        MOV AL, STR
        MOV BH, 0
        MOV BL, COLOROK
        MOV CX, 1
        MOV AH, 9
        INT 10H
        CALL Cursor
        CALL DELAYL
  ENDM

这里有一个子程序Cursor是之前没有接触过的，它的功能是为了移动光标，防止字符之间相互覆盖，这一子程序中通过BIOS系统功能调用（INT 10H）的02H，03H功能实现光标位置的设置和读取

功能号（AH）功能调用参数返回参数
02H设置光标位置BH: 显示页码
DH: 行 DL: 列
03H获取光标位置BH: 显示页码DH: 行 DL: 列

具体程序如下：

Cursor PROC             ; 将光标向后移动一位
        PUSH DX
        PUSH CX
        PUSH BX
        PUSH AX
        MOV AH, 03H
        INT 10H
        ADD DL, 01H       ; 将列数加一后设置光标位置
        MOV AH, 02H
        INT 10H
        POP AX
        POP BX
        POP CX
        POP DX  
        RET
  Cursor ENDP

最后就要修改显示的函数DISP1和DISP2了，具体代码如下

	DISP1 PROC FAR     ; 显示太阳
       	PUSH AX
       	PUSH BX
       	PUSH CX
       	PUSH DX
       	MOV AH,15     ; 读当前显示状态
       	INT 10H
       	MOV AH,0      ; 设置显示方式
       	INT 10H
       	MOV DX,0      ; 行号为0，列号为0
	REPT: MOV AH,2      ; 设置光标位置
      	INT 10H  
       	MOV AL,0FH    ; OFH一太阳图形的ASCII码
        MOV BH, 0
        MOV BL, COLORSUN
        MOV CX,1      ; 显示字符个数
       	MOV AH,09     ; 写字符
       	INT 10H
       	CALL DELAY
       	SUB AL,AL
       	MOV AH,0      ; 清除原图形
       	INT 10H
       	INC DH        ; 行号+1
       	ADD DL,2      ; 列号+1
       	CMP DH,25     ; 判断是否到25行，不等继续显示太阳，相等返回
       	JNE REPT
       	POP DX
       	POP CX
       	POP BX
       	POP AX
       	RET
 	DISP1 ENDP
	DISP2 PROC FAR      ; 显示OK
        PUSH DX
        PUSH CX
       	PUSH BX
       	PUSH AX
        MOV DL, KEY
        ADD DL, 30H
        CMP DL, 3AH
        JAE EQUALTEN
        MOV BH, 0
        MOV AL, DL
        MOV BL, COLORNUM
        MOV CX, 1
        MOV AH,9
        INT 10H
        CAll Cursor
        OUTPUTOK 'O'
        OUTPUTOK 'K'
        OUTPUTOK '!'
    	POP AX
    	POP BX
    	POP CX
        POP DX
    	RET
        EQUALTEN: MOV CX, 1
        MOV AL, 31h     ; 当KEY==10时
        MOV AH, 09
        MOV BL, COLORNUM
        MOV BH, 0
        INT 10H
        CAll Cursor
        MOV AL, KEY
        ADD AL, 26H               ; 显示KEY的个位数
        MOV AH,09
        MOV BL, COLORNUM
        MOV BH, 0
        INT 10H
        CALL Cursor
        OUTPUTOK 'O'
        OUTPUTOK 'K'
        OUTPUTOK '!'
        POP AX
        POP BX
        POP CX
        POP DX            ; 此时直接结束程序
        CLI               ; 禁止下方程序中断发生，保护代码运行
        POP DS
        POP DX
        mov ah, 25H
        mov al, 09H
        int 21H
        STI               ; 开中断
        MOV AH,4CH
        INT 21H
	DISP2 ENDP

显示带颜色的字符需要使用BIOS系统（INT 21H）功能号为9的功能

功能号（AH）功能调用参数返回参数
09H在当前光标处
写字符和属性		BH: 页号 AL: 显示字符的ASCⅡ码
BL: 属性   CX: 显示次数

在程序中我重写了显示OK!的程序，因为如果使用原来的程序，OK!将很难显示属性（当然有可能是我的水平不够，还有更加简单的方法）
在上面的程序和宏过程中大家可能发现了COLOROK、COLORSUN、COLORNUM这三个参数，这三个参数需要提前在数据段中定义：

DATA SEGMENT
	KEY DB ?           ; ?表示占用空间
  	COLORSUN DB 42H    ; 太阳字符的属性
  	COLORNUM DB 57H    ; 按键次数的属性
  	COLOROK DB 32H     ; OK!的属性
DATA ENDS

对于字符属性，高四位代表文字颜色，低四位代表背景颜色。颜色对照表如下：

十六进制颜色十六进制颜色
0黑色 █8灰色 █
1蓝色 █9淡蓝色 █
2绿色 █A淡绿色 █
3青色 █B淡青色 █
4红色 █C淡红色 █
5紫红色 █D淡紫红色 █
6棕色 █E淡棕色 █
7银色█F白色█

如42H即文字颜色为红色，背景颜色为绿色


五、结语

本文较长，感谢大家可以看到最后，如果想要源代码，可以在文章开头下载，也可以在百度网盘 上下载，提取码：xhmc

XMJ2002
关注
键盘中断的配置及使用（MC9S08AW60）
小治成长记
10-31 2499
中断指计算机CPU获知某些事，暂停正在执行的程序，转而去执行处理该事件的程序，当这段程序执行完毕后再继续执行之前的程序。整个过程称为中断处理，简称中断，而引起这一过程的事件称为中断事件。
8086汇编语言：BIOS中断调用在屏幕上输出图案
坤舆湖畔的万某某的博客
11-30 3017
详细解释，原理分析，代码详细，样例丰富！
汇编:键盘中断(int 9)
m0_37564426的博客
03-01 2647
键盘中断， 一般按下键盘上的某个按钮就会触发键盘中断. assume cs:code, ds:data, ss:stack data segment db 128 dup(0) data ends stack segment stack db 128 dup(0) stack ends code segment start: mov ax, stack mov ss, ax ...
【汇编】自定义9号中断（键盘输入处理中断）
握固
08-19 5219
在屏幕上交替显示a~z，按ESC字体变绿色   assume cs:code,ds:data data segment dw 0,0;存放原9号中断的偏移和段地址 data ends code segment ;;;;;;;;;;;;;;;;;;;;;;
键盘中断
guocaigao的专栏
04-06 4407
键盘中有一颗键盘编码器的芯片，通常是Intel8048
看8086汇编 书上的一个小作业 键盘中断例程编写
我多么希望明天有太阳，来灼烧我腐烂的梦想
10-22 2471
;任务：在屏幕中间依次显示‘a'~’z' 并可以让人看清。在显示的过程中 按下Esc后，改变显示的颜色 assume cs:code ;栈 stack segment db 128 dup (0) stack ends ;store data data segment dw 0,0 data ends ; code segment start: mov ax,stack mov
汇编语言：键盘中断.zip
05-13
在本主题"汇编语言：键盘中断"中，我们将深入探讨如何利用汇编语言处理键盘输入，这是一个在操作系统、游戏和其他需要实时用户交互的程序中常见的功能。 键盘中断是计算机系统中一种重要的中断类型，当用户按下键盘...
汇编语言：常用中断向量表
12-30
汇编语言中断向量表 中断向量表是汇编语言中的一种重要概念，它提供了一种机制，允许操作系统和应用程序之间进行交互和通信。中断向量表是一个 Jump Table，它包含了一系列的中断向量，每个中断向量对应着一个特定...
汇编语言：第7章 输入输出和中断.ppt
06-16
汇编语言作为低级编程语言，提供了直接控制硬件的手段，因此理解I/O和中断的概念对于编写底层程序至关重要。本章主要讲解了I/O的基本概念、数据的传送方式以及中断机制，特别是针对DOS中断和BIOS中断的使用。 7.1 ...
汇编语言：使用8259中断实现定时/计数器实验
最新发布
YFY1129的博客
03-10 4782
使用8259中断实现定时/计数器实验
键盘中断程序与原理图实现过程
03-30
描述如何进行键盘中断实验，有相关程序和电路图实现过程！
键盘扫描码 键盘扫描码
07-16
键盘扫描码 手头查看用用 以下为凑字数：键盘扫描码键盘扫描码键盘扫描码
汇编语言_实验15：编写int 9 中断，完成键盘过程
weixin_43916755的博客
10-24 896
int9中断例程
王爽 汇编 实验16 增加键盘中断调用int 7ch中断例程
u010452022的专栏
11-07 893
assume cs:code code segment start: mov ax,cs mov ds,ax mov si,offset setscreen mov ax,0 mov es,ax mov di,0200h mov cx,offset endsetscreen-offset setscreen rep movsb mov ax,0 mov es,ax mov
汇编程序：按键松开时中断的处理
迂者-贺利坚的专栏
06-05 4673
当键盘上有键按下时，会产生该键的扫描码，并被送入端口地址为60h的寄存器中。然后，CPU会接受到9h号中断，如果该键是字符码，会将扫描码连同字符码(ASCII码)一起放入缓冲区，而如果该键是控制键和切换键，则会改变内存中对应键盘状态的字节中。 　　当要为某按键设置特别的功能时，可以改写int 9h的中断处理程序，也可以调用int 16h BIOS中断，各种方案，这是学习底层的同学要练的基本功。
【51单片机汇编】按键按下，中断一次，完成一次读/写操作。
m0_55251293的博客
11-10 2072
使用P1口的P1.4—P1.7作为输入位，P1.0—P1.3作为输出位。驱动LED以检查输出位的电平情况。（输入位高时，相应的LED点亮）。现要求采用中断边沿触发方式，每中断一次，完成一次读/写操作。
键盘之中断法1
LIN___IT的博客
10-17 660
本次项目是一个按键、外部中断、LED但又不失基础的综合项目，为接下来的学习大有裨益！最后，LED-执棋困局下一文章我们将继续介绍按键与中断的综合性项目，我们敬请期待吧！！！
babyos （十二） —— 键盘中断
孤舟钓客
01-17 5348
注：以下代码参考了linux2.6和Orange's（minix），但不雷同。若有bug，欢迎指出。 欢迎关注baby的成长：https://github.com/guzhoudiaoke/babyos/wiki 为了模仿linux的终端，还专门研究了下如何实现透明效果，结果发现简单的很，就是背景乘上个比例因子加前景乘上个比例因子。 1.键盘的工作原理 要让
8086汇编（10、int9键盘中断）
a807719447的专栏
04-03 1956
今天我们来实现个功能按F1 不断改变屏幕颜色 概念： 按键盘会产生扫描码 通码 按住不放 断码 弹起，通码+80H int9中断对应的端口为60H，也就是我们按下键盘，就可以从60H中读取到扫描码 扫描码的对照表可以参考这篇文章： 键盘按键的各种编码对照表 如果我们直接改变int9,那么硬件层面的一些其它操作细节会就无法继续了，比如控制键的状态信息的填充，比如后续硬件的应答事件。所以这里我们需要做个事情就是在调用int9之前做一个拦截。也就是我们先从60H端口中把数据读走，然后在调用它原来的中断，做
评论 3
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值