ANSYS apdl命令流案例1--------桁架桥梁结构分析

前言

该桁架桥由型钢组成，顶梁及侧梁，桥身弦杆，底梁分别采用3种不同型号的型钢，结构参数见表。桥长L=32m,桥高H=5.5m。桥身由8段桁架组成，每段长4m。该桥梁可以通行卡车，若这里仅考虑卡车位于桥梁中间位置，假设卡车的质量为4000kg，若取一半的模型，可以将卡车对桥梁的作用力简化为P1 ，P2和P3 ，其中P1= P3=5000 N, P2=10000N，如图所示
桥梁结构中各种构件的几何性能参数

桥梁的简化平面模型(取桥梁的一半)

命令程序

/prep7                      !进入前处理
/PLOPTS,DATE,0            !设置不显示日期和时间
!=====设置单元和材料 
ET,1,BEAM3                !定义单元类型
R,1,2.19E-3,3.83e-6, , , , ,	    !定义1号实常数用于顶梁侧梁
R,2,1.185E-3,1.87e-6,0,0,0,0,   	!定义2号实常数用于弦杆
R,3,3.031E-3,8.47E-6,0,0,0,0, 	!定义3号实常数用于底梁
MP,EX,1,2.1E11              !定义材料弹性模量
MP,PRXY,1,0.30              !定义材料泊松比
MP,DENS,1,,7800     	    !定义材料密度
!-----定义几何关键点 
K,1,0,0,, $ K,2,4,0,, $ K,3,8,0,, $ K,4,12,0,, $ K,5,16,0,, $ K,6,20,0,, $ K,7,24,0,, $ K,8,28,0,, $ K,9,32,0,, $ K,10,4,5.5,, $ K,11,8,5.5,, $ K,12,12,5.5,, $ K,13,16,5.5,, $ K,14,20,5.5,, $ K,15,24,5.5,, $ K,16,28,5.5,,
!-----通过几何点生成桥底梁的线
L,1,2 $ L,2,3 $ L,3,4 $ L,4,5 $ L,5,6 $ L,6,7 $ L,7,8 $ L,8,9 
!------生成桥顶梁和侧梁的线
L,9,16 $ L,15,16 $ L,14,15 $ L,13,14 $ L,12,13 $ L,11,12 $ L,10,11 $ L,1,10 
!------生成桥身弦杆的线 
L,2,10 $ L,3,10 $ L,3,11 $ L,4,11 $ L,4,12 $ L,4,13 $ L,5,13 $ L,6,13 $ L,6,14 $ L,6,15 $ L,7,15 $ L,7,16 $ L,8,16 
!------选择桥顶梁和侧梁指定单元属性 
LSEL,S,,,9,16,1,
LATT,1,1,1,,,, 
!-----选择桥身弦杆指定单元属性 
LSEL,S,,,17,29,1,
LATT,1,2,1,,,,
!-----选择桥底梁指定单元属性 
LSEL,S,,,1,8,1,
LATT,1,3,1,,,,
!------划分网格 
AllSEL,all                         !再恢复选择所有对象
LESIZE,all,,,1,,,,,1                  !对所有对象进行单元划分前的分段设置 
LMESH,all                        !对所有几何线进行单元划分  
!=====在求解模块中，施加位移约束、外力，进行求解
/solu
NSEL,S,LOC,X,0                    !根据几何位置选择节点 
D,all,,,,,,ALL,,,,,                     !对所选择的节点施加位移约束
AllSEL,all                          !再恢复选择所有对象 
NSEL,S,LOC,X,32                   !根据几何位置选择节点
D,all,,,,,,,UY,,,,                       !对所选择的节点施加位移约束
ALLSEL,all                         !再恢复选择所有对象  
!------基于几何关键点施加载荷
FK,4,FY,-5000  $ FK,6,FY,-5000  $ FK,5,FY,-10000
/replot                             !重画图形
Allsel,all                           !选择所有信息(包括所有节点、单元和载荷等)
solve                              !求解
!=====进入一般的后处理模块 
/post1                             !后处理
PLNSOL, U,Y, 0,1.0                  !显示Y方向位移
PLNSOL, U,X, 0,1.0                 !显示X方向位移
!------显示线单元轴力------
ETABLE,bar_I,SMISC, 1
ETABLE,bar_J,SMISC, 1
PLLS,BAR_I,BAR_J,0.5,1             !画出轴力图 
finish                              !结束

结果