aardio - 菜单操作

关于菜单，功能很简单，但使用较复杂。

总结了一下：

1、注意区分了解主菜单和弹出菜单。

        主菜单：显示在窗口上。每个菜单项可绑定一个弹出菜单使用。一般主显示。

        弹出菜单：被主菜单绑定后，点击主菜单项才显示。或执行popup()函数显示。一般主功能。

        如下图所示：

2、了解如何定义菜单项内容，包括以下：

1、id：菜单id，可选，不定义则自动分配。 

2、text：菜单文本。正常情况下为字符串。如果显示图片，则为位图句柄，并需将flag设置为 4/*_MF_BITMAP*/。

3、proc：点击函数。如果菜单定义了默认点击函数，则此项可空，点击时交由默认点击函数处理。但仅限一级菜单项可空。二级菜单项需手动指定点击函数。

4、menu：包含的子菜单。如果定义了子菜单，则当前菜单项无法定义点击函数proc，且不会触发默认点击函数。

5、flag：控制菜单项的外观和性能的标志，可以是多值的组合，用"或"操作。

6、bitmap：正常图标，默认没有。可通过..com.picture.loadBitmap()或..gdip.bitmap("").copyHandle();实现。建议通过后者，可以支持更多的图片格式。

7、bitmapCheckd：选中图标，默认为黑色对号。设置方式同上。

3、已知问题：

1、使用png图片时，如果有半透明区域，则第一次弹出菜单，图标会出现锯齿。 建议使用bmp\jpg\ico或无半透明区域的png。

如图：    正常情况：

2、主菜单如果使用图片，且主窗口背景色为浅色，图片高度最好不要超过菜单默认高度(18)，否则菜单下边会多出1个像素。虽然不明显，但对于强/迫/症/爱/好/者，必须不可忍。

如下图：

3、弹出菜单如果使用图片作为菜单项目时，则所有项目的图片宽度最好保持一致。因为在没设置菜单图标时，菜单将该图片作为项目前景的同时，还同时拉伸至菜单项最宽度，作为背景显示，非常不美观。如下图：

4、上代码：

//窗口菜单
import win.ui;
import win.ui.menu;
/*DSG{{*/
var winform = win.form(text="菜单用法演示";right=497;bottom=345)
winform.add(
button={cls="button";text="Button";left=200;top=164;right=295;bottom=201;z=1}
)
/*}}*/

//图片建议用 ..gdip.bitmap("").copyHandle(); 可以支持各种图片格式。
var h1 = ..gdip.bitmap("\alert.png").copyHandle();
var h2 = ..gdip.bitmap("\download.png").copyHandle();

// 创建弹出菜单。
// 弹出菜单是不显示在窗口上的。1、被主菜单绑定调用。2、使用popup()函数弹出。
var menuFile = win.ui.popmenu(winform);

// 可以预先定义一个默认点击事件，非必需。
// 如果菜单项未单独定义点击函数，则执行此默认函数。
// 该函数必须在添加需要使用此函数的菜单项前进行定义。
menuFile.onMenuItemClick = function(id){
	var text = menuFile.getString(id,0);
	..win.msgbox("您点击了【"++text++"】，本例程由光庆编写","弹出菜单【文件】的默认点击事件");
}

// 添加一个普通的菜单项，可包含文本、图标、点击事件等。
menuFile.add(
	text="打开",
	bitmap = h1, //正常图标，默认没有。
	bitmapCheckd = h2, //选中图标，默认为黑色对号
	proc = function(id){
		// 在点击事件里改变当前菜单项的选中状态。
		menuFile.check(id,!menuFile.checked(id,0/*_MF_BYCOMMAND*/),0/*_MF_BYCOMMAND*/);
		winform.msgbox(menuFile.checked(id,0));
	}
) 

// 添加一个没有图标的普通菜单项。
// 菜单高度变为正常高度，可能与有图标的不一致，影响美观。
// 未指定点击事件，使用默认点击事件。
menuFile.add("保存1，没有图标，正常高度") 

// 添加一个没有图标的普通菜单项。
// 但为了保持菜单高度一致，创建一个空白图标，或使用一个透明png图片。
// 未指定点击事件，使用默认点击事件。
menuFile.add(
	text="保存2，空白图标，图标高度",
	bitmap = ..gdip.bitmap(1,32).copyHandle();
) 

// 添加一个包含子菜单的菜单项。包含文本、子菜单项。图标和点击事件无效。
// 不支持图标会影响菜单整体美观，暂未想到解决方法（自绘除外）。
var id=menuFile.add(
	text="记录，有子菜单，已修正无法创建图标的问题，图标高度",
	bitmap=h1,
	// proc有子菜单时是无效的，不支持点击事件
	menu = {
		{text="text1",bitmap=h1,proc=menuFile.onMenuItemClick}, // 子菜单如果需要使用默认点击函数，则需要手动指定。
		{}, // 分隔符
		{"text2",menuFile.onMenuItemClick} // 子菜单如果需要使用默认点击函数，则需要手动指定。
	}
) 

// 添加一个分隔符
menuFile.add() 

// 添加一个全图片菜单项。
menuFile.add(..gdip.bitmap("\item.png").copyHandle(),λ()win.msgbox("图片菜单项被点击了！"),4/*_MF_BITMAP*/)

// 添加一个全图片菜单项 + 图标。
menuFile.add(text=..gdip.bitmap("\item.png").copyHandle(),bitmap=h2,flag=4/*_MF_BITMAP*/)

// 添加一个普通菜单项，图标直接用gdip.bitmap()载入。
menuFile.add(
	text = "退出";
	bitmap = ..gdip.bitmap("\ShutDown.ico").copyHandle();
	proc = function(id){
		..win.quitMessage();
	};
);

// 创建主菜单。主菜单显示在窗口用户区上方
// 主菜单不支持图标+文字。但支持全文字或全图标。
var menu = win.ui.menu(winform);

// 可以预先定义一个默认点击事件，非必需。
// 如果菜单项未单独定义点击函数，则执行此默认函数。
// 该函数必须在添加需要使用此函数的菜单项前进行定义。
menu.onMenuItemClick = function(id){
	//方法1：根据菜单ID判断需要执行的操作。
	select(id) {
		case 50001 {
			..win.msgbox("您点击了50001，本例程由光庆编写");
		}
		case 50002 {
			..win.msgbox("您点击了50002，本例程由光庆编写");
		}
	}
	// 方法2：根据菜单文本判断需要执行的操作。
	var text = menu.getString(id,0);
	select(text) {
		case "关于1" {
			..win.msgbox("您点击了【关于1】，本例程由光庆编写");
		}
		case "关于2" {
			..win.msgbox("您点击了【关于2】，本例程由光庆编写");
		}
	}
}

// 添加一个主菜单项，并绑定一个弹出菜单。
menu.add('文件',menuFile) 

// 添加一个主菜单项，不绑定弹出菜单，但可以定义点击事件。
menu.add('编辑',function(){win.msgbox("主菜单项被点击了！")})

// 添加一个图片菜单项。主菜单项默认高度（也就是图片最佳高度）为18。
menu.add(..gdip.bitmap("\bohao.png").copyHandle(40,18),λ()win.msgbox("图片菜单项被点击了！"),4/*_MF_BITMAP*/)

// 添加一个主菜单项，不定义点击函数，让其使用默认点击函数。
// 默认点击函数必须在此之前已经预先进行定义。
// 可手动指定id，以便默认函数能更方便的进行识别。id切勿与其他项id（特别是自动分配的id）重复。
// 以下为两种添加方式：
menu.add(id=50001,text='关于1')
menu.add('关于2',,,50002)

// 手动弹出菜单
winform.button.oncommand = function(id,event){
	menuFile.popup()
}

winform.show() 
win.loopMessage();

5、相关图片资源下载：

6、如果有时间，再写一篇菜单自绘的笔记，预计会很炫，但很少有人会舍得费工夫去自绘。