【原创】uC/OS II 任务切换原理

最新推荐文章于 2023-02-12 21:41:12 发布

weixin_33768481

最新推荐文章于 2023-02-12 21:41:12 发布

阅读量159

点赞数

原文链接：http://www.cnblogs.com/cposture/p/4291503.html

版权

今天学习了uC/OS II的任务切换，知道要实现任务的切换，要将原先任务的寄存器压入任务堆栈，再将新任务中任务堆栈的寄存器内容弹出到CPU的寄存器，其中的CS、IP寄存器没有出栈和入栈指令，所以只能引发一次中断，自动将CS、IP寄存器压入堆栈，再利用中断返回，将新任务的任务断点指针弹出到CPU的CS、IP寄存器中，实现任务切换。虽然明白个大概，但是其中的细节却有点模糊，为什么调用IRET中断返回指令后，弹入CPU的CS、IP寄存器的断点指针是新任务的断点指针，而不是当前任务的，UCOS II是如何实现这个过程的？网上的文章没有提及任务切换的细节，然而这些细节却是理解的重点，所以才有了今天这一篇文章！

在uC/OS II中，任务的调度由任务调度器完成，其主要的工作有两项：

1.在任务就绪表中查找最高优先级的就绪任务，该任务将是未来切换执行的任务；

2.实现任务的切换。

任务级的任务调度器，由OS_Sched()实现。

 1     //!!!为简单说明问题，OS_Sched中特意删减了一些语句
 2     void OS_Sched (void)
 3     {
 4     INT8U y;
 5     OS_ENTER_CRITICAL();
 6     y =OSUnMapTbl[OSRdyGrp];
 7     //得到最高优先级任务，OSPrioHighRdy从此为就绪表中最高优先级任务的优先级别
 8     OSPrioHighRdy=(INT8U)((y <<3)+OSUnMapTbl[OSRdyTbl[y]]);
 9     //判断当前任务是否为就绪表中最高优先级任务
10     if(OSPrioHighRdy!=OSPrioCur)
11     {
12     //得到新任务的任务控制块的指针
13     OSTCBHighRdy=OSTCBPrioTbl[OSPrioHighRdy];
14     //统计任务切换次数的计数器加1
15     OSCtxSwCtr++;
16     //此句关键！使用软件中断切换任务，OS_TASK_SW()其实为INT 0x80，128号中断
17     //中断产生后，CPU依次将PSW状态寄存器、断点指针段地址：偏移地址压入当前任务的堆栈中
18     OS_TASK_SW();
19     }
20     OS_EXIT_CRITICAL();
21     }

View Code

从上述代码，可以知道，OS_Sched的任务切换步骤分为两步：

1.获得最高优先级任务的任务控制块指针；

2.利用中断实现断点数据的切换。（当前任务中止运行时，CPU寄存器 CS、IP 、PSW和通用寄存器等中的数据就称为断点数据）

在获得了新任务的任务控制块指针，相当于获得了任务控制块中包含的任务堆栈，而任务堆栈中又包含了该任务运行时，CPU寄存器的初始内容，即断点数据。前面已经提到过 “ 要实现任务的切换，要将原先任务的寄存器压入任务堆栈，再将新任务中任务堆栈的寄存器内容弹出到CPU的寄存器 ”，除了 CS、IP 寄存器，其他寄存器只需要利用出栈和入栈指令即可，而 CS、IP 寄存器的出栈、入栈要利用中断INT 0x80和IRET。好吧，那问题来了，uC/OS是如何利用中断实现断点指针CS、IP的切换？

产生INT 0x80后，CPU做了什么，当然是去执行和 INT 0x80相关的中断服务程序去了（说明：每个中断都有一个对应好的中断服务程序，每当产生该中断，则由CPU自动调用该对应的中断服务程序）。

在uC/OS II中，INT 0x80对应的中断服务程序是

 1     _OSCtxSw PROC FAR
 2     ;
 3     ;保存当前任务寄存器内容，将它们压入当前任务堆栈，AX、CX、DX、BX、SP（原始值）、BP、SI 及 DI
 4     PUSHA ;
 5     PUSH ES ;
 6     PUSH DS ;
 7     ;
 8     ;将当前任务的任务控制块的指针段地址赋值给DS寄存器
 9     MOV AX, SEG _OSTCBCur;Reload DS in case it was altered
10     MOV DS, AX ;
11     ;
12     ; LES指令作用，取得OSTCBCur变量内容（因为任务控制块的第一个成员为任务堆栈指针，所以ES:[BX+0]表示的地址不仅是任务控制块的首地址，也是任务堆栈指针的地址），低字存放于BX，高字存放于ES，有关LES详细查看另一篇文章！
13     ;同时由于任务控制块的第一成员为任务堆栈指针变量，所以任务堆栈指针成员变量的地址和任务控制块的地址一样
14     LES BX, DWORD PTR DS:_OSTCBCur; OSTCBCur->OSTCBStkPtr = SS:SP！！！
15     MOV ES:[BX+2], SS ;将当前SS（栈的基地址）寄存器值存放至当前任务控制块的2，3内存单元
16     MOV ES:[BX+0], SP ;将当前SP（栈顶的偏移量）存放至当前任务控制块的0，1内存单元
17     ;
18     CALL FAR PTR _OSTaskSwHook;Call user defined task switch hook
19     ;
20     ;存储器寻址，DS:_OSTCBHighRdy+2存放的是新任务的栈基址SS，DS:_OSTCBHighRdy存放的是栈顶偏移量SP
21     MOV AX, WORD PTR DS:_OSTCBHighRdy+2;将OSTCBHighRdy赋值给OSTCBCur，使OSTCBCur指向新的任务控制块
22     MOV DX, WORD PTR DS:_OSTCBHighRdy;OSTCBCur=OSTCBHighRdy
23     MOV WORD PTR DS:_OSTCBCur+2, AX ;
24     MOV WORD PTR DS:_OSTCBCur, DX ;
25     ;
26     MOV AL, BYTE PTR DS:_OSPrioHighRdy;OSPrioCur=OSPrioHighRdy
27     MOV BYTE PTR DS:_OSPrioCur, AL ;
28     ;
29     ;将最高级优先级任务的任务控制块包含的SS和SP寄存器值，CPU的SS和SP指向了新的任务堆栈
30     LES BX, DWORD PTR DS:_OSTCBHighRdy; SS:SP =OSTCBHighRdy->OSTCBStkPtr
31     MOV SS, ES:[BX+2];
32     MOV SP, ES:[BX];
33     ;
34     ;注意：这里弹出的是新任务的堆栈，而不是旧的，因为CPU的SS和SP已经指向了新的任务堆栈
35     POP DS ;Loadnew task's context
36     POP ES ;
37     POPA ;
38     ;
39     ;当新任务的堆栈都弹出的时候，只剩下新任务的CS、IP指针，刚好运行IRET弹到CPU的CS、IP寄存器，开始新任务的运行
40     IRET ;Return to new task
41     ;
42     _OSCtxSw ENDP

View Code

请仔细将上面代码对照着注释看一遍，注释已经说得很清楚了，_OSCtxSw的堆栈操作，可以看下面两幅图

（0）在调用 _OSCtxSw中断服务程序前，CPU将PSW和任务断点指针CS、IP压入当前任务堆栈

（1）将CPU寄存器 AX、CX、DX、BX、SP（原始值）、BP、SI 及 DI压入当前任务堆栈

（2）将当前 CPU 的堆栈指针SS和SP存入当前任务控制块的任务堆栈指针变量（FAR指针变量占4字节）

说明：至此，当前任务的断点数据已经全部保存，所以在每一个新任务运行之前，uC/OS都会将旧任务的断点数据全部按照顺序压入私有堆栈中，同时每一个新任务的任务堆栈都已保存初始化好的或以前任务中止时，CPU保存的断点数据。

（3） OSTCBCur = OSTCBHighRdy、 OSPrioCur = OSPrioHighRdy

（4）使CPU的SS和SP堆栈指针指向新的任务堆栈

（5）将新的任务堆栈的内容弹出到CPU寄存器，顺序为DS、ES、DI、SI、BP、SP、BX、DX、CX、AX。

说明：注意是新任务堆栈在进行弹栈操作，而新任务堆栈在弹栈前，和旧任务的断点数据全部压栈后的结构一模一样，都是顺序为DS、ES、DI、SI、BP、SP、BX、DX、CX、AX、IP、CS、PSW。经过POP DS POP ES POPA，这3条指令之后，新任务堆栈便只剩下 IP、CS、PSW，IP和CS这断点指针指向新任务的任务代码，只要将它们弹出到CPU的CS、IP寄存器，就可以实现任务切换。

（6）运行IRET，将新任务断点指针弹出到CPU的 CS、IP 指针寄存器，PSW弹出到CPU的PSW寄存器

（7）至此，uC/OS开始运行新任务