中文编程为女友制造一场浪漫的邂逅

用中文编程来为女友制造一场浪漫的邂逅，

效果如下

花瓣是随机掉落的，女友图片是多张动态切换的，启动之后会是全屏模式，还有喜欢的音乐播放

环境：

易语言

代码如下

主代码

.版本 2
.支持库 shellEx
.支持库 spec
.支持库 iext2

.程序集 窗口程序集1
.程序集变量 花瓣集, 落花, , "0"
.程序集变量 数量, 整数型
.程序集变量 目录, 文本型
.程序集变量 esc, 整数型
.程序集变量 女友, 落花
.程序集变量 当前女友, 整数型
.程序集变量 女友集, 文本型, , "0"

.子程序 __启动窗口_创建完毕
.局部变量 次数, 整数型
.局部变量 背景, 文本型
.局部变量 临时, 文本型

esc ＝ 注册热键 (取窗口句柄 (), 标签1.取窗口句柄 (), 0, #Esc键)
播放MP3 (-1, 取运行目录 () ＋ “\” ＋ 读配置项 (取运行目录 () ＋ “\配置.ini”, “配置参数”, “音乐”, ))
' 动画框1.背景图片 ＝ 读入文件 (取运行目录 () ＋ “\3.jpg”)
背景 ＝ 读配置项 (取运行目录 () ＋ “\配置.ini”, “配置参数”, “背景”, )
临时 ＝ 读配置项 (取运行目录 () ＋ “\配置.ini”, “配置参数”, “女友”, )
女友集 ＝ 分割文本 (临时, “,”, )
当前女友 ＝ 1
调试输出 (“背景”, 背景)
.判断开始 (背景 ＝ “”)
    动画框1.背景图片 ＝ 快照 (, , )
.判断 (背景 ≠ “”)
    动画框1.背景图片 ＝ 读入文件 (取运行目录 () ＋ “\” ＋ 背景)
.默认

.判断结束
目录 ＝ 取运行目录 () ＋ “\” ＋ 读配置项 (取运行目录 () ＋ “\配置.ini”, “配置参数”, “花瓣”, “img”) ＋ “\”
_启动窗口.移动 (0, 0, 取屏幕宽度 (), 取屏幕高度 ())
动画框1.移动 (0, 0, 取屏幕宽度 (), 取屏幕高度 ())
数量 ＝ 50

置随机数种子 ()
重定义数组 (花瓣集, 假, 数量)
女友.x ＝ 100
女友.y ＝ 100
女友.标识 ＝ 动画框1.创建物体 (动画物体1, 女友.x, 女友.y, , )
女友.角度 ＝ 5
女友.速度 ＝ 5
动画框1.置图片 (女友.标识, 读入文件 (取运行目录 () ＋ “\” ＋ 女友集 [当前女友]), )

.计次循环首 (数量, 次数)
    花瓣集 [次数].x ＝ 取整 (取随机数 (0, 取屏幕宽度 ()) ÷ 30) × 30
    花瓣集 [次数].y ＝ －取整 (取随机数 (0, 取屏幕高度 ()) ÷ 30) × 30
    花瓣集 [次数].标识 ＝ 动画框1.创建物体 (动画物体1, 花瓣集 [次数].x, 花瓣集 [次数].y, , )
    花瓣集 [次数].角度 ＝ 花瓣集 [次数].角度 ＋ 取整 (取随机数 (-1, 1))
    花瓣集 [次数].速度 ＝ 取随机数 (1, 5)
    动画框1.置图片 (花瓣集 [次数].标识, 读入文件 (目录 ＋ 到文本 (取整 (取随机数 (1, 40))) ＋ “.png”), )
.计次循环尾 ()


.子程序 _时钟1_周期事件
.局部变量 i, 整数型

' 窗口_鼠标穿透 (_启动窗口.取窗口句柄 (), 真)

.计次循环首 (数量, i)
    花瓣集 [i].y ＝ 花瓣集 [i].y ＋ 花瓣集 [i].速度
    花瓣集 [i].角度 ＝ 花瓣集 [i].角度 ＋ 取整 (取随机数 (-1, 1))
    .如果真 (花瓣集 [i].y ＞ 取屏幕高度 ())
        花瓣集 [i].y ＝ 取整 (取随机数 (0, 30))
        花瓣集 [i].x ＝ 取整 (取随机数 (0, 取屏幕宽度 ()) ÷ 30) × 30
        动画框1.置图片 (花瓣集 [i].标识, 读入文件 (目录 ＋ 到文本 (取整 (取随机数 (1, 40))) ＋ “.png”), )
    .如果真结束
    动画框1.置角度 (花瓣集 [i].标识, 花瓣集 [i].角度)

    动画框1.置物体位置 (花瓣集 [i].标识, 花瓣集 [i].x, 花瓣集 [i].y, )

.计次循环尾 ()
' 动画框1.背景图片 ＝ 快照 (, , )

.子程序 _标签1_反馈事件, 整数型
.参数 参数一, 整数型
.参数 参数二, 整数型

.如果真 (参数一 ＝ esc)
    结束 ()
.如果真结束


.子程序 _时钟2_周期事件

动画框1.置图片 (女友.标识, 读入文件 (取运行目录 () ＋ “\” ＋ 女友集 [当前女友]), )
动画框1.置角度 (女友.标识, 女友.角度)
动画框1.置物体位置 (女友.标识, 女友.x, 女友.y, )
当前女友 ＝ 当前女友 ＋ 1

.如果真 (当前女友 ＞ 取数组成员数 (女友集))
    当前女友 ＝ 1
.如果真结束

自定义类型

.版本 2

.数据类型 落花
    .成员 标识, 整数型
    .成员 x, 整数型
    .成员 y, 整数型
    .成员 速度, 整数型
    .成员 角度, 整数型

下载方式

链接：https://pan.baidu.com/s/1lmLEd8f6RMsede1mdsGMZQ 
提取码：1234