在ABAP中使用表达式操作内表（替代READ TABLE）

在传统的ABAP代码中，通常使用READ TABLE来访问某一条内表数据，使用LOOP来访问多条数据。其实，在ABAP中也可以使用表达式的方式来操作内表，以使得代码更简洁。

在本篇博客中，汇总了常用的内表表达式，并给出了与READ TABLE的相对比的写法，供读者参考。
主要包括：

• 使用内表表达式[ ]访问内表数据；
• 使用关键在VALUE和BASE为内表赋值；
• 使用在VALUE关键字中使用FOR实现LOOP循环赋值；
• 常用的built-in表达式lines_index( )和lines_exist( ).

（1）使用内表表达式[ ]访问内表数据, 索引访问或键值访问。

需要注意的是，在使用表达式的方式访问内表时，若内表内容未找到，并不会给sy-subrc返回值。而是会抛出异常cx_sy_itab_line_not_found。

DATA: lt_sflight        TYPE STANDARD TABLE OF sflight,
      lt_sflight_sorted TYPE SORTED TABLE OF sflight WITH UNIQUE KEY carrid connid fldate,
      ls_sflight        TYPE sflight.

SELECT * FROM sflight INTO TABLE lt_sflight WHERE carrid = 'AA'.
SELECT * FROM sflight INTO TABLE lt_sflight_sorted WHERE carrid = 'AA'.

* Index access
READ TABLE lt_sflight INTO ls_sflight INDEX 1.

ls_sflight = lt_sflight[ 1 ].

* key access
READ TABLE lt_sflight INTO ls_sflight
                  WITH KEY carrid = 'AA'
                           connid = '0017'.

ls_sflight = lt_sflight[ carrid = 'AA' connid = '0017' ].

* table key access
READ TABLE lt_sflight_sorted INTO ls_sflight
                     WITH TABLE KEY carrid = 'AA'
                                    connid = '0017'
                                    fldate = '20180127'.

ls_sflight = lt_sflight_sorted[ KEY primary_key
                                COMPONENTS
                                    carrid = 'AA'
                                    connid = '0017'
                                    fldate = '20180433' ].

（2）使用VALUE和BASE为内表赋值

**********************************************************************
* Value & Base
**********************************************************************
DATA: lt_sflight        TYPE STANDARD TABLE OF sflight,
      lt_sflight_sorted TYPE SORTED TABLE OF sflight WITH UNIQUE KEY carrid connid fldate,
      ls_sflight        TYPE sflight.

SELECT * FROM sflight INTO TABLE lt_sflight WHERE carrid = 'AA'.
SELECT * FROM sflight INTO TABLE lt_sflight_sorted WHERE carrid = 'AA'.

ls_sflight-carrid = 'AZ'.
ls_sflight-connid = '0788'.
ls_sflight-fldate = '20171123'.
APPEND ls_sflight TO lt_sflight.

lt_sflight = VALUE #( ( carrid = 'AZ' connid = '0788' fldate = '20171123' ) ).

lt_sflight = VALUE #( BASE lt_sflight
                      ( carrid = 'AZ' connid = '0788' fldate = '20171123' )
                    ).

(3) 使用在VALUE关键字中使用FOR实现循环LOOP赋值

**********************************************************************
* For expression
**********************************************************************
DATA: lt_sflight      TYPE STANDARD TABLE OF sflight,
      ls_sflight      TYPE sflight,
      lt_connid_range TYPE RANGE OF sflight-connid,
      ls_connid_range LIKE LINE OF lt_connid_range.

SELECT * FROM sflight INTO TABLE lt_sflight WHERE carrid = 'AA' OR carrid = 'AZ'.

LOOP AT lt_sflight INTO ls_sflight WHERE carrid = 'AZ'.
  ls_connid_range-sign   = 'I'.
  ls_connid_range-option = 'EQ'.
  ls_connid_range-low    = ls_sflight-connid.
  ls_connid_range-high   = ''.
  APPEND ls_connid_range TO lt_connid_range.
ENDLOOP.

CLEAR: lt_connid_range.
lt_connid_range = VALUE #( FOR line IN lt_sflight WHERE ( carrid = 'AZ' )
                           ( sign = 'I' option = 'EQ' low = line-connid high   = '' )
                         ).

(4) 两个常用的built-in表达式lines_index()和lines_exist.

**********************************************************************
* Build-in functions
**********************************************************************

DATA: lt_sflight TYPE STANDARD TABLE OF sflight,
      ls_sflight TYPE sflight,
      lv_index   TYPE sy-tabix.

SELECT * FROM sflight INTO TABLE lt_sflight WHERE carrid = 'AA' OR carrid = 'AZ'.

* line_index()
READ TABLE lt_sflight WITH KEY carrid = 'AZ' TRANSPORTING NO FIELDS.
lv_index = sy-tabix.
WRITE:/ 'The index is:' , lv_index.

lv_index = line_index( lt_sflight[ carrid = 'AZ' ] ).
WRITE:/ 'The index is:' , lv_index.

* line_exist()
READ TABLE lt_sflight WITH KEY carrid = 'AZ' TRANSPORTING NO FIELDS.
IF sy-subrc = 0.
  WRITE:/ 'The line exists in itab'.
ENDIF.

IF line_exists( lt_sflight[ carrid = 'AZ' ] ).
  WRITE:/ 'The line exists in itab'.
ENDIF.

* lines( )
DESCRIBE TABLE lt_sflight LINES lv_lines.

lv_lines = lines( lt_sflight ).