扩展Event 让事件带参

//-----------------------------------------------------------------------------------------------------------------------------------
//-----------------------------------------------------------------------------------------------------------------------------------

//testb.fla 帧上的代码

var element:int = 0;
var value:int = 0;

btn.addEventListener(MouseEvent.CLICK, btnClick);

function btnClick(e){
	
	element++;
	value++;
	
	dispatchEvent(new CustomEvent(CustomEvent.UPDATE_TEXT, String(element), String(value)));
}

//-----------------------------------------------------------------------------------------------------------------------------------
//-----------------------------------------------------------------------------------------------------------------------------------

//testa.fla 帧上的代码

import flash.display.Loader;
import flash.events.Event;
import flash.net.URLRequest;
import flash.display.MovieClip;

var swfMC:MovieClip;

var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, swfCom);
loader.load(new URLRequest("testb.swf"));

function swfCom(e){
	swfMC = e.target.content as MovieClip;
	swfMC.addEventListener(CustomEvent.UPDATE_TEXT, scoreBoardUpdateListener, false, 0, true);
	addChild(swfMC);
}

function scoreBoardUpdateListener(e:CustomEvent):void{
	updateData(e.element, e.value);
}

function updateData(elements:String, value:String):void{
	trace(elements + "/" + value);
}

//-----------------------------------------------------------------------------------------------------------------------------------
//-----------------------------------------------------------------------------------------------------------------------------------

//事件类
package
{
	import flash.events.Event;
	public class CustomEvent extends Event
	{
		public static const UPDATE_TEXT:String = "customEvent";
		public var element:String;
		public var value:String;

		public function CustomEvent(type:String,element:String, value:String, bubbles:Boolean=false,cancelable:Boolean=false)
		{
			super(type, bubbles,cancelable);
			this.element = element;
			this.value = value;
		}
		
		public override function clone():Event {
			return new CustomEvent(type,element,value, bubbles,cancelable)
		}
	}
}