OpenGL ES3.1使用计算着色器（Compute Shader）

OpenGL ES3.1使用计算着色器（Compute Shader）

1.基本介绍

OpenGL ES从3.1版本开始支持计算着色器
        工作模型有全局工作组和本地工作组，全局工作组包含由三维的本地工作组组成，本地工作组也由三个维度组成。本地工作组三个维度大小分别为：local_size_x，local_size_y，local_size_z。
一个什么都不做的着色器最基本代码：

#version 310 es
layout(local_size_x=32,local_size_y=32) in;//设置本地工作组大小，local_size_z未设置默认为1
void main(void){
   
	//执行代码
}

2.创建、编译和链接计算着色器

创建计算着色器和顶点着色器、片元着色器过程差不多。

shader=glCreateShader(GL_COMPUTE_SHADER);//使用GL_COMPUTE
glShaderSource(shader,1,sourece,NULL);
glCompileShader(shader);
program=glCreateProgram();
glAttachShader(program,shader);
glLinkProgram(program);

3.执行计算着色器

当然要先使用glUseProgram(program)
3.1使用glDispatchCompute(GLuint num_groups_x,GLuint num_groups_y,GLuint num_groups_z)设置全局工作组大小并且执行计算着色器。
3.2使用glDispatchComputeIndirect(GLintptr indirect)使用存储在缓冲区对象参数来设置全局工作组大小并且执行计算着色器。
通过绑定GL_DISPATCH_INDIRECT_BUFFER缓冲对象来设置全局参数，缓冲对象由三个无符号整数(GLuint)来设置。indirect参数是当前绑定到 GL_DISPATCH_INDIRECT_BUFFER 目标的缓冲区的字节偏移量。

4.获取着色器属性

glGetProgramiv (GLuint program, GLenum pname, GLint *params)
pname:可为GL_MAX_COMPUTE_WORK_GROUP_SIZE

5.每个计算单元的位置

const uvec3 gl_WorkGroupSize;//本地工作组大小
in uvec3 gl_NumWorkGroups;//全局工作组大小
in uvec3 gl_LocalInvocationID;//表示当前执行单元在本地工作组中的位置
in uvec3 gl_WorkGroupID;//表示当前本地工作组在全局工作组中的位置
in uvec3 gl_GlobalInvocationID;//等于gl_WorkGroupID*gl_WorkGroupSize+gl_LocalInvocationID，所以它是当前执行单元的三维索引
in uint gl_LocalInvocationIndex;//它是gl_LocalInvocationID的一种扁平化方式，等于gl_LocalInvocationID.z*gl_WorkGroupSize.x*gl_WorkGroupSize.y+gl_LocalInvocationID.y*gl_WorkGroupSize.x+gl_LocalInvocationID.x

6.同步

同步类型有两种运行屏障(execution barrier)和内存屏障(memory barrier)

6.1运行屏障(execution barrier)

计算着色器程序中使用barrier()触发，如果计算着色器的一个请求遇到了barrier(),那么它就会停止运行，并等待同一本地工作组的所有请求到达为止，这一点在条件语句中使用尤为需要注意避免死锁。

6.2内存屏障(memory barrier)

        最基本的版本就是memoryBarrier(),它可以保证着色器的请求内存的写入操作一定提交到内存端，而不是通过缓冲区（cache）或者调度队列之类的方式。它还可以给着色器编译器做出指示，让它不要对内存操作重排序，以免因此跨越屏障函数。
        memoryBarrierAtomicCounter()会等待原子计数器更新，然后继续执行。
        memoryBarrierBuffer()和memoryBarrierImage()会等待缓存和图像变量的写入操作完成，然后继续执行。
        memoryBarrierShared()会等待带有shared限定符的变量更新，然后继续执行。

7.使用计算着色器写一个百万粒子发射器

7.1着色器代码

顶点着色器

#version 310 es
precision mediump image2D;//OpenGL ES要求显示定义image2D的精度
layout (binding = 1,rgba32f) restrict uniform image2D position_buffer;
uniform mat4 mvp;
out float intensity;//粒子年龄值
void main() {
   
    ivec2 size=imageSize(position_buffer);
    vec4 pos=imageLoad(position_buffer,ivec2(gl_VertexID%size.y,gl_VertexID/size.y));//将一维坐标转换为图像二维坐标
    gl_Position=mvp*vec4(pos.xyz,1.0f);
    intensity=pos.w;
}

片元着色器

#version 310 es
precision mediump float;
out vec4 color;
//这个值来自顶点着色器中读取的粒子年龄值
in float intensity;
void main(void){
   
    //根据粒子的年龄，在热红色到冷蓝色之间的混合结果
    color=mix(vec4(0.0f,0.2f,1.0f,1.0f),vec4(0.2f,0.05f,0.0f,1.0f),intensity);
}

计算着色器

#version 310 es
precision mediump image2D;//OpenGL ES要求显示定义image2D的精度
//uniform块中包含引力器的位置和质量
layout (std140,binding=0) uniform attractor_block{
   
    vec4 attractor[64];//xyz=position,w=mass
};
//每块中粒子的数量为128
layout (local_size_x=128) in;
//使用两个缓冲来包含粒子的位置和速度信息
layout (binding = 0,rgba32f) restrict uniform image2D velocity_buffer;
layout (binding = 1,rgba32f) restrict uniform image2D position_buffer;
//时间间隔
uniform float dt;
void main(void){
   
    //从缓存中读取当前的位置和速度
    ivec2 size=imageSize(velocity_buffer);
    ivec2 p=ivec2(int(gl_GlobalInvocationID.x)/size.y,int(gl_GlobalInvocationID.x)%size.y);
    vec4 vel=imageLoad(velocity_buffer,p);
    vec4 pos=imageLoad(position_buffer,p);
    int i;
    //使用当前速度x时间来更新位置
    pos.xyz += vel.xyz * dt;
    pos.w -= 0.0001 * dt;
    //对于每个引力器
    for (i = 0; i < 4; i++)
    {
   
        //计算受力并更新速度
        vec3 dist = (attractor[i].xyz - pos.xyz);
        vel.xyz += dt * dt * attractor[i].w * normalize(dist) / (dot(dist, dist) + 10.0);
    }
    //如果粒子已经过期，那么重置它
    if (pos.w <= 0.0)
    {
   
        pos.xyz = vec3(0.0f);
        vel.xyz *= 0.01;
        pos.w += 1.0f;
    }

    //将新的位置和速度信息重新保存在缓存中
    imageStore(position_buffer,p,pos);
    imageStore(velocity_buffer,p,vel);
}

7.2粒子系统初始化

	srand(clock());
    glEnable(GL_BLEND);
    glBlendFunc(GL_ONE, GL_ONE);
    //激活计算着色器，