【NOIP2003提高组】加分二叉树

Description

　　设一个n个节点的二叉树tree的中序遍历为（l,2,3,…,n），其中数字1,2,3,…,n为节点编号。每个节点都有一个分数（均为正整数），记第j个节点的分数为di，tree及它的每个子树都有一个加分，任一棵子树subtree（也包含tree本身）的加分计算方法如下：
　　subtree的左子树的加分× subtree的右子树的加分＋subtree的根的分数
　　若某个子树为主，规定其加分为1，叶子的加分就是叶节点本身的分数。不考虑它的空子树。
　　试求一棵符合中序遍历为（1,2,3,…,n）且加分最高的二叉树tree。要求输出：
　　（1）tree的最高加分
　　（2）tree的前序遍历

Input

　　第1行：一个整数n（n ＜ 30），为节点个数。
　　第2行：n个用空格隔开的整数，为每个节点的分数（分数 ＜ 100）。

Output

　　第1行：一个整数，为最高加分（结果不会超过4,000,000,000）。
　　第2行：n个用空格隔开的整数，为该树的前序遍历。

Sample Input

5
5 7 1 2 10

Sample Output

145
3 1 2 4 5

没什么说的，树形动归。
f[i,j]表示i节点到j节点的最大加分树。
f[i,j]可有三种来源
1，i做父节点，i+1 到 j 做它的右子树
2，k做父节点，i 到 k-1 做它的左子树，k+1 到 j 做它的右子树
3，j做父节点，i 到 j-1 做它的左子树

所以 f[i,j]={f[i,i]+f[i+1,j], f[i+k,i+k]+f[i,k-1]*f[k+1,j], f[j,j]+f[i,j-1]}  (i<k<j)

var
 n,i,j,k,max:longint;//i表示上述i；j表示上述k；k+i表示上述j；
 f,root:array[1..31,1..31]of longint;// root 记录 i 到 j 最大加分树的父节点

procedure print(l,r:longint);//递归输出
begin
 if (l>r)or(l=0) then exit;
 write(root[l,r],' ');
 print(l,root[l,r]-1);
 print(root[l,r]+1,r);
end;

begin
 read(n);
 for i:=1 to n do read(f[i,i]);
 for i:=1 to n do root[i,i]:=i;
 for k:=1 to n-1 do
  for i:=1 to n-k do
   begin
   max:=f[i,i]+f[i+1,i+k];//第一种情况
   root[i,i+k]:=i;
   for j:=i+1 to i+k-1 do//第二种情况
    if f[j,j]+f[i,j-1]*f[j+1,i+k]>max then
     begin
     max:=f[j,j]+f[i,j-1]*f[j+1,i+k];
     root[i,i+k]:=j;
     end;
   if f[i+k,i+k]+f[i,i+k-1]>max then//第三种情况
    begin
     max:=f[i+k,i+k]+f[i,i+k-1];
     root[i,i+k]:=i+k;
     end;
   f[i,i+k]:=max;
   end;
  writeln(f[1,n]);
  print(1,n);
end.

 

写得仓促，难免有问题，如有发现，请评论告知。

或有何感想，也欢迎吐槽..