ABB机器人与PLC进行ModbusTCP通信--Float浮点数据传输

森林KING

已于 2023-05-22 15:33:29 修改

阅读量7.2k

点赞数 3

文章标签：机器人 tcp/ip c#

于 2023-05-22 09:32:24 首次发布

本文链接：https://blog.csdn.net/m0_67136031/article/details/130793277

版权

一、引言

abb机器人的编程语言中没有专为Modbustcp写的函数，这一点和博图PLC不同。abb机器人想要进行Modbustcp通信使用的还是Socket通信发送和接收信息的方式，同时需要自己去在示教器或者RobotStudio仿真软件中搭建ModbusTcp程序框架，这和使用VS编写Modbustcp通信程序相似。以下内容主要讲述是abb机器人和上位机视觉平台为客户端，PLC为服务器进行Modbustcp通信的03功能码的通信，其他功能码类似。Modbustcp的功能码介绍可以看一下03功能码

二、Float数据类型传输

首先要知道的是Float数据类型占4个字节，Modbustcp的一个线圈寄存器占2个字节，也就是说一个浮点Float数据要占用2个线圈寄存器。
RobotStudios编写modbustcp框架：

03功能框架：
slaveID为单元识别码 start为起始地址 length为读取寄存器的个数
在这里插入图片描述
其中SendSocket模块： ip地址为自己电脑ip地址前三位相同后一位可以随意我这里填181
端口号：502

Get32Float模块： 也就是发送之后，服务器返回的数据要进行解析
将字节数组转为浮点类型数据

主程序：读取两个浮点数据，需要读取length：4个寄存器，占用8个字节
在这里插入图片描述
程序代码如下：

MODULE Module1
    VAR socketdev socket1;
    VAR num slaveID;
    VAR num start;
    VAR num length;
    VAR num value;
    PERS num arrayValue{10};  
    PROC main()    
       slaveID:=1;
       start:=0;
       length:=4;
       ReadHoldingRegister slaveID,start,length;
    ENDPROC


    PROC ReadHoldingRegister(num slaveID,num start,num length)
        VAR byte byte_send{12};
        VAR byte byte_receive{20};
        
        byte_send{1}:=0X00;
        byte_send{2}:=0X00;
        byte_send{3}:=0X00;
        byte_send{4}:=0X00;
        byte_send{5}:=0X00;
        byte_send{6}:=0X06;
        byte_send{7}:=slaveID;
        byte_send{8}:=0X03;
        byte_send{9}:=start div 256;
        byte_send{10}:=start mod 256;
        byte_send{11}:=length div 256;
        byte_send{12}:=length mod 256;    
        SendSocket byte_send,byte_receive;
        TPWrite Get32Float(byte_receive,length);
    ENDPROC
    
    
    FUNC string Get32Float(byte recebuffer{*},num length)
        VAR byte receive{4};
        VAR rawbytes raw_data;
        VAR num value;
        VAR string str;
        VAR num nCount:=1;
        FOR i FROM 1 TO length*2 STEP 4 DO 
            FOR j FROM 1 TO 4 DO 
                receive{j}:=recebuffer{9+i+(j-1)};
            ENDFOR
            ClearRawBytes raw_data;
            PackRawBytes receive{4},raw_data,(RawBytesLen(raw_data)+1)\Hex1;
            PackRawBytes receive{3},raw_data,(RawBytesLen(raw_data)+1)\Hex1;
            PackRawBytes receive{2},raw_data,(RawBytesLen(raw_data)+1)\Hex1;
            PackRawBytes receive{1},raw_data,(RawBytesLen(raw_data)+1)\Hex1;
            UnpackRawBytes raw_data,1,value\Float4;
            arrayValue{nCount}:=value;
            Incr nCount;
            str:=str+NumToStr(value,3)+"";     
        ENDFOR
        RETURN str;
    ENDFUNC
    
ENDMODULE