职责链模式+策略模式+反射,完美实现下机操作(二)

上篇博客中介绍了如何应用职责链模式对上机时间进行处理，现在时间得到了，该怎么利用上机时间计算出上机消费金额呢？

策略模式（Strategy）:它定义了算法家族，分别封装起来，让它们之间可以互相替换，此模式让算法的变化不会影响到算法的客户。

这么看来，策略模式是非常适合用来处理机房收费系统的收银操作的。定义一个抽象算法类，BL_STG_CashSuper，会员用户和临时用户的收费算法分别写到BL_STG_CashVip，和BL_STG_CashTmp中，并继承BL_STG_CashSuper类。另外再定义一个BL_STG_CashContext类来判定具体使用哪个算法。

类图：

        

代码具现化：

1. BL_STG_CashSuper 抽象类，定义所有支持的算法的公共接口

Public MustInherit Class BL_STG_CashSuper
    '根据上机时间、卡的类型，计算出消费金额(抽象方法)
    Public MustOverride Function GetConsumeMoney(ByVal Time As Integer) As Single
End Class

2. BL_STG_CashVip 具体策略类，计算会员用户消费金额，封装了具体的算法或行为，继承于类 BL_STG_CashSuper

Imports Charge_EN
Public Class BL_STG_CashVip : Inherits BL_STG_CashSuper
    Dim queryBasedata As New BL_QueryBaseData                '实例化类BL_QueryBaseData用于查询基础数据
    Dim ENBaseDatainfo As New EN_BaseData_info               '定义基础数据实体
    Dim basedatalist As List(Of EN_BaseData_info)            '定义实体的泛型集合
    Dim VipHourCash As Single                                '定义变量存放会员用户每小时费用 

    Public Overrides Function GetConsumeMoney(Time As Integer) As Single
        '调用查询方法获取数据，且赋值给实体泛型集合
        basedatalist = queryBasedata.queryBaseData(ENBaseDatainfo)

        VipHourCash = basedatalist(0).vipcost                '给变量赋值（会员用户每小时费用）
        Dim comsumecash As Single                            '定义变量存放消费金额
        comsumecash = CSng(Time) * CSng(VipHourCash / 60)    '计算消费金额
        Return comsumecash                                   '返回消费金额
    End Function
End Class

 

3. BL_STG_CashTmp 具体策略类，计算临时用户消费金额，封装了具体的算法或行为，继承于类 BL_STG_CashSuper

Imports Charge_EN
Public Class BL_STG_CashTmp : Inherits BL_STG_CashSuper

    Dim queryBasedata As New BL_QueryBaseData                '实例化类BL_QueryBaseData用于查询基础数据
    Dim ENBaseDatainfo As New EN_BaseData_info               '定义基础数据实体
    Dim basedatalist As List(Of EN_BaseData_info)            '定义实体的泛型集合
    Dim TmpHourCash As Single                                '定义变量存放临时用户每小时费用

    Public Overrides Function GetConsumeMoney(Time As Integer) As Single
        '调用查询方法获取数据，且赋值给实体泛型集合
        basedatalist = queryBasedata.queryBaseData(ENBaseDatainfo)

        TmpHourCash = basedatalist(0).tmpcost                '给变量赋值（会员用户每小时费用）
        Dim comsumecash As Single                            '定义变量存放消费金额
        comsumecash = CSng(Time) * CSng(TmpHourCash / 60)    '计算消费金额
        Return comsumecash                                   '返回消费金额
    End Function
End Class

4. BL_STG_CashContext ,应用简单工厂模式，通过传入的卡的类型，来具体选择应用哪个算法。

Public Class BL_STG_CashContext
    Private cashsuper As BL_STG_CashSuper           '定义抽象类
    Public Sub New(ByVal CardType As String)

        'select语句进行判断选择传入的卡类型,进行自动创建消费类型
        Select Case CardType
            Case "固定用户"
                cashsuper = New BL_STG_CashVip()    '创建固定用户收费类型
            Case "临时用户"
                cashsuper = New BL_STG_CashTmp()    '创建临时用户收费类型
            Case Else
                CardType = Nothing
        End Select
    End Sub
    Public Function GetResult(ByVal Time As Integer) As Single
        '调用相关的消费处理类计算收费方法
        Return cashsuper.GetConsumeMoney(Time)
    End Function
End Class

    策略模式封装了变化，消除了条件语句，避免了大量的判断，特别是在和简单工厂模式结合后，把具体实现的职责交给BL_STG_CashContext类来承担，这就最大化的减轻了客户端的职责。

    但是这样仍然不够完美，假如我们需要增加一种算法的时候，比如说，超级会员收费方式；那么在增加一个超级会员算法类的同时还需要去修改BL_STG_CashContext类中的Select语句，开闭原则又没有好好遵守，这总是让人很不爽~别忘记还有一招反射呢。

利用反射技术，对BL_STG_CashContext类进行改造

Imports System.Reflection                           '添加反射的引用
Public Class BL_STG_CashContext
    Private cashsuper As BL_STG_CashSuper           '定义抽象类
    Public Sub New(ByVal CardType As String)

        '应用反射技术根据卡号类型自动选择应该实例化的类
        Dim strInstance As String = "Charge_BLL.BL_STG_Cash" + CardType
        cashsuper = CType(Assembly.Load("Charge_BLL").CreateInstance(strInstance), BL_STG_CashSuper)
    End Sub
    Public Function GetResult(ByVal Time As Integer) As Single
        '调用相关的消费处理类计算收费方法
        Return cashsuper.GetConsumeMoney(Time)
    End Function
End Class

反射，反射程序员的快乐，这样再添加新算法的时候连BL_STG_CashContext类也不用改动了。

U层调用

        '===根据获得的上机时间，应用策略模式计算消费金额==========================================
        Dim CardType As String
        '---进行字符串转换，转换为反射识别的字符
        Select Case Cardlist(0).Cardtype
            Case "会员"
                CardType = "Vip"
            Case "临时用户"
                CardType = "Tmp"
            Case Else
                CardType = ""
        End Select
        '---实例化类BL_STG_CashContext,传入用户类型
        Dim cashcontext As New BL_STG_CashContext(CardType)
        '---调用策略模式计算出余额并且赋值给consumecash
        Dim consumecash As Single = cashcontext.GetResult(ENLineinfo.consumeTime)
        '---定义变量newbalance,用于存放最新的余额
        Dim newbalance As Single = CSng(Cardlist(0).balance.ToString) - CSng(consumecash)
        '==================================================================================

 

任何需求的变更都是需要成本的，我们需要做的就是怎么才能以最小的代价完成这些变更。       --大鸟

而设计模式正式为此而生。

 

机房收费系统的下机就到这里了，有什么不合理的地方，路过的大鸟指点一二。。