CDS 进销存报表功能实现

已于 2024-03-13 11:30:12 修改
阅读量1.9k 收藏 40
点赞数 53
文章标签： sap
于 2024-03-11 15:14:14 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/qq_33852362/article/details/136624782
版权

CDS 进销存报表功能实现

业务需求概览

SAP标准功能一般有两个常用的进销存报表.

  • MB5B
  • J3RFLVMOBVEDH

其中MB5B特殊库存不支持合并显示.同时这两张报表为旧技术(ECC)实现,随着业务量积累效率明显越来越低.零售业中基本无法使用.

综上所述,本功能充分利用S4 HANA新特性,用CDS实现进销存报表.

增加差异金额的分摊计算逻辑,使工厂层的评估变动分摊到库存明细级,最终实现库存明细级别的完整的数量,金额的进销存逻辑.

该项目包含在GITHUB个人工具包中.
https://github.com/OutKeal/abap_zwftools

主要功能实现

1. 物料凭证预处理

功能方法.ZWFT_INV_CLASS=>MSEG_WRITE( ).本方法主要两个地方调用,物料凭证保存增强和独立程序ZWFT_INV_MSEG.独立程序主要处理逻辑变更,配置表更时重新生成数据,增强负责正常数据处理.

  1. 处理物料凭证金额,使一些0金额业务例如移库也有金额

    • 若本币金额(dmbtr)为空且外部金额(exbwr)不为空,则金额取外部金额.

    • 若本币金额为空,则用公式本币金额=数量*评估总金额/评估总数量,计算本币金额.

  2. 借贷(shkzg)为H的行,数量金额都切换为负.

  3. 从配置表zwft_inv_type匹配获取进销存类型.

  4. 获取库存评估编号(增强时从结构VM07M,重新跑时从MATDOC)

  5. 处理特殊库存关键字

    • O/K,特殊库存关键字为供应商编号

    • W,特殊库存关键字为客户编号

    • E/T,特殊库存关键字为mat_kdauf+mat_kdpos

  6. 通过物料凭证的录入日期/录入时间,生成时间戳.

  7. 315/316等凭证,补全其发货行.

  8. 写入表ZWFT_INV_MSEG

*Importing	XMSEG	TYPE TY_T_MSEG	表 MSEG
*Importing	VM07M	TYPE TY_T_VM07M OPTIONAL	带有结构 VM07M 的表
  METHOD mseg_write.
    init_inv_type( ).
    DATA: in_mseg TYPE TABLE OF zwft_inv_mseg.
    DATA: in_mseg_ex TYPE TABLE OF zwft_inv_mseg.

    IF vm07m IS INITIAL.
      SELECT mblnr,mjahr,zeile,kalnr
        FROM matdoc
        FOR ALL ENTRIES IN @xmseg
    WHERE mblnr = @xmseg-mblnr
        INTO TABLE @DATA(lt_doc).
      SORT lt_doc BY mblnr mjahr zeile.
    ENDIF.

    CHECK xmseg[] IS NOT INITIAL.
    LOOP AT xmseg INTO DATA(l_xmseg).
      READ TABLE zwft_inv_class=>inv_type INTO DATA(l_inv_type)
                                                              WITH KEY bwart = l_xmseg-bwart
                                                                                shkzg = l_xmseg-shkzg.
      APPEND INITIAL LINE TO in_mseg ASSIGNING FIELD-SYMBOL(<in_mseg>).
      MOVE-CORRESPONDING l_xmseg TO <in_mseg>.

      <in_mseg>-satnr = zwft_single_read=>mara( <in_mseg>-matnr )-satnr.
      IF <in_mseg>-satnr IS INITIAL.
        <in_mseg>-satnr = <in_mseg>-matnr.
      ENDIF.

      IF <in_mseg>-dmbtr IS INITIAL AND l_xmseg-exbwr IS NOT INITIAL.
        <in_mseg>-dmbtr = l_xmseg-exbwr.
      ELSEIF <in_mseg>-dmbtr IS INITIAL.
        IF l_xmseg-bustw IS INITIAL AND <in_mseg>-lbkum IS NOT INITIAL.
          <in_mseg>-dmbtr = <in_mseg>-erfmg * <in_mseg>-salk3 / <in_mseg>-lbkum.
        ENDIF.
      ENDIF.

      IF <in_mseg>-shkzg = 'H'.
        <in_mseg>-erfmg  = - <in_mseg>-erfmg.
        <in_mseg>-dmbtr  = - <in_mseg>-dmbtr.
      ENDIF.

      <in_mseg>-record_type = 'MDOC'.
      <in_mseg>-inv_type = l_inv_type-inv_type.
      CLEAR l_inv_type.
      CASE <in_mseg>-sobkz.
        WHEN 'O' OR 'K'.
          <in_mseg>-ssnum = <in_mseg>-lifnr.
        WHEN 'W'.
          <in_mseg>-ssnum = <in_mseg>-kunnr.
        WHEN 'E' OR 'T'.
          <in_mseg>-ssnum = <in_mseg>-mat_kdauf && <in_mseg>-mat_kdpos.
      ENDCASE.

      CONVERT DATE l_xmseg-cpudt_mkpf TIME l_xmseg-cputm_mkpf
        INTO TIME STAMP <in_mseg>-timestamp TIME ZONE sy-zonlo.
      IF vm07m IS NOT INITIAL.
        READ TABLE vm07m INTO DATA(l_vm07m) WITH KEY zeilv = l_xmseg-zeile.
        IF sy-subrc EQ 0.
          <in_mseg>-kalnr = l_vm07m-kaln1.
        ENDIF.
      ELSEIF lt_doc IS NOT INITIAL.
        READ TABLE lt_doc INTO DATA(ls_doc) WITH KEY mblnr = l_xmseg-mblnr mjahr = l_xmseg-mjahr zeile = l_xmseg-zeile BINARY SEARCH.
        IF sy-subrc EQ 0.
          <in_mseg>-kalnr = ls_doc-kalnr.
        ENDIF.
      ENDIF.

      IF <in_mseg>-bwart = '315' OR <in_mseg>-bwart = '316'.
        APPEND INITIAL LINE TO in_mseg_ex ASSIGNING FIELD-SYMBOL(<in_mseg_ex>).
        <in_mseg_ex> = <in_mseg>.
        <in_mseg_ex>-record_type = 'MDOC_CP'.
        <in_mseg_ex>-shkzg = COND #( WHEN <in_mseg_ex>-shkzg = 'S' THEN 'H' ELSE 'H' ).
        <in_mseg_ex>-erfmg  = - <in_mseg_ex>-erfmg.
        <in_mseg_ex>-dmbtr  = - <in_mseg_ex>-dmbtr.
      ENDIF.

    ENDLOOP.

    IF in_mseg_ex IS NOT INITIAL.
      APPEND LINES OF in_mseg_ex TO in_mseg.
    ENDIF.

    IF in_mseg IS NOT INITIAL.
      MODIFY zwft_inv_mseg FROM TABLE in_mseg.
    ENDIF.
  ENDMETHOD.

2. CDS 时点库存

带参数的CDS视图,截止到某一天(小于)之前的物料凭证求和,简单实现库存的查询.

需要处理的部分在物料凭证预处理时已经处理完成.

@AbapCatalog.sqlViewName: 'ZWFT_INV_STOCK'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: '进销存时点库存'
define view ZWFT_CDS_INV_STOCK 
  with parameters
    P_endDate  : vdm_v_end_date
as select from zwft_inv_mseg
{   
    bukrs,
    werks,
    lgort,
    satnr,
    matnr,
    charg,
    sobkz,
    ssnum,
    sum( erfmg ) as menge,
    sum( dmbtr ) as dmbtr

}

where budat_mkpf < $parameters.P_endDate //进销存需求,截止日期+1传入   
group by 
    bukrs,
    werks,
    lgort,
    satnr,
    matnr,
    charg,
    sobkz,
    ssnum

3. CDS 进销存发生额

简单实现开始到结束日期的,按进销存类型分类汇总的发生数量/发生金额.

  • I 入库数量/金额
  • O 出库数量/金额
  • D 差异金额 (来源请看后续差异计算逻辑)
  • E 未分配 (原则上不应该有未分配,补充配置表ZWFT_INV_TYPE)
@AbapCatalog.sqlViewName: 'ZWFT_INV_CHANGE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: '进销存发生额'


define view zwft_cds_inv_change 
  with parameters
    P_startDate  : vdm_v_start_date,
    P_endDate  : vdm_v_end_date
as select from zwft_inv_mseg
{
    bukrs,
    werks,
    lgort,
    satnr,
    matnr,
    charg,
    sobkz,
    ssnum,
    sum( case inv_type when 'I' then erfmg end ) as MENGE_I,
    sum( case inv_type when 'I' then dmbtr end ) as DMBTR_I,
    sum( case inv_type when 'O' then erfmg end ) as MENGE_O,
    sum( case inv_type when 'O' then dmbtr end ) as DMBTR_O,
    sum( case inv_type when 'D' then dmbtr end ) as dmbtr_d,
    sum( case inv_type when ' ' then erfmg end ) as MENGE_E,
    sum( case inv_type when ' ' then dmbtr end ) as DMBTR_E
    
}
where budat_mkpf >= $parameters.P_startDate
and budat_mkpf < $parameters.P_endDate
group by 
    bukrs,
    werks,
    lgort,
    satnr,
    matnr,
    charg,
    sobkz,
    ssnum

4. CDS 进销存实现

  1. 通过时点库存CDS视图获取期末库存数量金额
  2. 左关联时点库存CDS视图获取期初库存数量金额.
  3. 左关联进销存发生额CDS视图获取出库/入库/差异等数量金额.
  4. 根据特殊库存关键字还原特殊库存的关键字段
@AbapCatalog.sqlViewName: 'ZWFT_INV'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: '进销存报表'
define view ZWFT_CDS_INV 
  with parameters
    P_startDate  : vdm_v_start_date,
    P_endDate  : vdm_v_end_date
as select from ZWFT_CDS_INV_STOCK(P_endDate: $parameters.P_endDate ) as end
left outer join ZWFT_CDS_INV_STOCK( P_endDate: $parameters.P_startDate ) as start
on start.bukrs = end.bukrs
and start.werks = end.werks
and start.lgort = end.lgort
and start.satnr = end.satnr
and start.matnr = end.matnr
and start.charg = end.charg
and start.sobkz = end.sobkz
and start.ssnum = end.ssnum

left outer join zwft_cds_inv_change(P_startDate:$parameters.P_startDate,P_endDate:$parameters.P_endDate) as change
on change.bukrs = end.bukrs
and change.werks = end.werks
and change.lgort = end.lgort
and change.satnr = end.satnr
and change.matnr = end.matnr
and change.charg = end.charg
and change.sobkz = end.sobkz
and change.ssnum = end.ssnum
{
    end.bukrs,
    end.werks,
    end.lgort,
    end.satnr,
    end.matnr,
    end.charg,
    end.sobkz,
    end.ssnum,
    @EndUserText.label: '期初数量'
    start.menge as menge_start,
    @EndUserText.label: '期初金额'
    start.dmbtr as dmbtr_start,
    @EndUserText.label: '入库数量'
    change.MENGE_I as menge_in,
    @EndUserText.label: '入库金额'
    change.DMBTR_I as DMBTR_in,
    @EndUserText.label: '出库数量'
    change.MENGE_O as menge_out,
    @EndUserText.label: '出库金额'
    change.DMBTR_O as DMBTR_OUT,
    @EndUserText.label: '差异金额' 
    change.dmbtr_d as dmbtr_diff,
    @EndUserText.label: '异常数量'
    change.MENGE_E as menge_E,
    @EndUserText.label: '异常金额'
    change.DMBTR_E as DMBTR_E,
    @EndUserText.label: '期末数量'
    end.menge as menge_end,
    @EndUserText.label: '期末金额'
    end.dmbtr as dmbtr_end,
    case when end.sobkz = 'E' then LEFT(end.ssnum,10) end as KDAUF,
    case when end.sobkz = 'E' then RIGHT(end.ssnum,6) end as KDPOS,
    case when end.sobkz = 'T' then LEFT(end.ssnum,10) end as VBELN_VL,
    case when end.sobkz = 'T' then RIGHT(end.ssnum,6) end as POSNR_VL,
    case when end.sobkz = 'W' then LEFT(end.ssnum,10) end as KUNNR,
    case when end.sobkz = 'O' then LEFT(end.ssnum,10) end as LIFNR
}

差异金额处理

主要功能中实现的逻辑少了一部分发票校验差异\存货移动差异\重估差异等处理,会导致收发存金额不平,且结余对不上FI总账科目.

本块功能实现非物料凭证库存的库存金额调整的计算/分摊逻辑,完善进销存金额计算.

1.CDS 会计凭证调整明细

获取ACDOCA关键财务凭证明细.

关键条件:

  • and acdoca.ktosl = ‘BSX’
  • acdoca.awtyp <> ‘MKPF’
  • 包含acdoca.awtyp = ‘MKPF’ and acdoca.blart = ‘PR’,此类型为跨期记账自动差异处理生成的会计凭证.

获取关键字段:

  • timestamp,时间戳
  • kalnr,评估号
  • wsl,差异金额,带正负符号
@AbapCatalog.sqlViewName: 'ZWFT_INV_DIFF'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: '获取进销存差异'
define view ZWFT_CDS_INV_DIFF as select from acdoca
inner join bkpf
    on acdoca.rbukrs = bkpf.bukrs
    and acdoca.belnr = bkpf.belnr
    and acdoca.gjahr = bkpf.gjahr
{
    acdoca.awtyp,
    acdoca.belnr,
    acdoca.gjahr,
    acdoca.docln,
    acdoca.rbukrs,
    acdoca.drcrk,
    acdoca.budat,
    acdoca.matnr,
    acdoca.werks,
    acdoca.timestamp,
    acdoca.kalnr,
    acdoca.wsl
}
where ( acdoca.awtyp <> 'MKPF' or ( acdoca.awtyp = 'MKPF' and acdoca.blart = 'PR' ) )
and acdoca.ktosl = 'BSX'

2. 差异分摊

程序ZWFT_INV_DIFF,按照工厂,记账日期,物料获取差异明细,调用zwft_inv_class=>diff_split( )方法分摊差异.

通过CDS视图ZWFT_CDS_INV_S_TS,获取时间戳评估号的节点明细库存.

关键条件:

  • budat_mkpf <= :p_endDate(会计凭证过账日的月最后一天)

  • timestamp < :p_TIMESTAMP(会计凭证时间戳)

@AbapCatalog.sqlViewName: 'ZWFT_INV_S_TS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: '时间戳的库存'
define view ZWFT_CDS_INV_S_TS
  with parameters
    p_TIMESTAMP  : timestamp,
    p_endDate : vdm_v_end_date
as select from zwft_inv_mseg
{
    bukrs,
    werks,
    lgort,
    satnr,
    matnr,
    charg,
    sobkz,
    ssnum,
    kalnr,
    sum(erfmg) as menge,
    sum(dmbtr) as dmbtr
}
where budat_mkpf <= :p_endDate
and timestamp < :p_TIMESTAMP
group by 
    bukrs,
    werks,
    lgort,
    satnr,
    matnr,
    charg,
    sobkz,
    ssnum,
    kalnr

按照数量比例分摊每个评估号(大概等同于工厂+物料)的库存差异,分摊到最细的库存级别(库存地点,特殊库存),整理数据写入ZWFT_INV_MSEG表.

关键写入字段:

  • 进销存类型ZWFT_INV,默认D
  • 移动类型,BWART,默认DIF.
  • 凭证号相关字段,写会计凭证的凭证号/公司/年份,拆分行增加二级行号
  • 库存关键字段(工厂,物料,库位,特殊库存),取库存拆分明细对应信息.
  • 金额计算最后一行用减法.

可以考虑每天定时作业运动前一天的ZWFT_INV_DIFF处理差异的卷算.注意时序很重要.

总结

分摊完毕后,将物料/评估范围级的财务金额记账,分摊到了库存明细级别.报表曾将进销存类别D直接显示为差异金额,期初期末包含对应的差异金额.完成进销存计算闭环.

进销存报表

程序ZWFT_INV.

筛选条件:

  • 工厂
  • 仓库
  • 物料类型
  • 物料组
  • 物料编号
  • 开始日期
  • 结束日期

报表ALV显示:

​ 进销存视图数据已经足够,简单获取仓库/物料的描述,销售订单的对应款号即完成.

Karl_WF
关注
【转载】CDS相关资料整理(四)
森林木的博客
09-27 356
好多年没玩儿了，反正我三压都稳稳的压偏~既然人家写的很好，直接搬运吧，代码人，总不能说”窃“吧虽然干着”盗窃“的事儿原文：https://zhuanlan.zhihu.com/p/610924866?utm_id=01、 CDS概念Core data services（以下简称CDS）可以指两样东西，一个是HANA CDS，一个是ABAP CDS。如我们所知，HANA CDS只支持HANA数据库，...
SAP进销存难点分析及对策
热门推荐
wbin9752的专栏
02-25 1万+
1、基本需求： 业务部门提出如上表格式进销存需求，并且金额要和总账中存货科目保持一致，如果要实现上表格式进校存，可以通过SAP标准程序（MC.9、MB51、MB5B）加工繁琐而成。现分析一下SAP标准程序逻辑优缺点及自开发程序实现方案。 2、SAP标准程序逻辑及优缺点分析 2.1  MC．9取数逻辑 MC.9取数逻辑基于S031和S032两个信息结构可以取的某个月底库存数量金库存金额，
SAP-CDS学习
最新发布
wk849337494的博客
08-22 407
通过SE11可以查看。
SAP MM 进销存报表优化小记
06-18 292
SAP MM 进销存报表优化小记 笔者刚刚加入SY项目，就接到了SY集团上海总部SAP运维部门负责人的工作分配，说是有一只进销存报表，需要做一个优化，可能是需要重新设计重新开...
SAP MM 进销存报表与标准报表MB5B
07-06 3550
SAP MM 进销存报表与标准报表MB5B 提到进销存报表，SAP提供了一个标准报表MB5B。这个报表能显示指定的日期范围内，期初库存（数量与金额），期末库存（数量与金额），总...
SAP-MM库存进销存报表
yanzibing99的博客
06-01 3416
SAP-MM-进销存报表
【MM系列】SAP 物料进销存报表查看
ARICK2014的博客
07-12 3156
公众号：SAP Technical 本文作者：matinal 原文出处：http://www.cnblogs.com/SAPmatinal/ 原文链接：【MM系列】在SAP里查看数据的方法 前言部分 大家可以关注我的公众号，公众号里的排版更好，阅读更舒适。 正文部分 MB51 + MB5B查看 物料在工厂、库存地点下的某个期间的物料移动 每一笔物料凭证...
SAP Business One 进销存明细报表SQL查询
我的博客
01-08 3180
软件环境：SAP Business One 9.2 首先感谢ITPUB论坛的“guozhiqiang01”提供源码和思路，在基础上对SAP Business One 进销存明细报表的查询代码优化如下：  SELECT t2.TransNum 交易编号,        t2.TransType 交易类型,        t1.ItemCode 物料编号,        t1.ItemName 物...
物料进销存报表查看
matinal 當冬夜漸暖 。公众号：matinal
03-16 2664
物料进销存报表查看
SAP简单报表开发
bit的博客
09-02 4975
在公司摸鱼了一个多月，上周有开发任务了，在SAP里二次开发，做一个简单报表 1.需求简介 以前出口货物保险费对账单是由保险公司提供，审单员进行打印张贴于OA进行提需审批；现保险公司不提供出口货物保险费对账单，需在SAP中开发相应出口货物保险费对账单报表。 2.熟悉表和相关事务码 来了公司才了解SAP是什么，之前可谓一无所知，对公司的业务完全不了解，但是好在使用ABAP开发报表不是很难,在导师简单介绍基本语法后，基本就可以上手。 T-CODE：se16n 查询透明表 首先先熟悉要使用到的几个表,了解字段 .
开发的一个订单库存和采购系统 进销存系统(PB开发)
09-27
开发的一个订单库存和采购系统 进销存系统， PB写的
进销存表格完整版
05-03
里诺进销存表格模板完整版，可适用于加载模板使用
进销存明细表(含双击跳转)
IT养家
05-29 1047
*&amp;---------------------------------------------------------------------**&amp; Report  ZMMR004*&amp;*&amp;---------------------------------------------------------------------**&amp;*&amp;*&amp;--...
SAP存货分析报表
congchui5375的博客
02-23 594
一.存货周转率 制造企业中存货所占的流动资产比重较大，存货的变现能力将直接影响企业资产的利用效率，存货的变现能力，一般用存货的周转率来反映。存货周转率是衡量和评价企业购人存货、投人生产...
SAP 库存报表查询
willieyuan的博客
03-17 7762
事务代码： MMBE　：查询单个物料 MB51：查询物料凭证，移动等。 MB52：可以查多个物料。 ....... RM07MBST（程序，SE38键入运行）：库存值清单（FI财务使用），如下： ...
[转]SAP存货分析报表
weixin_30311605的博客
04-05 282
对于存货分析,SAP提供了一大堆MC.*的报表，但基本无企业用，Why?因为大部分是基于信息结构,非常不准确!也很难利用起来。下面是库存分析中的一些名词解释： 一.存货周转率 制造企业中存货所占的流动资产比重较大，存货的变现能力将直接影响企业资产的利用效率。存货的变现能力，一般用存货的周转率来反映。存货周转率是衡量和评价企业购入存货、投人生产、销售收回等各环节管理状况的综合性指标，具体...
【转载】CDS相关资料整理(十五)定义CDS表函数功能
森林木的博客
10-28 381
路边随拍原文地址：https://www.ut163.com/fiori_learning_arrangement/sap-cds/define_cds_table_function_function/定义CDS表函数功能创建CDS表功能为CDS表功能创建DDL源使用AMDP方法创建AMDP类AMDP功能完成CDS表功能的定义在创建CDS时，有一种是定义Define　Table　Function的...
拓展总结七：SAP物料主数据重要字段解析&底表汇总（二）
m0_73971710的博客
08-13 1927
5、MRP2视图1）采购类型（获取类型）：F-外部采购，E-内部采购（自制），X-两者皆可。2）特殊采购类：在采购类型的基础上根据特殊业务设定的值，确定物料是直接采购还是外协采购或者为虚拟件，常用的有10-寄售/采购类型F30-委外或外协/采购类型F50-虚无装配/采购类型E。3）反冲：如果生产过程采用产成品倒冲原材料库存的方式，则需要设置此值，也就是在报工时扣减物料。
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值