1.渐开线基础
(一)基本参数关系:
可惜需要会员了:齿轮参数原文地址
不过不要紧,上面的内容是我精心挑出来的,对于建模也足够了,而且网上关于齿轮的资料也多的是。
2.完整命令
/clear,start
rm1 = 40 !齿轮轴孔半径
b1 = 50 !齿轮厚度
z1= 20 !齿轮齿数
m = 8 !模数
ha = 1 !齿顶高系数
c = 0.25 !顶隙系数
!========================
!齿轮建模
z = z1
ang = 360/z !每个齿的圆心角
ang1 = ang/2 !半个齿的圆心角
r = m*z/2
rf = (z-2*ha-2*c)*m/2 !齿根圆半径
ra = (z+2*ha)*m/2 !齿顶圆半径
r1 = m*c !齿更倒角半径
pi=3.1415926
s=pi*m/2 !分度圆的齿厚
inva=0.014904 !渐开线函数的值
*afun,deg !设置角度计算的单位为度
rb=r*cos(20) !计算基圆半径
*afun,rad !设置角度计算单位为弧度
n=12
*dim,x,,n !定义两个数组用来存放生成的点
*dim,y,,n
*if,rf,gt,rb,then !如果齿根圆大于基圆,计算齿根圆上的压力角
af=acos(rb/rf) !齿根圆上的压力角
invaf=tan(af)-af
phi=s/r-2*(invaf-inva) !计算齿根圆齿厚对应的圆心角
x(1)=rf*cos(phi/2) !计算齿根圆的坐标值
y(1)=rf*sin(phi/2)
detar=(ra-rf)/(n-1)
*do,i,1,n-1 !进行循环计算任意圆上的坐标
ri=rf+i*detar
j=i+1
ai=acos(rb/ri) !计算任意圆上的压力角
invai = tan(ai)-ai
phi = s/r-2*(invai-inva) !计算齿根圆齿厚对应的圆心角
x(j)=rf*cos(phi/2) !任意圆对应曲线的x坐标值
y(j)=rf*sin(phi/2) !任意圆对应曲线的y坐标值
*enddo
*else !齿根圆小于基圆的情况,取af=0
phi=s/r+2*inva !计算齿根圆齿厚对应的圆心角
x(1)=rf*cos(phi/2) !计算齿根圆的坐标值
y(1)=rf*sin(phi/2)
x(2)=rb*cos(phi/2) !计算基圆圆的坐标值
y(2)=rb*sin(phi/2)
detar = (ra-rb)/(n-2)
*do,i,1,n-2 !进行循环计算任意圆上的坐标
ri=rb+i*detar
j=i+2
ai=acos(rb/ri) !计算任意圆上的压力角
invai = tan(ai)-ai
phi = s/r-2*(invai-inva) !任意圆对应齿厚的圆心角
x(j)=ri*cos(phi/2) !任意圆对应曲线的x坐标值
y(j) = ri*sin(phi/2) !任意圆对应曲线的y坐标值
*enddo
*endif
/prep7 !进入ansys前处理器
*do,i,1,n !生成n=12个关键点
k,i,x(i),y(i)
*enddo
!=======================================
k,n+1,ra,0 !生成齿顶圆上的关键点
lstr,n,n+1 !直线连接近似替代齿顶圆圆弧
bsplin,n,n-1,n-2,n-3,n-4,n-5 !样条拟合生成齿廓
bsplin,n-5,n-6,n-7,n-8,n-9,n-10
bsplin,n-10,n-11
lcomb,2,3,0 !将前面的样条曲线合并
lcomb,2,4,0
cyl4,,,rm1,0,rf,ang1 !生成一个圆环
adele,1 !删除生成的圆环面
ldele,3 !删除一条与齿廓相连的线
lstr,2,13 !生成两条线
lstr,7,1
lcomb,3,6,0 !线相加
lfillt,7,2,r1 !对齿根进行倒角
lang,3,16,90 !由倒角半径上的一点生成一条垂线
kl,4,0.1 !在线上按比率生成一个关键点
lang,8,18,90 !由该关键点生成一条垂线
lsbl,4,11,,delete,keep !通过生成的垂线对另一条线进行分割
al,3,1,2,9 !形成一个齿形面
al,6,7,12,11,8,9
al,13,5,10,11
!==========================================
!========镜像生成一个齿廓部分====================
csys,4 !将工作坐标系作为激活坐标系
arsym,y,all,,,,0,0 !对xz平面进行镜像操作
csys,1 !激活柱坐标系
agen,z,all,,,,ang,,,0
csys,0 !激活直角坐标系
allsel,all
vext,all,,,0,0,b1,0,0,0 !通过给定偏移量,由面生成体
vadd,all
numcmp,all !压缩实体的编号
!=====根据需要建立键槽部分========
block,-11,11,31,45.4,0,60
*get,vmax,volu,,num,max
vsbv,1,vmax
allsel,all
vgen,,all,,,,,-b1/2,,,1 !将齿轮移至中心