***********************************************读取模版图像*****************************************************
read_image (Image, 'image/board-01.png')
get_image_size (Image, Width, Height)
dev_open_window (0, 0, Width, Height, 'black', WindowHandle)
dev_display (Image)
dev_set_draw ('margin')
Row:=143
Column:=306
Phi:=rad(0.3)
Length1:=157.0
Length2:=20.0
***********************************************创建形状模板**************************************************
*画矩形
*draw_rectangle2 (WindowHandle, Row, Column, Phi, Length1, Length2)
*生成矩形
gen_rectangle2 (Rectangle, Row, Column, Phi, Length1, Length2)
*剪切矩形区域图像
reduce_domain (Image, Rectangle, ImageReduced)
*用创建形状模型
create_shape_model (ImageReduced, 'auto', 0, rad(360), 'auto', 'none', 'use_polarity', 30, 10, ModelID)
*create_shape_model_xld (SelectedContoursModel, 'auto', rad(0), rad(90), 'auto', 'auto', 'ignore_local_polarity', 3, ModelID)
*在模版图像中搜索模版
find_shape_model (Image, ModelID, 0, rad(360), 0.4, 1, 0, 'least_squares', 0, 0.7, ModelRow, ModelColumn, ModelAngle, ModelScore)
*获取模版轮廓
get_shape_model_contours (ShapeModel, ModelID, 1)
stop ()
************************************************自定义测试窗口ROI*********************************************
dev_display (Image)
*draw_rectangle2 (WindowHandle, Row, Column, Phi, Length1, Length2)
OffsetRow:=Row-ModelRow
OffsetColumn:=Column-ModelColumn
*根据模版坐标位置和ROI窗口生成新的测试窗口
gen_rectangle2 (Rectangle, ModelRow+OffsetRow, ModelColumn+OffsetColumn, Phi,Length1, Length2)
************************************************连续图像采集*************************************************
* Image Acquisition 01: Code generated by Image Acquisition 01
ImageFiles := []
ImageFiles[0] := 'image/board-01.png'
ImageFiles[1] := 'image/board-02.png'
ImageFiles[2] := 'image/board-03.png'
ImageFiles[3] := 'image/board-04.png'
ImageFiles[4] := 'image/board-05.png'
ImageFiles[5] := 'image/board-06.png'
ImageFiles[6] := 'image/board-07.png'
ImageFiles[7] := 'image/board-08.png'
ImageFiles[8] := 'image/board-09.png'
ImageFiles[9] := 'image/board-10.png'
ImageFiles[10] := 'image/board-12.png'
ImageFiles[11] := 'image/board-13.png'
ImageFiles[12] := 'image/board-14.png'
ImageFiles[13] := 'image/board-15.png'
ImageFiles[14] := 'image/board-16.png'
ImageFiles[15] := 'image/board-17.png'
ImageFiles[16] := 'image/board-18.png'
ImageFiles[17] := 'image/board-19.png'
ImageFiles[18] := 'image/board-20.png'
**********************************************测试窗口跟随被测物体对齐******************************************
for Index := 0 to |ImageFiles| - 1 by 1
read_image (Image, ImageFiles[Index])
dev_display (Image)
RowCheck:=0
ColumnCheck:=0
AngleCheck:=0
Score:=0
*在搜索图像中寻找模版
find_shape_model (Image, ModelID, 0, rad(360), 0.4, 1, 0, 'least_squares', 0, 0.7, RowCheck, ColumnCheck, AngleCheck, Score)
*生成2D齐次变换矩阵
hom_mat2d_identity (HomMat2DIdentity)
*添加偏移转换到2D齐次变换矩阵上
hom_mat2d_translate (HomMat2DIdentity, RowCheck, ColumnCheck, HomMat2DTranslate)
*添加旋转转换到2D齐次变换矩阵上
hom_mat2d_rotate (HomMat2DTranslate, AngleCheck, RowCheck, ColumnCheck, HomMat2DRotate)
*对模版形状进行仿射变换
affine_trans_contour_xld (ShapeModel, ShapeModelTrans, HomMat2DRotate)
*显示仿射变换后的模版形状
dev_display (ShapeModelTrans)
*对OffsetRow, OffsetColumn这两个坐标执行仿射变换
affine_trans_pixel (HomMat2DRotate, OffsetRow, OffsetColumn, OutLeftRow, OutLeftColumn)
*生成要跟随被测物的测试窗口ROI
gen_rectangle2 (OutRectangle, OutLeftRow, OutLeftColumn, Phi+AngleCheck, Length1, Length2)
*显示图像
dev_display (Image)
*显示测试窗口ROI
dev_display (OutRectangle)
stop()
endfor
halcon模板匹配之被测物通过仿射变换跟随窗口移动
于 2023-12-16 08:09:30 首次发布