032 Visual Basic 访问者模式之男女之别

1.‘状态’的抽象类和‘人’的抽象类

Public MustInherit Class Action
    Public MustOverride Sub GetManConclusion(ByVal concreteElementA As Man)
    Public MustOverride Sub GetWomanConclusion(ByVal concreteElementB As Woman)
End Class

Public MustInherit Class Person
    Public MustOverride Sub Accept(ByVal visitor As Action)
End Class

2.具体“状态”类

Public Class Success
    Inherits Action

    Public Overloads Overrides Sub GetManConclusion(ByVal concreteElementA As Man)
        Console.WriteLine("{0}{1}时，背后多半有一个伟大的女人", concreteElementA.GetType.Name, Me.GetType.Name)
    End Sub

    Public Overloads Overrides Sub GetWomanConclusion(ByVal concreteElementA As Woman)
        Console.WriteLine("{0}{1}时，背后多半有一个不成功的男人", concreteElementA.GetType.Name, Me.GetType.Name)
    End Sub
End Class


Public Class Failing
    Inherits Action

    Public Overloads Overrides Sub GetManConclusion(ByVal concreteElementA As Man)
        Console.WriteLine("{0}{1}时，闷头喝酒，谁也不用劝", concreteElementA.GetType.Name, Me.GetType.Name)
    End Sub

    Public Overloads Overrides Sub GetWomanConclusion(ByVal concreteElementB As Woman)
        Console.WriteLine("{0}{1}时，眼泪汪汪，谁也劝不了", concreteElementB.GetType.Name, Me.GetType.Name)
    End Sub
End Class


Public Class Amativeness
    Inherits Action

    Public Overloads Overrides Sub GetManConclusion(ByVal concreteElementA As Man)
        Console.WriteLine("{0}{1}时，凡事不懂也要装懂", concreteElementA.GetType.Name, Me.GetType.Name)
    End Sub

    Public Overloads Overrides Sub GetWomanConclusion(ByVal concreteElementB As Woman)
        Console.WriteLine("{0}{1}时，遇事懂也装作不懂", concreteElementB.GetType.Name, Me.GetType.Name)
    End Sub
End Class

3.“男人”类和“女人”类

Public Class Man
    Inherits Person

    Public Overrides Sub Accept(ByVal visitor As Action)
        visitor.GetManConclusion(Me)
    End Sub
End Class
Public Class Woman
    Inherits Person

    Public Overrides Sub Accept(ByVal visitor As Action)
        visitor.GetWomanConclusion(Me)
    End Sub
End Class

4.对象结构类

Public Class ObjectStructure
    Private elements As IList(Of Person) = New List(Of Person)
    Public Sub Attach(ByVal element As Person)
        elements.Add(element)
    End Sub

    Public Sub Detach(ByVal element As Person)
        elements.Remove(element)
    End Sub

    Public Sub Display(ByVal visitor As Action)
        For Each e In elements
            e.Accept(visitor)
        Next
    End Sub
End Class

5.客户端代码

Module Module1

    Sub Main()
        Dim o As New ObjectStructure
        o.Attach(New Man)
        o.Attach(New Woman)

        Dim v1 As New Success
        o.Display(v1)

        Dim v2 As New Failing
        o.Display(v2)

        Dim v3 As New Amativeness
        o.Display(v3)

        Console.Read()

    End Sub

End Module