裸机开发之点亮LED

基于X210开发板的LED灯点亮。

---

原理图和引脚分析

查阅底板原理图可以得到，四个LED引脚分别为：

• D22：GPJ0_3
• D23：GPJ0_4
• D24：GPJ0_5
• D25：PWMTOUT1

其中PWMTOUT1引脚与核心板的GPD0_1引脚相连，所以可以通过操作GPD0_1引脚来操作D25。

GPIO

GPIO,General Purpose Input Output的简称，属于芯片上的一部分引脚，这部分引脚可以被编程控制工作模式和电压高低，以上的四个引脚都属于GPIO引脚的一部分，所以我们可以通过编程控制这些LED的开和关

寄存器

软件操作硬件的接口就是寄存器，我们如果要操作控制这些GPIO，就要操控GPIO的寄存器，通过读写这些寄存器来让GPIO发生响应的动作，查阅S5PV210的用户手册的GPIO的章节可以得到GPJ0的相关寄存器：

• GPJ0CON,
  
  • GPJ0 Control Register：控制寄存器
  • R/W：可读写
  • Address = 0xE020_0240：寄存器硬件地址
  • 一共有32位,每4位是一种功能，是一个多功能寄存器，我们要使用的3,4,5引脚就是在这里配置的
  • 作用是用来配置各个引脚的控制模式，在LED项目中，我们应该把引脚配置为Output模式，目的是让其输出高低电平，
  • 可以得到，我们需要把GPJ0CON的3,4,5引脚配置为0001的输出模式
• GPJ0DAT,数据寄存器，一共8位
  
  • 当GPJ0CON被配置为输入模式的时候，相对位置中的数据就是我们要读取的数据，
  • 如果被配置为输出模式，则需要向相对位置中写入数据
  • 可以得出，我们已经配置为输出模式，则需要向3,4,5位写入数据
• GPJ0PUD,Pull-up/ down，控制引脚的弱上/下拉
• GPJ0DRV,deiver，用于配置GPIO引脚的驱动能力，驱动电流大小
• GPJ0CONPDN，上/下拉寄存器
• GPJ0PUDPDN，上/下拉寄存器

通过上面步骤可以得到我们点亮LED的编程步骤：

• 定位到GPJ0CON寄存器，内存地址0xE020_0240
• 操作该内存地址的12~15,16~19,20~23位
• 分别在这几个位写入0001从而开启输出模式
• 定位到GPJ0DAT寄存器，内存地址0xE020_0244
• 操作该内存地址的3,4,5位
• 分别在这几个位写入0，从而让对应引脚输出低电平，在LED负极与正极形成正向电压差，则LED就会被点亮

汇编操作寄存器

汇编代码：

#define GPJ0CON 0xE0200240
#define GPD0CON 0xE02000A0

#define GPJ0DAT 0xE0200244
#define GPD0DAT 0xE02000A4

.global _start          // 把_start声明为外部可访问，以便汇编程序定位到这里开始运行
_start:
    // 把0x11111111写入0xE0200240(GPJ0CON)
    ldr r0,=0x11111111  // =号可以看出使用的是ldr伪指令
    ldr r1,=GPJ0CON
    str r0,[r1]     // 寄存器间接寻址，把r0中的数据写到r1指针指向的变量中

    ldr r4,=1<<4    // 配置LED6控制引脚为输出引脚
    ldr r5,=GPD0CON
    str r4,[r5]
flash:
    // 使用位移进行运算
    ldr r0,=1<<1    //熄灭LED6
    ldr r1,=GPD0DAT
    str r0,[r1] // 引脚输出低电平

    ldr r0,=~(1<<3)    // 点亮LED3，其他熄灭
    ldr r1,=GPJ0DAT
    str r0,[r1] // 引脚输出低电平

    bl delay    // 调用延时函数

    ldr r0,=1<<1    //熄灭LED6
    ldr r1,=GPD0DAT
    str r0,[r1] // 引脚输出低电平

    ldr r0,=~(1<<4)    //点亮中间的LED4灯
    ldr r1,=GPJ0DAT
    str r0,[r1] // 引脚输出低电平

    bl delay    // 调用延时函数

    ldr r0,=1<<1    //熄灭LED6
    ldr r1,=GPD0DAT
    str r0,[r1] // 引脚输出低电平

    ldr r0,=~(1<<5)    //点亮LED5
    ldr r1,=GPJ0DAT
    str r0,[r1] // 引脚输出低电平

    bl delay    // 调用延时函数

    ldr r0,=0<<1    //点亮LED6
    ldr r1,=GPD0DAT
    str r0,[r1] // 引脚输出低电平

    ldr r0,=(1<<3 | 1<<4 | 1<<5)    //熄灭其他灯
    ldr r1,=GPJ0DAT
    str r0,[r1] // 引脚输出低电平

    bl delay    // 调用延时函数

    b flash;    // 使用b进行不返回跳转,实现无限循环

delay:          // 延时函数
    ldr r2,=9999999
    ldr r3,=0x0
delay_loop:
    sub r2,r2,#1    // r2递减
    cmp r2,r3   // 通过比较会影响CPSR的Z标记，等于的话Z=1，eq就会成立，否则下一句的ne就会成立
    bne delay_loop  // 如果不等就继续循环
    mov pc,lr   // 返回，将lr中的地址放到pc中，以便调用函数继续运行

make之后，就可以烧写进开发板进行裸机运行了。