Mplus—三个或多个变量随机截距交叉滞后模型（RI-CLPM）语法

RI-CLPM with three or more variables

关于随机截距交叉滞后模型的Mplus语法，多数以两个变量为例，因此，有人可能会有这样的疑问：

三个变量的语法怎么写呢？

自己在两个变量的基础上修改的语法，会不会有什么问题呢？

关于这个问题，研究者给出的答案是：

所有的变量都分解为个体间和个体内成分，写出相应的滞后路径和变量之间的相关即可。

Is it possible to run an RI-CLPM with three (or more) outcomes? Yes, it is statistically possible to run a “trivariate” RI-CLPM and empirical researchers have done so, see for example Van Lissa, Keizer, Van Lier, Meeus, and Branje (2019), Flouri, Papachristou, Midouhas, Ploubidis, Lewis, and Joshi (2019), and Hygen, Belsky, Stenseng, Steinsbekk, Wichstrom, and Skalicka (2022). We don’t provide model code here for this mode, but extension to a trivariate RI-CLPM should be relatively straight forwards. That is, all variables should be decomponsed into between- (random intercepts) and within-components, and relevant lagged effects, as well as (residual) variances and covariances, should be included in the model.

对3个变量（X、M、Y）进行了5次测量（x1-x5、m1-m5、y1-y5），建立RI-CLPM，Mplus语法为：

TITLE: The basic RI-CLPM, 5 waves, 3 variables.

            ! 该文件的内容为RI-CLPM的语法，包括3个变量，进行了5次测量

DATA: FILE = RICLPM.dat; ! 数据来源

VARIABLE: NAMES = x1-x5 m1-m5 y1-y5; ! 变量名称

ANALYSIS: MODEL = NOCOV;

                   ! Sets all default covariances to zero

                   ! 通过该语句将所有默认协方差设置为零

MODEL:

! Create between components (random intercepts)

! 个体间水平上，创建三个随机截距RIx、RIm和RIy

RIx BY x1@1 x2@1 x3@1 x4@1 x5@1;

RIm BY m1@1 m2@1 m3@1 m4@1 m5@1;

RIy BY y1@1 y2@1 y3@1 y4@1 y5@1;

! Create within-person centered variables 个体内水平上，创建变量

wx1 BY x1@1;

wx2 BY x2@1;

wx3 BY x3@1;

wx4 BY x4@1;

wx5 BY x5@1;

wm1 BY m1@1;

wm2 BY m2@1;

wm3 BY m3@1;

wm4 BY m4@1;

wm5 BY m5@1;

wy1 BY y1@1;

wy2 BY y2@1;

wy3 BY y3@1;

wy4 BY y4@1;

wy5 BY y5@1;

! Constrain measurement error variances to 0 将测量误差方差限制为0

x1-y5@0;

! Estimate lagged effects between within-person centered variables

! 估计个体内变量的滞后效应

wx2 wm2 wy2 ON wx1 wm1 wy1;

wx3 wm3 wy3 ON wx2 wm2 wy2;

wx4 wm4 wy4 ON wx3 wm3 wy3;

wx5 wm5 wy5 ON wx4 wm4 wy4;

! Estimate covariance between random intercepts 估计随机截距之间的协方差（相关）

RIx WITH RIy;

RIx WITH RIm;

RIy WITH RIm;

! Estimate covariance between within-person components at first wave

! 估计第一个时间点个体内变量之间的协方差（相关）

wx1 WITH wy1;

wx1 WITH wm1;

wy1 WITH wm1;

! Estimate covariances between residuals of within-person components

! 估计个体内变量残差之间的协方差（相关）

wx2 WITH wy2;

wx2 WITH wm2;

wy2 WITH wm2;

wx3 WITH wy3;

wx3 WITH wm3;

wy3 WITH wm3;

wx4 WITH wy4;

wx4 WITH wm4;

wy4 WITH wm4;

wx5 WITH wy5;

wx5 WITH wm5;

wy5 WITH wm5;

OUTPUT: TECH1 STDYX SAMPSTAT CINTERVAL;

---

希望上述介绍可以帮助到你！也欢迎大家在评论区多多交流分享。

你的关注/点赞 /收藏★/分享，是最大的支持！