使用schtasks
创建定时任务
接下来,你可以使用schtasks
命令来创建定时任务。这个命令允许你从命令行创建、修改、查询、删除、运行和结束计划任务。
以下是一个示例,展示如何使用schtasks
命令创建一个每天凌晨1点执行backup.bat
的定时任务:
@echo off schtasks /create /sc daily /tn "Daily Backup" /tr "C:\path\to\backup.bat" /st 01:00
在这个命令中:
/create
表示创建新任务。/sc daily
表示任务的频率是每天。/tn "Daily Backup"
表示任务的名称是"Daily Backup"。/tr "C:\path\to\backup.bat"
表示任务运行的命令是批处理文件的路径。/st 01:00
表示任务开始的时间是凌晨1点
备份PostgreSQL数据库脚本
@Title 【PostgreSQL Backup】
@echo off & setlocal enableextensions
echo. ################################################################
echo. ##===============【PostgreSQL Database Backup】===============##
echo. ################################################################
cd /d "%~dp0"
set str_time_first_bit="%time:~0,1%"
if %str_time_first_bit%==" " (
Set DateTime=%date:~0,4%%date:~5,2%%date:~8,2%_0%time:~1,1%%time:~3,2%%time:~6,2%
)else (
set DateTime=%date:~0,4%%date:~5,2%%date:~8,2%_%time:~0,2%%time:~3,2%%time:~6,2%
)
::指定数据库用户名和密码
SET DBUSR=postgres
SET PGPASSWORD=1234
:: 指定PostgreSQL数据库安装路径bin目录
rem %%i为第1字段,%%j为第2字段,%%k为第3字段,%%l为第4字段,请根据需要修改获取的变量
::从注册表获取PostgreSQL安装路径
for /f "tokens=1,2,3,* " %%i in ('reg query HKEY_LOCAL_MACHINE\SOFTWARE\PostgreSQL\Installations\postgresql-x64-12 /v "Base Directory" ^| find /i "Base Directory"') do set regvalue="%%l"
echo PostgreSQL安装路径为%regvalue%
SET PGPATH=%regvalue%\bin
::指定备份文件存放路径
SET SAVEPATH=E:\DataBaseBackUp\
:: 判断文件夹是否存在,如不存在则自动创建文件夹
if exist %SAVEPATH% ( echo "备份路径已存在,无需创建" ) else ( md %SAVEPATH% )
::指定备份数据库名称
SET DBNAME=SurveyMcu
::指定备份文件名称
SET FILENAME=%DBNAME%_%DateTime%.backup
echo. 开始执行数据库备份
%PGPATH%\pg_dump -h localhost -U postgres -p 5432 --verbose --format=c --blobs %DBNAME% > %SAVEPATH%%FILENAME%
echo. Database backup completed.
::echo. 检测备份状态
set /a FileSize=1*1024
for %%i in ( %SAVEPATH%%FILENAME% ) do ( if %%~zi gtr %FileSize% (echo. %DBNAME%备份成功!) else (echo. %DBNAME%备份失败!) )
echo. *********************************************************************
echo. Backup File: %SAVEPATH%%FILENAME%
echo. *********************************************************************
::删除指定路径下指定天数之前(以文件的最后修改日期为准)的历史文件。
::指定保存天数
set DaysAgo=10
forfiles /p %SAVEPATH% /s /m *.backup /d -%DaysAgo% /c "cmd /c del /f /q /a @path"
::按任意键返回命令【pause】
::pause