aardio - MsSql数据库+虚表示例

已于 2022-08-15 08:04:55 修改
阅读量3.2k 收藏 35
点赞数 10
分类专栏： aardio 文章标签： aardio
于 2021-05-24 14:58:28 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/sdlgq/article/details/117223368
版权

给同事写了个数据录入的小程序，算是一个简单的【mssql数据库+虚表】示例。

主窗口

主窗口设计界面：

主窗口运行界面：

主窗口代码：

import fonts.fontAwesome;
import win.ui;
import win.ui.ctrl.vlistEx;
/*DSG{{*/
mainForm = win.form(text="张某的程序";right=959;bottom=591;image=$"\res\20090526_315b100ca64e65d61fb7Wh5pSZjX9laE.jpg";bkBottom=0;bkLeft=0;bkRight=0;bkTop=0;border="none";exmode="none";maximize=1;mode="popup";sysmenu=false;title=false)
mainForm.add(
datetimepick={cls="datetimepick";left=55;top=549;right=167;bottom=572;db=1;dl=1;edge=1;font=LOGFONT(h=-16);z=8};
datetimepick2={cls="datetimepick";left=198;top=549;right=314;bottom=572;db=1;dl=1;edge=1;font=LOGFONT(h=-16);z=12};
edit={cls="edit";left=380;top=549;right=511;bottom=572;db=1;dl=1;edge=1;font=LOGFONT(h=-16);tabstop=1;z=9};
plus={cls="plus";text='\uF044 添加';left=744;top=543;right=838;bottom=578;bgcolor=-5197169;db=1;dl=1;font=LOGFONT(h=-16;name='FontAwesome');notify=1;z=4};
plus2={cls="plus";text='\uF002 查询';left=526;top=543;right=620;bottom=578;bgcolor=-5197169;db=1;dl=1;font=LOGFONT(h=-16;name='FontAwesome');notify=1;z=3};
plus3={cls="plus";text='\uF122 退出';left=849;top=543;right=943;bottom=578;bgcolor=-5197169;db=1;dr=1;font=LOGFONT(h=-16;name='FontAwesome');notify=1;z=5};
plus4={cls="plus";left=7;top=4;right=28;bottom=27;dl=1;dt=1;foreRepeat="stretch";foreground="\res\png-0056.png";z=6};
plus5={cls="plus";text='\uF045 导出';left=635;top=543;right=729;bottom=578;bgcolor=-5197169;db=1;dl=1;font=LOGFONT(h=-16;name='FontAwesome');notify=1;z=7};
static={cls="static";text="日期";left=15;top=549;right=55;bottom=572;color=16777215;db=1;dl=1;font=LOGFONT(h=-16);transparent=1;z=10};
static2={cls="static";text="至";left=176;top=549;right=196;bottom=572;color=16777215;db=1;dl=1;font=LOGFONT(h=-16);transparent=1;z=11};
static3={cls="static";text="客户";left=339;top=549;right=379;bottom=572;color=16777215;db=1;dl=1;font=LOGFONT(h=-16);transparent=1;z=13};
vlist={cls="vlistEx";text="自定义控件";left=3;top=30;right=958;bottom=527;border=1;db=1;dl=1;dr=1;dt=1;frame=1;z=1};
张某的程序={cls="static";text="张某的程序";left=36;top=4;right=343;bottom=31;color=16777215;dl=1;dt=1;font=LOGFONT(h=-16);transparent=1;z=2}
)
/*}}*/

//定义按钮样式
var skin = {
	background={
		active=0xFFD3E0BC;
		default=0xFF8FB2B0;
		hover=0xFF928BB3
	}
}
mainForm.plus.skin(skin)
mainForm.plus2.skin(skin)
mainForm.plus3.skin(skin)
mainForm.plus5.skin(skin)

//连接mssql数据库
import sqlServerEx
var db=sqlServerEx("221.1.2.3",11433,"zhang","zhang","123456");
if !db {
	win.msgboxErr("连接数据库失败！程序自动退出")
	//mainForm.close()
	//win.quitMessage()
	return ; 
}

//查询mssql数据库，并显示到虚表中
mainForm.plus2.oncommand = function(id,event){
    var kehu = (#mainForm.edit.text>0)?"and kehu='"++mainForm.edit.text++"'":""
	var tb = db.getTable(`select
	id,
	riqi as 日期,
	kehu as 客户,
	pinming as 品名,
	jianshu as 件数,
	guige as 规格,
	kouqianzhongliang as 扣前重量,
	kouhouzhongliang as 扣后重量,
	kouqianzhongliang-kouhouzhongliang as 扣除重量,
	danjia as 单价,
	jine as 金额,
	baozhuangdanjia as 包装单价,
	baozhuangjine as 包装金额,
	rengongdanjia as 人工单价,
	rengongjine as 人工金额,
	zhuangchedanjia as 装车单价,
	zhuangchejine as 装车金额,
	kouqianjine as 扣前金额,
	kouhoujine as 扣后金额,
	kouchujine as 扣除金额,
	shifujine as 实付金额,
	shijian as 操作时间
	from jilu
	where riqi>='`++mainForm.datetimepick.text++`'
	and riqi<='`++mainForm.datetimepick2.text++`'`
	++ kehu ++
	`order by id`)
	// 添加合计行
	var sum={}
	for (i=1;#tb){
		tb[i]["id"]=i //将id改为序号
		for (c=1;#tb.fields){
			sum[tb.fields[c]]:=0
			if math.isFinite(tb[i][tb.fields[c]])
			sum[tb.fields[c]]+=tonumber(tb[i][tb.fields[c]])
		}
	}
	sum["id"]=""
	sum["日期"]="合计"
	table.push(tb,sum)
	mainForm.vlist.setTable(tb)
}

import win.ui.simpleWindow
win.ui.simpleWindow(mainForm)
mainForm.show();

//退出程序
mainForm.plus3.oncommand = function(id,event){
	//mainForm.close()
	win.quitMessage()
}

//载入“添加”窗口
mainForm.plus.oncommand = function(id,event){
	var frmChild = mainForm.loadForm("\dlg\addjilu.aardio",db);
	frmChild.show();
}

//导出csv格式文件
mainForm.plus5.oncommand = function(id,event){
    if mainForm.vlist.count=0 {
    	mainForm.msgboxErr("没有查询内容！")
    	return ;
    } 
    import fsys.dlg
    var f=fsys.dlg.save("*.csv|*.csv","请选择要导出的文件",,mainForm)
	if !f return ;  
	
    
    var csv=""
    var items=mainForm.vlist.getItems()
    for (i=1;#items){
    	var it=string.join(items[i],",")
		csv+=it+'\r\n'
    }
    
	import fsys.file
	var f=fsys.file(f,"w")
	if f.write(string.fromto(csv)){
		mainForm.msgbox("文件导出完毕！")
	}else{
		mainForm.msgboxErr("文件导出失败！")
	} 
	f.close()
}

return win.loopMessage();

“添加” 窗口

1、窗口设计界面

2、窗口运行界面

3、代码

import win.ui;
import fonts.fontAwesome
import win.dlg.message
/*DSG{{*/
var winform = win.form(text="aardio form";right=699;bottom=469;image=$"\res\20090526_315b100ca64e65d61fb7Wh5pSZjX9laE.jpg";bkBottom=0;bkLeft=0;bkRight=0;bkTop=0;border="none";max=false;min=false)
winform.add(
datetimepick={cls="datetimepick";left=100;top=44;right=270;bottom=70;edge=1;font=LOGFONT(h=-16);z=3};
plus={cls="plus";text='\uF044 保存';left=579;top=336;right=673;bottom=371;bgcolor=-5197169;db=1;dr=1;font=LOGFONT(h=-16;name='FontAwesome');notify=1;z=1};
plus2={cls="plus";text='\uF122 取消';left=579;top=392;right=673;bottom=427;bgcolor=-5197169;db=1;dr=1;font=LOGFONT(h=-16;name='FontAwesome');notify=1;z=2};
plus3={cls="plus";left=3;top=2;right=24;bottom=25;dl=1;dt=1;foreRepeat="stretch";foreground="\res\png-0056.png";z=5};
static={cls="static";text="添加记录";left=32;top=2;right=147;bottom=29;color=16777215;dl=1;dt=1;font=LOGFONT(h=-16);transparent=1;z=4};
static2={cls="static";text="日期";left=29;top=46;right=103;bottom=73;color=16777215;dl=1;dt=1;font=LOGFONT(h=-16);transparent=1;z=6}
)
/*}}*/

var args={...}
if #args<2{
	winform.msgboxErr("数据库无效")
	winform.close()
	win.quitMessage()
	return winform; 
}
var db = args[2]
win.dlg.message(winform)
var fields1={"kehu","pinming","jianshu","guige","danjia","baozhuangdanjia","rengongdanjia","zhuangchedanjia","kouchubili"}
var names1 ={"客户","品名"   ,"件数"   ,"规格" ,"单价"  ,"包装单价"       ,"人工单价"     ,"装车单价"       ,"扣除比例"}
var fields2={"kouqianzhongliang","kouhouzhongliang","jine","baozhuangjine","rengongjine","zhuangchejine","kouqianjine","kouhoujine","kouchujine","shifujine"}
var names2 ={"重量"             ,"扣后重量"        ,"金额","包装金额"     ,"人工金额"   ,"装车金额"     ,"扣前金额"   ,"扣后金额"  ,"扣除金额"  ,"实付金额"}
var edits={}
for(i=1;math.max(#fields1,#fields2) ;1){
    var top=50+i*35
    var height=30
    if i<=#fields1{
    	winform.add({
			{cls="static";text=names1[i];left=30;top=top;right=100;bottom=top+height;color=16777215;dl=1;dt=1;font=LOGFONT(h=-16);transparent=1;z=7};
		})
    	edits[fields1[i]]=winform.add({
			{cls="edit";tabstop=i;left=100;top=top;right=270;bottom=top+height;edge=1;font=LOGFONT(h=-16);z=8};
    	})[1]
    }
    if i<=#fields2{
    	winform.add({
			{cls="static";text=names2[i];left=300;top=top;right=370;bottom=top+height;color=16777215;dl=1;dt=1;font=LOGFONT(h=-16);transparent=1;z=7};
		})
    	edits[fields2[i]]=winform.add({
			{cls="edit";left=370;top=top;right=540;bottom=top+height;edge=1;font=LOGFONT(h=-16);z=8};
    	})[1]
    }
}

winform.plus2.oncommand = function(id,event){
	winform.close()
}

var skin = {
	background={
		active=0xFFD3E0BC;
		default=0xFF8FB2B0;
		hover=0xFF928BB3
	}
}
winform.plus.skin(skin)
winform.plus2.skin(skin)

edits_oncommand = function(id,event){
    var jianshu=tonumber(edits["jianshu"].text):0
    var guige= tonumber(edits["guige"].text):0
    var danjia= tonumber(edits["danjia"].text):0
    var baozhuangdanjia= tonumber(edits["baozhuangdanjia"].text):0
    var rengongdanjia= tonumber(edits["rengongdanjia"].text):0
    var zhuangchedanjia= tonumber(edits["zhuangchedanjia"].text):0
    var kouchubili = tonumber(edits["kouchubili"].text):0
   
    var kouqianzhongliang= math.round(jianshu*guige,2)
    var kouhouzhongliang = math.round(jianshu*guige*kouchubili,2)
    var jine = math.round(kouqianzhongliang*danjia,2)
 	var baozhuangjine = math.round(baozhuangdanjia*jianshu,2)
    var rengongjine = math.round(rengongdanjia*kouqianzhongliang,2)
    var zhuangchejine = math.round(zhuangchedanjia*jianshu,2)
    var kouqianjine = jine + baozhuangjine + rengongjine + zhuangchejine
    var kouhoujine = math.round(kouhouzhongliang*danjia,2) + baozhuangjine + rengongjine + zhuangchejine
    var kouchujine = math.round( kouqianjine - kouhoujine,2)
    var shifujine = math.floor(kouhoujine/10,0)*10
    
    edits["kouqianzhongliang"].text=tostring(kouqianzhongliang)
    edits["kouhouzhongliang"].text=tostring(kouhouzhongliang)
    edits["jine"].text=tostring(jine)
    edits["baozhuangjine"].text=tostring(baozhuangjine)
    edits["rengongjine"].text=tostring(rengongjine)
    edits["zhuangchejine"].text=tostring(zhuangchejine)
    edits["kouqianjine"].text=tostring(kouqianjine)
    edits["kouhoujine"].text=tostring(kouhoujine)
    edits["kouchujine"].text=tostring(kouchujine)
    edits["shifujine"].text=tostring(shifujine)
}

fields1={"jianshu","guige","danjia","baozhuangdanjia","rengongdanjia","zhuangchedanjia","kouchubili"}
for(i=1;#fields1;1){
	edits[fields1[i]].oncommand = edits_oncommand
}

winform.plus.oncommand = function(id,event){
	import console
	var names="riqi,"
	var values="'"+winform.datetimepick.text+"',"
	for k,v in edits{
		if !#v.text{
   			winform.msgboxErr("信息没有填写完整！","错误")
   			return ; 
   		}
		names+=k+","
   		if k="kehu" or k="pinming"{
   			values+="'"+v.text+"',"
		}else {
			values+=(#v.text?v.text:"0")+","
		}
	}
	
	names=string.trimright(names,",")
	values=string.trimright(values,",")
	var sql="insert into jilu("+names+") values("+values+")"
	if db.exec(sql) {
		for(hwnd,ctrl in winform.eachControlEx("edit")){
			ctrl.text=""
		}
		winform.msgOk("已添加",1500)
	}else {
		winform.msgErr("添加失败",1500)
	}
	
}

import win.ui.simpleWindow
win.ui.simpleWindow(winform)
winform.show();
edits["kehu"].setFocus()

win.loopMessage();
return winform;

卢光庆
关注
专栏目录
Python + aardio实现快速开发小说爬取的桌面应用
TOTOBEFREE的博客
07-10 1312
最近刷到一个视频，介绍了一款没听说过的工具语言aardio，其体积小巧，永久免费，并且兼容市面上大多数语言。这么神奇的吗？我直接光速打开其官网，定睛一看，6.5MB大小！于是我毫不犹豫的点击了下载，安装启动一气呵成，可是…我要拿它做什么用呢？诶！最近在学习爬虫，正好找个对象练练手，于是我将目光转向了著名鼎鼎的笔趣阁，打开浏览器搜索笔趣阁，woc，这也太多了吧，我翻看了浏览器前几页，就起码找到了几十个可以正常使用的笔趣阁。好嘛，说干就干，随便找了一个看起来还可以的网站，敲下了键盘上的 F12。
sqlserver2008数据库实例
09-09
可以用来学习操作数据库的例子，里面包含几张表，大概是学生成绩管理系统。你可以用来自学查询、更新、插入、删除等等。这是用2008做的数据库，如果需要用2005或更低版本打开，请百度转换方法。
aardio教程，修改winfrom的控件属性
最新发布
weixin_43539313的博客
07-31 203
修改文本的属性，注意mainfrom是主窗口。
aardio - 扩展sqlServer，增加事务处理功能
光庆的学习笔记
12-30 1200
练习要点： 1、创建新库，利用类的继承，保留原库功能和智能提示 2、利用新库给原库扩展新功能 库代码： import sqlServer namespace sqlServer; class ex{ ctor(...){ this = ..sqlServer(...) }; beginTrans = function(){ if(this.connection) return this.connection.BeginTrans(); } rollbackT
aardio Access数据库和所有表
weixin_37254196的博客
10-10 1249
aardio Access数据库和所有表 废话不多说 直接开干！
aardio连接mysql_aardio_一些踩过的坑
weixin_39982537的博客
01-20 351
1、关于延时的区别a.sleep()mainForm.button.oncommand = function(id,event){mainForm.edit.print("start");sleep(5000);mainForm.edit.print("end");}运行效果：点击按钮，等待5秒，打印“start”，打印“end”b.win.delay()mainForm.button.oncom...
aardio连接数据库查询
weixin_37254196的博客
09-22 3141
废话不多说，直接开干！ import win.ui; import string; import inet.whttp; import console; import fsys.file; import fsys.dlg; import thread.works import io; import com; import com.excel; import console; import mysql.client; //多线程管理器 import thread.manage var csv="关键词,
aardio-erp:aardio10开发企业管理系统
03-11
＃aardio-erp，仅支持aardio10以上版本 ...架设数据库，先手动建立好数据库，并引入数据库相应的安装文件aardio-erp-mssql.sql或aardio-erp-mysql（utf8，InnoDB）.sql 4.默认超级管理员帐号：admin密码：admin 5
E116-经典赛题-mssql数据库渗透测试.pdf
12-02
本文主要涉及的是针对MSSQL数据库的渗透测试流程，这是一类常见的网络安全实践，用于评估和加固数据库系统的安全性。以下是整个渗透测试过程的关键步骤和涉及的知识点： 1. **网络扫描**： - 使用Zenmap工具进行...
数据库课程设计-基于python+mysql的书店销售管理系统源码+数据库+课设报告.zip
07-25
数据库课程设计-基于python+mysql的书店销售管理系统源码+数据库+课设报告.zip 【备注】 1、该资源内项目代码都经过测试运行成功，功能ok的情况下才上传的，请放心下载使用！有问题请及时沟通交流。 2、适用人群：...
基于C#和Vue图书管理系统（PC端+server端源码+MSSQL数据库+Docker配置）
06-15
基于C#和Vue图书管理系统（PC端+server端源码+MSSQL数据库+Docker配置） 服务宗旨：有任何问题私信我 适合人群：工作中项目需要、模板框架实战学习、大学毕业设计参考、找工作项目实战积累等等 API - Visual ...
aardio10开发企业管理系统aardio-erp框架源码.zip
05-08
3.架设数据库,先手动建好数据库,并导入数据库相应安装文件aardio-erp-mssql.sql或aardio-erp-mysql(utf8,InnoDB).sql 4.默认超级管理员帐号: admin 密码: admin 5.配置服务端数据库连接文件 \wwwroot\system\...
aardio数据库查询实例
weixin_43250893的博客
07-25 443
【代码】aardio数据库查询实例。
aardio - 【库】system.data.sqlite 数据库操作库
光庆的学习笔记
01-19 453
库名：godking.systemDataSqlite。
用aardio 实现 access数据库迁移到sqlite
玄星幻火
02-06 832
import win.ui; /*DSG{{*/ mainForm = win.form(text="aardio工程17";right=959;bottom=591) mainForm.add( edit={cls="edit";text="Edit";left=351;top=132;right=814;bottom=504;edge=1;multiline=1;z=1}; listview={cls="listview";left=47;top=110;right=252;bottom=486;ed.
aardio连接mysql_aardio中call函数的一种使用
weixin_42128015的博客
01-26 437
问题描述有三个按钮，分别对应了三种功能，用func1()、func2()和func2()表示。在响应按钮时，要先运行前置函数pre()，再运行按钮对应的函数func()，最后运行后置函数suf()。如下所示：mainForm.button1.oncommand = function(id,event){pre();func1();suf();}mainForm.button2.oncommand ...
aardio - 虚表的使用
光庆的学习笔记
05-22 991
aardio中虚表的使用已经很普及，方法也很简单。以下用两种虚表来举例，演示虚表使用方法及运行效果：1、官方虚表库2、本人（光庆）封装的虚表库。
aardio - 【库】虚表增强版
光庆的学习笔记
01-20 9372
1、虚表是一个特殊的listview，一些特性可以通用。 2、虚表对大数据比较适合，几百万条数据毫无压力。 3、数据量大的情况下（过几十万数据）：虚表占用内存非常少，加载速度也非常快。listview 占内存非常多，加载速度非常慢。 4、数据在内存中处理速度是很快的，我们看到的慢，一般是加载到组件中并显示出来这段时间太长。.........
aardio - 【库】reportX报表控件功能扩展库(reportXEx)
光庆的学习笔记
01-19 2983
//reportXEX 报表控件扩展版 import reportX class reportXEX{ ctor(winform){ this = ..reportX(winform); if(!this) return; }; setTable = function(t){ this.InvalidatePaint() var fields = t.fields; var start = 0; if( #fields ){ .
sqlmap --os-shell mssql数据库原理详解
06-09
总之，SQL 注入漏洞和 MSSQL 数据库是两个不同的概念，SQLMAP 是一种利用 SQL 注入漏洞的工具，可以通过 `--os-shell` 参数获取操作系统的交互式shell，而 MSSQL 是一种常见的关系型数据库管理系统，用于管理和操作...
评论 4
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

卢光庆

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值