1.内核引导和初始化

处理器上电以后，首先执行引导程序，引导程序把内核加载到内存，然后执行内核，内核初始化完成以后，启动用户空间的第一个进程。

1.到哪里读取引导程序

处理器到哪里读取引导程序的指令呢？处理器在上电时自动把程序计数器设置为处理器厂商设计的某个固定值。对于ARM64处理器，这个固定值是0，处理器的内存管理单元（Memory Managemant Unit ，MMU）负值把虚拟地址转换为物理地址，ARM64处理器刚上电时没有开启内存管理单元，物理地址和虚拟地址相同，所以ARM64处理器到物理地址0取第一条指令。
嵌入式设备常用NOR闪存作为只读存储器来存放引导程序。NOR闪存的容量比较小，最小读写单位是字节，程序可以直接在芯片内执行。从物理地址0开始的一段物理地址空间被分配给NOR闪存。
综上所述：ARM64处理器到虚拟地址0取地址，就是到物理地址0取地址，也就是到NOR闪存的起始位置取指令。
注：
1.程序计数器就是pc，pc中存放指令的地址。
2.NOR闪存是随机存储介质,用于数据量较小的场合;NAND闪存是连续存储介质,适合存放大的数据。
3. 闪存是一种长寿命的非易失性(在断电情况下仍能保持所存储的数据信息)的存储器，数据删除不是以单个的字节为单位而是以固定的区块为单位。注意:NOR Flash 为字节存储。

2.引导程序

嵌入式设备通常U-boot作为引导程序。 u-boot是德国DENX软件中心开发的引导程序，是遵循GPL条款的开源项目。
下面简要介绍ARM64处理器的uboot程序的执行过程，入口是文件"arch/arm/cpu/armv8/start.S"定义的标号_start,我们从标号_start开始分析。

2.1 入口_start

标号_start是U-Boot程序的入口，直接跳转到标号reset执行。

.globl  _start
_start:
b reset 

2.2 标号reset

从标号reset开始的代码如下：

reset:
	/* Allow the board to save important registers 允许板卡保存重要的寄存器 */
	b	save_boot_params
.globl	save_boot_params_ret
save_boot_params_ret:

#if CONFIG_POSITION_INDEPENDENT
	/*
	 * Fix .rela.dyn relocations. This allows U-Boot to be loaded to and
	 * executed at a different address than it was linked at.
	 */
pie_fixup:
	adr	x0, _start		/* x0 <- Runtime value of _start */
	ldr	x1, _TEXT_BASE		/* x1 <- Linked value of _start */
	sub	x9, x0, x1		/* x9 <- Run-vs-link offset */
	adr	x2, __rel_dyn_start	/* x2 <- Runtime &__rel_dyn_start */
	adr	x3, __rel_dyn_end	/* x3 <- Runtime &__rel_dyn_end */
pie_fix_loop:
	ldp	x0, x1, [x2], #16	/* (x0, x1) <- (Link location, fixup) */
	ldr	x4, [x2], #8		/* x4 <- addend */
	cmp	w1, #1027		/* relative fixup? */
	bne	pie_skip_reloc
	/* relative fix: store addend plus offset at dest location */
	add	x0, x0, x9
	add	x4, x4, x9
	str	x4, [x0]
pie_skip_reloc:
	cmp	x2, x3
	b.lo	pie_fix_loop
pie_fixup_done:
#endif

#ifdef CONFIG_SYS_RESET_SCTRL
	bl reset_sctrl
#endif
	/*
	 * Could be EL3/EL2/EL1, Initial State:  //异常级别可能是3，2，1
	 * 初始状态：Little Endian, MMU Disabled, i/dCache Disabled
	 * 小端字节序，禁止MMU，禁止指令/数据缓存。
	 */
	adr	x0, vectors
	switch_el x1, 3f, 2f, 1f
3:	msr	vbar_el3, x0
	mrs	x0, scr_el3
	orr	x0, x0, #0xf			/* SCR_EL3.NS|IRQ|FIQ|EA，设置寄存器SCR_EL3的NS,IRQ,FIQ和EA四个位 */
	msr	scr_el3, x0
	msr	cptr_el3, xzr			/* Enable FP/SIMD，启用浮点和SIMD功能 */
#ifdef COUNTER_FREQUENCY
	ldr	x0, =COUNTER_FREQUENCY
	msr	cntfrq_el0, x0			/* Initialize CNTFRQ */
#endif
	b	0f
2:	msr	vbar_el2, x0
	mov	x0, #0x33ff
	msr	cptr_el2, x0			/* Enable FP/SIMD */
	b	0f
1:	msr	vbar_el1, x0
	mov	x0, #3 << 20
	msr	cpacr_el1, x0			/* Enable FP/SIMD */
0:

	/*
	 * Enable SMPEN bit for coherency.
	 * This register is not architectural but at the moment
	 * this bit should be set for A53/A57/A72.
	 */
#ifdef CONFIG_ARMV8_SET_SMPEN
	switch_el x1, 3f, 1f, 1f
3:
	mrs     x0, S3_1_c15_c2_1               /* cpuectlr_el1 */
	orr     x0, x0, #0x40
	msr     S3_1_c15_c2_1, x0
1:
#endif

	/* Apply ARM core specific erratas */
	bl	apply_core_errata

	/*
	 * Cache/BPB/TLB Invalidate
	 * i-cache is invalidated before enabled in icache_enable()
	 * tlb is invalidated before mmu is enabled in dcache_enable()
	 * d-cache is invalidated before enabled in dcache_enable()
	 */

	/* Processor specific initialization */
	bl	lowlevel_init

#if defined(CONFIG_ARMV8_SPIN_TABLE) && !defined(CONFIG_SPL_BUILD)
	branch_if_master x0, x1, master_cpu
	b	spin_table_secondary_jump
	/* never return */
#elif defined(CONFIG_ARMV8_MULTIENTRY)
	branch_if_master x0, x1, master_cpu

	/*
	 * Slave CPUs
	 */
slave_cpu:
	wfe
	ldr	x1, =CPU_RELEASE_ADDR
	ldr	x0, [x1]
	cbz	x0, slave_cpu
	br	x0			/* branch to the given address */
#endif /* CONFIG_ARMV8_MULTIENTRY */
master_cpu:
	bl	_main  /*主处理器执行函数_main*/

注：
1.b和bl都是跳转的意思，即执行子程序；
2.异常级别：
【ARMv8】异常级别的定义EL0、EL1、EL2、EL3

3.SIMD全称Single Instruction Multiple Data，单指令多数据流，能够复制多个操作数，并把它们打包在大型寄存器的一组指令集。

第二阶段程序加载器

U-BOOT分为SPL和正常的U-boot程序两部分，如果想要编译SPL，需要开启配置宏CONFIG_SPL_BUILD。SPL是"Secondary Program Loader"的简称，即第二段程序加载器，第二阶段是相对于处理器里面的只读存储器中的固化程序来说的，处理器启动时最先执行的是只读存储器中的固化程序。
固化程序通过检测启动方式来加载第二段程序加载器。为什么需要第二阶段程序加载器？原因是：一些处理器内部集成的静态随机访问存储器比较小，无法装载一个完整的U-BOOT，此时需要第二段程序加载器，它主要负责初始化内存和存储设备驱动，然后把正常的U-boot镜像从存储设备读到内存中去执行。