目录
单位等值（Metric Invariance）或弱等值（Weak Invariance）
尺度等值（Scalar Invariance）或强等值（Strong Invariance）
误差方差等值（Error Variance Invariance）或严格等值（Strict Invariance）
测量不变性/测量等值
测量等值（Measurement Equivalence, ME）或测量不变性（Measurement Invariance, MI）是指在不同情境下对同一属性进行测量所得结果是一致的。这些情境包括不同群体、不同场合和不同测量的时间点。
不同群体和不同场合的等值也称为多组等值/不变性。
不同时间点的等值也称为纵向等值/不变性。
纵向不变性/纵向等值
在纵向调查或追踪研究中，只有保证测量工具具有纵向不变性，即使用同一量表在不同时间点均能有效对被试某一特性进行测量，才能够真正揭示心理活动发展变化的规律。
因此，在正式进行数据分析之前，首先要对量表的纵向不变性进行检验。
例如，下面这篇文章想要探究特质愤怒、敌意归因偏向、愤怒沉浸和社会攻击之间的纵向关系
Li, R., & Xia, L. X. (2020). The mediating mechanisms underlying the longitudinal effect of trait anger on social aggression: Testing a temporal path model. Journal of Research in Personality, 88, 104018. http://doi.org/10.1016/j.jrp.2020.104018
在构建交叉滞后面板模型（Cross-Lagged Panel Model, CLPM）之前，首先对各个量表的纵向不变性进行了检验。
Third, the measurement invariance of the longitudinal data was tested. Fourth, a FULL auto-regressive cross-lagged model with all research variables across three waves was conducted.
在同一群体中，间隔相同的时间，进行三次测量。采用单一数据文件，即三次测量的数据包含在同一文件中，SPSS数据陈列方式如下：
纵向不变性模型设定上，同一测量指标的误差允许相关
纵向不变性模型中同一指标使用了不止一次，而一般认为误差方差中包含的指标独特性方差在两次测量间保持恒定，所以同一指标的误差允许相关是方法效应（method effect）的估计。如果不允许误差相关反而导致系统的参数估计偏差。
所以上述模型的示意图为：
分析步骤
形态等值（Configural Invariance）
检验潜变量的构成形态或模式是否相同，也成为因素模式等同。
单位等值（Metric Invariance）或弱等值（Weak Invariance）
检验测量指标与因子之间的关系，即因子负荷在各组间是否等值。
如果每一个观测项目在对应潜变量上的因子负荷跨组等同，就可以说明观测指标和潜在特质之间在不同组间有着相同的意义。
尺度等值（Scalar Invariance）或强等值（Strong Invariance）
检验观测变量的截距是否具有不变性。
强等值性的确立表明测量在不同组之间具有相同的参照点。
只有满足单位等值与尺度等值，即单位和参照点都相同，用观测变量估计的潜变量分数才是无偏的，组间比较也才有意义
误差方差等值（Error Variance Invariance）或严格等值（Strict Invariance）
检验误差方差是否跨组等值。
Mplus操作方法
三次调查数据的纵向不变性检验
形态等值语句
TITLE: This is an example of a longitudinal invariance; ! 该语句的内容
DATA: FILE IS XXX.dat; ! 数据文件
VARIABLE: NAMES ARE X11-X13 X21-X23 X31-X33; ! 数据文件中的变量
USEVARIABLE ARE X11-X13 X21-X23 X31-X33; ! 本次分析中所用到的变量
MISSING=ALL (99); ! 定义缺失值。Mplus默认使用全息极大似然估计（FIML）处理缺失值，这种处理最大程度利用原始数据
ANALYSIS: ESTIMATOR=MLM; ! 估计方法，适用于非正态数据
MODEL: X1 BY X11-X13;
X2 BY X21-X23;
X3 BY X31-X33; ! 验证性因素分析
X11-X13 PWITH X21-X23;
X11-X13 PWITH X31-X33;
X21-X23 PWITH X31-X33; ! 允许不同时间点同一指标的误差相关
OUTPUT: SAMPSTAT MOD STANDARDIZED CINTERVAL; ! 结果输出样本统计量、修正指数、标准化值、置信区间
- MLM：极大似然估计伴标准误和均值校正的卡方检验，此时得到的参数为Satorra-Bentler 校正统计量（S-Bχ2 : Satorra-Bentler chi-square values）。此方法适用于非正态数据。
- 用PWITH设定误差方差相关，PWITH定义配对相关或协方差关系，X1 X2 PWITH X3 X4等价于X1 WITH X3; X2 WITH X4。
单位等值/弱等值语句
TITLE: This is an example of a longitudinal invariance;
DATA: FILE IS XXX.dat;
VARIABLE: NAMES ARE X11-X13 X21-X23 X31-X33;
USEVARIABLE ARE X11-X13 X21-X23 X31-X33;
MISSING=ALL (99);
ANALYSIS: ESTIMATOR=MLM;
MODEL: X1 BY X11-X13 (1-3);
X2 BY X21-X23 (1-3);
X3 BY X31-X33 (1-3); ! 加设因子负荷等值，通过相同的数字设定负荷等值
X11-X13 PWITH X21-X23;
X11-X13 PWITH X31-X33;
X21-X23 PWITH X31-X33; ! 允许不同时间点同一指标的误差相关
OUTPUT: SAMPSTAT MOD STANDARDIZED CINTERVAL;
- (number) 限定参数相等
- F1 BY X1-X5 (1-5);
- F2 BY X6-X10 (1-5);
- 上述语句表明，条目X2和X7，X3和X8……的负荷设定为相等，条目X1和X6的负荷程序默认为1
尺度等值/强等值语句
TITLE: This is an example of a longitudinal invariance;
DATA: FILE IS XXX.dat;
VARIABLE: NAMES ARE X11-X13 X21-X23 X31-X33;
USEVARIABLE ARE X11-X13 X21-X23 X31-X33;
MISSING=ALL (99);
ANALYSIS: ESTIMATOR=MLM;
MODEL: X1 BY X11-X13 (1-3);
X2 BY X21-X23 (1-3);
X3 BY X31-X33 (1-3); ! 加设因子负荷等值，通过相同的数字设定负荷等值
X11-X13 PWITH X21-X23;
X11-X13 PWITH X31-X33;
X21-X23 PWITH X31-X33; ! 允许不同时间点同一指标的误差相关
[X11 X21 X31] (4);
[X12 X22 X32] (5);
[X13 X23 X33] (6); ! 加设截距等值
[X2*]; [X3*]; ! 由于前两步Mplus默认因子均值为0，从第三步开始只默认第一组的因子均值为0，其他组自由估计。
! 然而我们的数据采用“单组模型”，所以第二次测量的因子均值也被当做第一组因子处理了。
! 因此在这里开始加上第二次、第三次因子均值自由估计的语句。
OUTPUT: SAMPSTAT MOD STANDARDIZED CINTERVAL;
- 通过[list of variables]表示均值、截距或阈限值，通过(number)相同的数字设定项目截距等值
- [X1 X2 X3]表示估计X1 X2 X3的均值、截距或阈限
- * 指定开始值或将默认值设置改成自由估计
- X* 自由估计
- X*0.6 将X的起始值设定为0.6
误差方差等值语句
TITLE: This is an example of a longitudinal invariance;
DATA: FILE IS XXX.dat;
VARIABLE: NAMES ARE X11-X13 X21-X23 X31-X33;
USEVARIABLE ARE X11-X13 X21-X23 X31-X33;
MISSING=ALL (99);
ANALYSIS: ESTIMATOR=MLM;
MODEL: X1 BY X11-X13 (1-3);
X2 BY X21-X23 (1-3);
X3 BY X31-X33 (1-3); ! 加设因子负荷等值，通过相同的数字设定负荷等值
X11-X13 PWITH X21-X23;
X11-X13 PWITH X31-X33;
X21-X23 PWITH X31-X33; ! 允许不同时间点同一指标的误差相关
[X11 X21 X31] (4);
[X12 X22 X32] (5);
[X13 X23 X33] (6); ! 加设截距等值
[X2*]; [X3*]; ! 第二次和第三次的因子均值自由估计
X11 X21 X31 (7);
X12 X22 X32 (8);
X13 X23 X33 (9); ! 加设误差方差等值，通过相同的数字设定误差方差等值
! list of variables 定义方差或者残差方差，当变量是自变量时为方差，当为因变量时为残差方差
OUTPUT: SAMPSTAT MOD STANDARDIZED CINTERVAL;
模型比较
通过模型比较，来确定测量工具满足哪个层面的不变性。
拟合指数差异的方法检验测量等值，常用指标有：
1. 卡方差异检验差异不显著：Crawford和Henry(2004)制作的SBDIFF.EXE差异检验程序
Computer program for Satorra-Bentler scaled difference chi square test
In the current study, we fitted the longitudinal configural →weak invariance → strong invariance → strict invariance models in sequence. The fitness of each of the invariance models was evaluated with global fit indices and ∆χ2 tests. Specifically, the configural invariance assumption was evaluated with global fitness of the configural invariance. The fitness of other invariance models was evaluated with ∆χ2 tests. An invariance assumption held if its corresponding ∆χ2 test result was nonsignificant (p > .05).
2. ∆RMSEA < 0.015，∆CFI < 0.01
The nested longitudinal invariance models were evaluated using Chen (2007) recommendations that change in CFI (ΔCFI) of less than 0.01 and change in RMSEA (ΔRMSEA) of less than 0.015 or a change in SRMR (ΔSRMR) of less than 0.030 would support metric invariance. For scalar and strict invariance a change in CFI (ΔCFI) of less than 0.01 and change in RMSEA (ΔRMSEA) of less than 0.015 or a change in SRMR (ΔSRMR) of less than 0.010 would indicate invariance across time (Stenling et al., 2018).
We used the criteria suggested by Chen et al. (2008): a decrease in CFI of <0.01, and an increase in RMSEA of <0.015 was taken as an unacceptable decrease of model fit (de Beurs et al., 2015).
Specifically, following previous recommendations [16], a decrease in CFI of ≥ 0.01 and an increase in RMSEA of ≥ 0.015 was considered unacceptable to establish measurement invariance (Moreira et al., 2018).
希望上述介绍可以帮助到你！也欢迎大家在评论区多多交流分享。
你的关注/点赞 /收藏★/分享，是最大的支持！
6763
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
