AS3的对象池

1. 为什么使用对象池

假设游戏当中，玩家按下鼠标，那么游戏场景中出现一个美女A，代码是

var A:美女A=new 美女A();
addChild(A);

放开鼠标美女被清除，代码是：

 A.dispose();A=null;  

如果某个玩家不停地点击鼠标，那么我们的代码将不停的NEW 美女A()而NEW 美女A()其实是很费时消耗系统性能这是问题就来了，假设NEW 美女A()消耗了2KB内存，玩家疯狂点一千次，那么我们的美女类就不断地创建，清除，创建，清除，那么我们的游戏内存直接增加1000*2kb，因为FLASH是托管的GC清理资源，具体什么时候清理只有GC知道，那么我们的游戏的性能就.........可是如果我们有了对象池那又是一种什么情况呢？首先美女将被new 美女A() 然后美女A被放入到对象池中存放，当鼠标按下的时候我们将执行：ObjectPool. borrowObject()：取得美女A，当鼠标按下我们执行ObjectPool.returnObject()：这样子美女又被放入到对象池中存起来了，执行一千次，由于使用对象池取得美女A和放入美女A中不涉及到对象的创建和销毁，所以我们的游戏不会导致系统资源的增加。因为美女A被访到内存池中存储起来重复利用了。

2. 对象池原理

对象池的工作原理的核心有两点：使用和缓存，即对于那些被频繁使用的对象，在使用完后，不立即将它们释放，而是将它们缓存起来，以供后续的应用程序重复使用，从而减少创建对象和释放对象的次数，进而改善应用程序的性能。

优点：能快速取出对象节省了NEW对象所产生的cpu，时间的消耗。能很好的控制内存的占用，使用时从对象池取出，使用完毕放回。中间不涉及到对象销毁创建，所以内存占用是定量的。

要实现一个对象池，一般会涉及到以下的几个类：

目标对象（SomeObject）类

     该类就是程序中频繁使用的对象。

对象池（ObjectPool)类

    该类主要用于管理对象的借出和归还，并通知对象池完成相应的工作。它至少包含两个方法：

　 borrowObject()：用于从池中借出对象；

　 returnObject()：将对象归还到池中；

代码如下：

package wingox.pool {
    import flash.utils.Dictionary;

    /**
     * @version 20100315
     * @author BrightLi
     */
    public class ObjectPool {

        private static var _pool : Dictionary = new Dictionary(true);

        private var _template : Class;

        private var _list : Array;

        public function ObjectPool(value : Class) {
            _template = value;
            _list = new Array();
        }

        public function borrowObject() : Object {
            if(_list.length > 0) {
                return _list.shift();
            }
            return new _template();
        }

        public function returnObject(value : Object) : void {
            _list.push(value);
        }

        public static function getPool(value : Class) : ObjectPool {
            if(!_pool[value]) {
                _pool[value] = new ObjectPool(value);
            }
            return _pool[value];
        }
    }
}

对象池如果用的不好可能会造成极大的内存问题，要视情况而定，只有经常用到的对象才可以池化，如果在整个程序生命期中只用过一两次的显示对象一定不要池化否则相当于自己制造了AVM永远不会GC的“垃圾”。
举个例子：如登录界面，这个只会用到一次的显示对象，一定不要池化！