根据RemObject的远程方法调用原理实现的简单远程方法调用

最新推荐文章于 2023-01-21 10:33:23 发布
最新推荐文章于 2023-01-21 10:33:23 发布
阅读量3.4k 收藏 5
点赞数
分类专栏： DELPHI 文章标签： integer string interface function byte class
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/michelsn/article/details/1819491
版权

                     根据RemObject的远程方法调用原理实现的简单远程方法调用

                              作者:俞伟      QQ:183088201     邮件:yu924@hotmail.com

 

以下是根据RemObject的远程方法调用原理实现的简单远程方法调用的内容及代码：

因为在RemObject中，调用远程方法需要三个单元，即：XXX_Intf,XXX_Invk,XXX_Impl

（1）XXX_Intf主要是服务接口声明和代理类定义及实现。

（2）XXX_Invk主要是实现了具体的方法执行

（3）XXX_Impl主要是服务接口的具体实现

因为本人比较懒惰，没有像RemObject那样分的那么具体。本文主要讲述远程方法调用的简单实现，让大家可以看出调用的原理，而且实现的代码简单，大家可以通过阅读代码就可以看出相关的原理。

以下是具体的代码：

客户端通过代理类调用

procedure TForm1.Button1Click(Sender: TObject);
var
  iA, iB, iC: Integer;
  obj: TMathFunc_Proxy; //代理类
begin
  iA := StrToInt(Edit1.Text);
  iB := StrToInt(Edit2.Text);
  obj := TMathFunc_Proxy.Create;
  try
    iC := obj.Sum(iA, iB);
  finally
    FreeAndNil(obj);
  end;
  Edit3.Text := IntToStr(iC);
end;

代理类负责构造传递和接收处理与远程服务的交互信息：

function TMathFunc_Proxy.Sum(const A, B: Integer): Integer;
var
  strModuleName,
  strInterfaceName,
  strMethodName: string;
  DNAMessage: TDNAMessage;
begin
  //创建消息交互对象
  DNAMessage := TDNAMessage.Create;
  try
    //创建新的方法调用消息
    DNAMessage.CreateMessage('Test', 'MathFunc', 'Sum');
    //往消息中写入参数值
    DNAMessage.Write('A', TypeInfo(Integer), A);
    DNAMessage.Write('B', TypeInfo(Integer), B);
    //分发传递消息
    DNAMessage.Distributed(DNAMessage.MessageStream);
    //从方法请求结果消息返回的消息中提取相关结果
    DNAMessage.Read('', TypeInfo(string), strModuleName);
    DNAMessage.Read('', TypeInfo(string), strInterfaceName);
    DNAMessage.Read('', TypeInfo(string), strMethodName);
    DNAMessage.Read('Result', TypeInfo(Integer), Result);
  finally
    //销毁方法调用消息
    if Assigned(DNAMessage.MessageStream) then
      DNAMessage.DestroyMessage;
    //销毁消息交互对象
    FreeAndNil(DNAMessage);
  end;  
end;

TDNAMessage类负责消息的序列化和反序列化过程，不过本文中因为没有具体的去实现TCP等协议的通信管道，所以直接在TDNAMessage类的方法Distributed中模拟了整个调用过程中的客户端发送 -> 服务端接收、处理、返回 -> 客户端接收、处理的过程

方法原型：
    procedure Distributed(aStream: TStream);

代码：

procedure TDNAMessage.Distributed(aStream: TStream);
var
  strModuleName,
  strInterfaceName,
  strMethodName: string;
  iA, iB, iC: Integer;
  obj: TMathFunc;
begin
  //在这里我们可以写把方法请求交互消息传递给远程服务
  { TODO -omichelsn -c :  2007-10-11 8:45:24 }

  //此处代码模拟远程服务在接收到客户端发送的方法请求交互消息及相应处理过程
  //-------------------------------------------------------------Begin
  aStream.Position := 0;
  //读取要调用的模块/接口/方法名称等信息
  Read('', TypeInfo(string), strModuleName);
  Read('', TypeInfo(string), strInterfaceName);
  Read('', TypeInfo(string), strMethodName);
  //读取要调用的方法的参数信息
  Read('A', TypeInfo(Integer), iA);
  Read('B', TypeInfo(Integer), iB);
  //调用具体的方法来计算
  obj := TMathFunc.Create;
  try
    iC := obj.Sum(iA, iB);
  finally
    FreeAndNil(obj);
  end;
  //创建法请求交互结果消息
  CreateMessage(strModuleName, strInterfaceName, strMethodName);
  //写入方法调用的结果值
  Write('Result', TypeInfo(Integer), iC);
  aStream.Position := 0;
  //------------------------------------------------------------End
  //在这里我们可以写把方法请求交互结果消息传递给客户端服务
  { TODO -omichelsn -c :  2007-10-11 8:45:16 }

  //在这里我们可以写客户端接收远程服务发送的方法请求交互结果消息
  { TODO -omichelsn -c :  2007-10-11 8:46:48 }
 
end;

以下是全部的源代码：

Unit1单元（客户端调用单元）

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, TypInfo, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Edit1: TEdit;
    Edit2: TEdit;
    Edit3: TEdit;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

uses
  Unit2;
{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
  iA, iB, iC: Integer;
  obj: TMathFunc_Proxy;
begin
  iA := StrToInt(Edit1.Text);
  iB := StrToInt(Edit2.Text);
  obj := TMathFunc_Proxy.Create;
  try
    iC := obj.Sum(iA, iB);
  finally
    FreeAndNil(obj);
  end;
  Edit3.Text := IntToStr(iC);
end;

end.

Unit2单元（类似RemObject中的XXX_Intf,XXX_Impl）

unit Unit2;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes;

type
  //MathFunc接口
  IMathFunc = interface(IUnKnown)
  ['{30A624D5-4DA0-43FF-B210-5D5BCAFC5593}']
    function Sum(const A, B: Integer): Integer; stdcall;
  end;

  //MathFunc实现类
  TMathFunc = class(TInterfacedObject, IMathFunc)
  public
    function Sum(const A, B: Integer): Integer; stdcall;
  end;

  //MathFunc代理类
  TMathFunc_Proxy = class(TInterfacedObject, IMathFunc)
  public
    function Sum(const A, B: Integer): Integer; stdcall;
  end;

implementation

uses
  Unit3;
{ TMathFunc }

function TMathFunc.Sum(const A, B: Integer): Integer;
begin
  Result := A + B;
end;

{ TMathFunc_Proxy }

function TMathFunc_Proxy.Sum(const A, B: Integer): Integer;
var
  strModuleName,
  strInterfaceName,
  strMethodName: string;
  DNAMessage: TDNAMessage;
begin
  //创建消息交互对象
  DNAMessage := TDNAMessage.Create;
  try
    //创建新的方法调用消息
    DNAMessage.CreateMessage('Test', 'MathFunc', 'Sum');
    //往消息中写入参数值
    DNAMessage.Write('A', TypeInfo(Integer), A);
    DNAMessage.Write('B', TypeInfo(Integer), B);
    //分发传递消息
    DNAMessage.Distributed(DNAMessage.MessageStream);
    //从方法请求结果消息返回的消息中提取相关结果
    DNAMessage.Read('', TypeInfo(string), strModuleName);
    DNAMessage.Read('', TypeInfo(string), strInterfaceName);
    DNAMessage.Read('', TypeInfo(string), strMethodName);
    DNAMessage.Read('Result', TypeInfo(Integer), Result);
  finally
    //销毁方法调用消息
    if Assigned(DNAMessage.MessageStream) then
      DNAMessage.DestroyMessage;
    //销毁消息交互对象
    FreeAndNil(DNAMessage);
  end;  
end;

end.

Unti3单元（本单元实现了消息创建、序列化和发送返回的过程，类似RemObject中的TROMessage, TROStreamSerializer,和TROSerializer等类的对消息创建、序列化、发送返回的实现过程）

unit Unit3;

interface

uses
  SysUtils, Classes, TypInfo;

type
  IDNAMessage = interface(IUnKnown)
    //读-写整型参数值
    procedure ReadInteger(aName: string; anOrdType : TOrdType; var Ptr);
    procedure WriteInteger(aName: string; anOrdType : TOrdType; const Ptr);
    //读-写字符串型参数值
    procedure ReadString(aName: string; anOrdType : TOrdType; var Ptr);
    procedure WriteString(aName: string; anOrdType : TOrdType; const Ptr);
    //读写参数值入口方法
    procedure Write(aName: string; aType : PTypeInfo; const Ptr);
    procedure Read(aName: string; aType : PTypeInfo; var Ptr);
  end;

  TDNAMessage = class(TInterfacedPersistent, IDNAMessage)
  private
    fStream: TStream;
    procedure ReadInteger(aName: string; anOrdType : TOrdType; var Ptr);
    procedure WriteInteger(aName: string; anOrdType : TOrdType; const Ptr);
    procedure ReadString(aName: string; anOrdType : TOrdType; var Ptr);
    procedure WriteString(aName: string; anOrdType : TOrdType; const Ptr);
  public
    //创建新的方法调用消息
    procedure CreateMessage(aModuleName, aInterfaceName, aMethodName: string);
    //销毁方法调用消息
    procedure DestroyMessage;

    procedure Write(aName: string; aType : PTypeInfo; const Ptr);
    procedure Read(aName: string; aType : PTypeInfo; var Ptr);
    //分发传递消息
    procedure Distributed(aStream: TStream);
    //具体的交互消息
    property MessageStream: TStream read fStream default nil;
  end;

implementation

uses Unit2;
{ TDNAMessage }

procedure TDNAMessage.CreateMessage(aModuleName, aInterfaceName,
  aMethodName: string);
begin
  if Assigned(fStream) then
    FreeAndNil(fStream);
  fStream := TMemoryStream.Create;
  fStream.Position := 0;
  Write('', TypeInfo(string), aModuleName);
  Write('', TypeInfo(string), aInterfaceName);
  Write('', TypeInfo(string), aMethodName);
end;

procedure TDNAMessage.DestroyMessage;
begin
  if Assigned(fStream) then
    FreeAndNil(fStream);
end;

procedure TDNAMessage.Distributed(aStream: TStream);
var
  strModuleName,
  strInterfaceName,
  strMethodName: string;
  iA, iB, iC: Integer;
  obj: TMathFunc;
begin
  //在这里我们可以写把方法请求交互消息传递给远程服务
  { TODO -omichelsn -c :  2007-10-11 8:45:24 }

  //此处代码模拟远程服务在接收到客户端发送的方法请求交互消息及相应处理过程
  //-------------------------------------------------------------Begin
  aStream.Position := 0;
  //读取要调用的模块/接口/方法名称等信息
  Read('', TypeInfo(string), strModuleName);
  Read('', TypeInfo(string), strInterfaceName);
  Read('', TypeInfo(string), strMethodName);
  //读取要调用的方法的参数信息
  Read('A', TypeInfo(Integer), iA);
  Read('B', TypeInfo(Integer), iB);
  //调用具体的方法来计算
  obj := TMathFunc.Create;
  try
    iC := obj.Sum(iA, iB);
  finally
    FreeAndNil(obj);
  end;
  //创建法请求交互结果消息
  CreateMessage(strModuleName, strInterfaceName, strMethodName);
  //写入方法调用的结果值
  Write('Result', TypeInfo(Integer), iC);
  aStream.Position := 0;
  //------------------------------------------------------------End
  //在这里我们可以写把方法请求交互结果消息传递给客户端服务
  { TODO -omichelsn -c :  2007-10-11 8:45:16 }

  //在这里我们可以写客户端接收远程服务发送的方法请求交互结果消息
  { TODO -omichelsn -c :  2007-10-11 8:46:48 }
 
end;

procedure TDNAMessage.Read(aName: string; aType: PTypeInfo; var Ptr);
begin
  case aType^.Kind of
    tkInteger: ReadInteger(aName, GetTypeData(aType)^.OrdType, Ptr);
    tkLString, tkString: ReadString(aName, GetTypeData(aType)^.OrdType, Ptr);
  end;
end;

procedure TDNAMessage.ReadInteger(aName: string; anOrdType : TOrdType;
  var Ptr);
var sze : byte;
    src : pointer;
begin
  src := @Ptr;
  sze := 0;
  case anOrdType of
    otSByte,
    otUByte : sze := SizeOf(byte);
    otSWord,
    otUWord : sze := SizeOf(word);
    otSLong,
    otULong : sze := SizeOf(integer);
  end;
  fStream.ReadBuffer(src^, sze);
end;

procedure TDNAMessage.ReadString(aName: string; anOrdType: TOrdType;
  var Ptr);
var
  sze : integer;
begin
  sze := 0;
  fStream.ReadBuffer(sze, SizeOf(sze));
  if (sze>0) then begin
    SetLength(string(Ptr), sze);
    fStream.ReadBuffer(string(Ptr)[1], sze);
  end
  else string(Ptr) := '';
end;

procedure TDNAMessage.Write(aName: string; aType: PTypeInfo; const Ptr);
begin
  case aType^.Kind of
    tkInteger: WriteInteger(aName, GetTypeData(aType)^.OrdType, Ptr);
    tkLString, tkString: WriteString(aName, GetTypeData(aType)^.OrdType, Ptr);
  end;
end;

procedure TDNAMessage.WriteInteger(aName: string; anOrdType : TOrdType;
  const Ptr);
var
  sze : byte;
  src : pointer;
begin
  { ToDo: make sure a Integer is always marshaled as Int32 }

  src := @Ptr;
  sze := 0;
  case anOrdType of
    otSByte,
    otUByte : sze := SizeOf(byte);
    otSWord,
    otUWord : sze := SizeOf(word);
    otSLong,
    otULong : sze := SizeOf(integer);
  end;

  fStream.Write(src^, sze);
end;

procedure TDNAMessage.WriteString(aName: string; anOrdType: TOrdType;
  const Ptr);
var
  sze : integer;
begin
  sze := Length(string(Ptr));
  fStream.Write(sze, SizeOf(sze));
  if (sze > 0) then
    fStream.Write(string(Ptr)[1], sze);
end;

end.

 

以上是我这些天学习RO得到的点心得，请大家多多指教

伟伟

SZ大伟
关注
  • 0
    点赞
  • 踩
  • 5
    收藏
    觉得还不错? 一键收藏
  • 1
    评论
专栏目录
RemObject全解学习教程
01-01
很全的RemObjects全解学习教程，可学习到最全的RemObjects使用
delphi下用remobject实现网络线程同步
01-06
RemObjects是EldoS公司开发的一个跨平台的.NET、Java、Objective-C、Swift、C#、Delphi和Python之间的中间件，它提供了一种简单的方式来实现跨语言的远程过程调用（RPC）。通过RemObjects，你可以创建服务端并暴露...
remobject 簡介
06-23 517
許多使用Web Services 開發系統的人都會有一個困擾，那就是效率不高，其原因很簡單，XML 本身屬於純文字型態，加上必須依賴XML Parser 剖析XML 文件，在傳輸與解譯上都是造成效率不彰的原因，這是Web Services 的先天限制，也是為了相容性所付出的代價。當然! 如果網路頻寬夠大，電腦速度夠快，這些都不是問題。但事實是目前的頻寬與電腦速度還不足以勝任，這使得Web Se
RemObject解决自动生成代码的想法
最新发布
shsh1234567890的博客
01-21 61
RemObject解决自动生成代码的想法
RemObjects SDK for Delphi
q2315702359的博客
11-21 616
RemObjects SDK的所有版本都包含Service Builder，这是一种RAD服务建模工具，允许您使用高效的跨平台RemObjects定义语言(RODL)轻松定义服务的接口。RemObjects SDK for Delphi是一个完全管理的库，它使您能够为Delphi/FPC、.NET和Mono平台构建完全管理的多层服务器和客户端。平台之间的完全有线兼容性，允许您混合使用不同版本的SDK或在不同操作系统上运行的客户端和服务器。用于建模和定义服务的RAD服务生成器工具。真正的RAD服务建模。
RemObject中文全解_DA00-32
10-09
在“RemObject中文全解_DA00-32”中，你将深入学习如何设置RemObjects项目，配置服务器和客户端，以及创建和调用远程方法。内容可能涵盖以下方面： 1. 安装和配置RemObjects SDK：讲解如何在开发环境中安装...
RemObject中文全解_HY01-06
10-09
- RemObjects是一种中间件，它提供了一种标准化的方式，使得不同编程语言可以相互通信，实现远程调用和数据交换。 - 它支持多种平台和语言，包括C#、Delphi、Swift、Objective-C、Java等，实现了语言之间的无缝...
RemObject for delphi 7.0
04-06
RemObjects SDK是一个全面的开发工具包，它包含了一系列组件和服务，用于实现对象之间的远程方法调用（Remote Method Invocation，RMI）。这种技术允许开发者在不同的进程、计算机甚至网络之间透明地调用对象的方法...
delphi实例remobject_javascript.
04-01
RemObjects是面向对象的跨平台通信库，它允许开发者在不同语言之间进行远程方法调用（RPC），在这个案例中，它被用来连接Delphi和JavaScript环境，使得Delphi应用可以为Java、Android等平台提供JavaScript接口。...
remobject 三层简单示例
10-18
remobject 三层简单示例 remobject 简单入门例子
RemObject SDK 说明书(中文版)
10-13
RemObject SDK 说明书 中文版 这东东的使用说明资源真的很少,整理了下
Delphi + RemObjects 实现软件智能更新
05-18
智能更新完整源码，包含： 1 更新包制作 2 更新服务器 3 更新客户端 可单独使用，也可以嵌入到其他代码中。
RemObject全解-中文
02-23
RemObject全解-中文 .
RemObject手册.chm
01-07
英文版滴，注意了，不是API文档啊。自己看吧。
使用 RemObjects SDK 建立 WebService 应用
shaily读书学习
02-19 2817
终于又静下心来写了个图文教程，这几天事情太多，头脑混乱，截图都不会了。。。。大家还是见好就收吧。。本文为本站原创，转载请注明出处！ By Rarnu 2007-7-251. 准备工作　　首先下载 RemObjects SDK，我用的是 4.0.19 版，可以安装在 Delphi2007 中。用其他版本 delphi 的也可以下载 4.0.19，用起来效果一样的。需要注意的是，Rem
RemObject 介绍
11-20 254
目前的频宽与计算机速度还不足以胜任，这使得Web Services 的应用面缩减不少，因此许多的Web Servcies开发工具都会提供将SOAP讯息压缩的解决方案，藉此减少网络传输时间。另一个问题则是Web Services 必须依赖网络通讯协议，以现今的情况来看是以HTTP或TCP两种网络通讯协议为主流，假如客户想将系统安装于一台计算机上(不管是何理由，或许是因为节省金钱)，Web ...
RemObjects（一）客户端远程调用服务端接口过程
weixin_30696427的博客
12-13 264
RemObjects SDK 是高度封装的产物，对OOP发挥极致。 本文将以RemObjects SDK最简单的DEMO——FirstSample为例， 介绍客户端是如何完成远程调用服务端接口的全过程。 也理解为什么可以通过不同传输通道（TCP/HTTP...)，不同消息格式（二进制，SOAP...) 与服务端进行通讯 客户端就这三个RO控件，是如何完成一个完整的调用过程的呢...
在delphi中嵌入脚本语言--(译)RemObjects Pascal Script使用说明(1)(译)
hksoobe的专栏
03-29 5773
在delphi中嵌入脚本语言--(译)RemObjects Pascal Script使用说明(1)(译) 翻译这篇文章源于我的一个通用工资计算平台的想法，在工资的计算中，不可避免的需要使用到自定义公式，然而对于自定义公式的实现，我自己想了一些，也在网上搜索了很多，解决办法大致有以下几种： 1. 自己写代码去解析公式。这种方法的缺点是，解析的代码很难实现，如果公式的功能比较完整，如增加条件
RemObject认证服务端程序编写步骤.doc
02-13
2. 应用服务：这部分是核心业务逻辑，用户编写的特定方法，如getSessionID，需要在用户成功登录后才能调用。此外，还创建了一个名为LogServices的服务，包含了login和logout方法，分别用于验证用户登录状态和注销。 ...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论 1
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值