Android加载3D模型的学习笔记

篇章目标要点

3D模型的使用最早是在游戏领域广泛使用的，随着技术的发展，其他工业领域也在逐步引入3D相关的技术设计。本文是结合初学3D模型的读取和显示总结的心得，本文作为序列的第一篇介绍，重点会阐述3D模型加载的主要知识点。

3D数据格式解读

常见的3D模型的格式包括stl和obj两种，其中stl模型一般仅包含面信息，不含纹理信息。obj模型包含面和纹理信息，因为后续自己重点研究obj模型怎么读取。
如下图所示.obj格式的模型文件，可以基于text打开，其内容构成如下图所示，主要由顶点/纹理坐标/顶点法向量/面这4个方面的信息构成。其主要信息格式的截图参照截图说明

Obj格式数据解码过程

了解了Obj数据格式之后，接下来就是读取数据文件，提取出当中的顶点/纹理坐标/顶点法向量/面信息，需要提取出的信息概况为(1)x,y,z坐标排列顺序下的n个点的坐标集合；(2)全部面×3个顶点的法向量，3个点填充相同的法向量；(3)全部面×3个顶点的纹理坐标。输出格式均为FloatBuffer格式

着色器理解

着色器的作用如其字面的意思，就是给3D模型的构成元素上色的，主要就是顶点和面的颜色。

顶点着色器

顶点着色器处理顶点的变换，光照，纹理的应用和计算等顶点强相关的工作。详细如下图所示，概况了主要作用和变量类型

片元着色器

片元着色器负责面的纹理采样/面颜色汇总/计算雾的功能，其变更和作用定义如下。

着色器参考代码

着色器的代码一般以.sh格式文件编写，可以在工程的assets目录下。

顶点着色器代码

顶点着色器是基于C语言实现，以下是一个示例，主要计算了跟点相关的变量计算

uniform mat4 uMVPMatrix; //总变换矩阵
uniform mat4 uMMatrix; //变换矩阵
uniform vec3 uLightLocation;	//光源位置
uniform vec3 uCamera;	//摄像机位置
attribute vec3 aPosition;  //顶点位置
attribute vec3 aNormal;    //顶点法向量
attribute vec2 aTexCoor;    //顶点纹理坐标
//用于传递给片元着色器的变量
varying vec4 ambient;
varying vec4 diffuse;
varying vec4 specular;
varying vec2 vTextureCoord;  
//定位光光照计算的方法
void pointLight(					//定位光光照计算的方法
  in vec3 normal,				//法向量
  inout vec4 ambient,			//环境光最终强度
  inout vec4 diffuse,				//散射光最终强度
  inout vec4 specular,			//镜面光最终强度
  in vec3 lightLocation,			//光源位置
  in vec4 lightAmbient,			//环境光强度
  in vec4 lightDiffuse,			//散射光强度
  in vec4 lightSpecular			//镜面光强度
){
  ambient=lightAmbient;			//直接得出环境光的最终强度  
  vec3 normalTarget=aPosition+normal;	//计算变换后的法向量
  vec3 newNormal=(uMMatrix*vec4(normalTarget,1)).xyz-(uMMatrix*vec4(aPosition,1)).xyz;
  newNormal=normalize(newNormal); 	//对法向量规格化
  //计算从表面点到摄像机的向量
  vec3 eye= normalize(uCamera-(uMMatrix*vec4(aPosition,1)).xyz);  
  //计算从表面点到光源位置的向量vp
  vec3 vp= normalize(lightLocation-(uMMatrix*vec4(aPosition,1)).xyz);  
  vp=normalize(vp);//格式化vp
  vec3 halfVector=normalize(vp+eye);	//求视线与光线的半向量    
  float shininess=50.0;				//粗糙度，越小越光滑
  float nDotViewPosition=max(0.0,dot(newNormal, vp)); 	//求法向量与vp的点积与0的最大值
  diffuse=lightDiffuse*nDotViewPosition;				//计算散射光的最终强度
  float nDotViewHalfVector=dot(newNormal,halfVector);	//法线与半向量的点积 
  float powerFactor=max(0.0,pow(nDotViewHalfVector,shininess)); 	//镜面反射光强度因子
  specular=lightSpecular*powerFactor;    			//计算镜面光的最终强度
}


void main()     
{ 
   gl_Position = uMVPMatrix * vec4(aPosition,1); //根据总变换矩阵计算此次绘制此顶点位置  
   
   vec4 ambientTemp, diffuseTemp, specularTemp;   //存放环境光、散射光、镜面反射光的临时变量      
   pointLight(normalize(aNormal),ambientTemp,diffuseTemp,specularTemp,uLightLocation,vec4(0.15,0.15,0.15,1.0),vec4(0.9,0.9,0.9,1.0),vec4(0.4,0.4,0.4,1.0));
   
   ambient=ambientTemp;
   diffuse=diffuseTemp;
   specular=specularTemp;
   vTextureCoord = aTexCoor;//将接收的纹理坐标传递给片元着色器
}            

片元着色器代码

片元着色器则处理的是面相关的信息，包括纹理和接收从顶点着色器过来的参数内容。

precision mediump float;
uniform sampler2D sTexture;//纹理内容数据
//接收从顶点着色器过来的参数
varying vec4 ambient;
varying vec4 diffuse;
varying vec4 specular;
varying vec2 vTextureCoord;

void main()                         
{    
   //将计算出的颜色给此片元
   vec4 finalColor=texture2D(sTexture, vTextureCoord);    
   //给此片元颜色值
   gl_FragColor = finalColor*ambient+finalColor*specular+finalColor*diffuse;
}   

展示效果

以下是参照《Android 3D游戏技术开发宝典》源码基础上加载的模型的效果，设置了两点缩放和拖动旋转的功能。
缩放原理：调整Camera距离
旋转原理：进行矩阵旋转换算

学习心得

3D模型的内容非常博大，比如实现不同颜色样式的模型，需要将大模型进行拆解成小模型，每个小模型设置单独的纹理，从而实现整体的效果。还有局部模型的运动也是基于相同的思路，后续会进一步向这个方向进行挖掘和分享。本篇文章没有共享代码，将在在后续更加精彩的分享中与大家分享。由于作者水平有限，文章有较多不足，欢迎提出交流～