千兆以太网的双向图像传输和显示系统(2)

1. 实现目标：上位机通过串口发送图片到FPGA中，FPGA接收图片并保存在DDR2中，保存在 DDR2中的图片分为两路，一路经过VGA时序输出到RGB触摸屏上，另一路按照以太网帧格式进 行编码, 将以太网帧发送到PC端后，可用上位机软件实时显示视频图像。
2. 主要工作：1.FPGA串口图像接收。2.DDR2读写。3.千兆以太网发送。4.VGA视频图像显示。
3. 使用工具：Quartus ii、Modelsim、Wireshark、小梅哥UDP摄像头、串口传图工具。
   二、串口数据转换（将串口单字节数据拼接成图像原来的16位RGB565格式）
   转换简易波形图如下：
   

//接收图像大小800*480
module uart2ddr2(
	//system interface
	clk50M,
	rst_n,
	//uart_byte_rx interface
	data8bit,
	data8bit_en,
	//fifo interface
	//	FIFO Write Side 1
	wr1_data,
	wr1,	
	//external interface	
	ctrl_state,
	rx_img_done
);
	//system interface
	input clk50M;             //系统时钟
	input rst_n;              //系统异步复位
	//uart_byte_rx interface
	input [7:0]data8bit;      //串口接收的8位数据
	input data8bit_en;        //串口接收完成标志位
	//fifo interface
	output reg wr1;         //fifo写控制
	output [15:0]wr1_data;	     //fifo写数据
	//external interface		
	output reg rx_img_done;   //一张图片数据传送完成标志位
	
	output reg ctrl_state;
		
//	reg ctrl_state;           //读写控制状态，1代表可写状态，0代表可读状态

	localparam h_pixel = 800, //屏的行像素点
	           v_pixel = 480; //屏的场像素点
	
	parameter tft_data_cnt_max = h_pixel*v_pixel;     //tft屏一帧数据量，根据屏的大小而定
	parameter rx_data_cnt_max = tft_data_cnt_max*2;   //最大串口接收数据量，根据屏的大小而定	因为像素数据是16bit而串口接收是8bit所以要乘以二
	

	//串口数据个数计数器
	reg [19:0]data_cnt;
	always@(posedge clk50M or negedge rst_n)
	begin
		if(!rst_n)
			data_cnt <= 20'd0;		
		else if(rx_img_done)    //可读状态，串口传数据无效	 
			data_cnt <= 20'd0;
		else if(data8bit_en)           //可写状态，计数串口接收到的数据
			data_cnt <= data_cnt + 20'd1;
		else 
			data_cnt <= data_cnt;	
	end	
	
	//2个8位串口合成一个16位数据
	//step1:将接收的串口数据存储起来
	reg [7:0]r1_data8bit;
	always@(posedge clk50M or negedge rst_n)
	begin
		if(!rst_n)		
			r1_data8bit <= 8'd0;		
		else		
			r1_data8bit <= data8bit;				
	end
	
	//step2:产生数据合成标志位，即将data8bit_en延时1个周期的信号
	reg r1_data8bit_en;
	always@(posedge clk50M or negedge rst_n)
	begin
		if(!rst_n)		
			r1_data8bit_en <= 1'b0;		
		else		
			r1_data8bit_en <= data8bit_en;		
	end
	
	//step3:数据合成
	reg [15:0] data16bit;
	always@(posedge clk50M or negedge rst_n)
	begin
		if(!rst_n)	
			data16bit <= 16'd0;
		else if(r1_data8bit_en && data_cnt[0]==0)
			data16bit <= {r1_data8bit,data8bit};//{第一个字节,第二个字节}
		else
			data16bit <= data16bit;
	end
	
	//写fifo数据
	assign wr1_data = data16bit;
	
	//fifo写控制
	always@(posedge clk50M or negedge rst_n)
	begin
		if(!rst_n)	
			wr1 <= 1'b0;
		else if(r1_data8bit_en && data_cnt[0]==0)
			wr1 <= 1'b1;
		else
			wr1 <= 1'b0;
	end
			
	//一帧图片数据传输完成标志	
	always@(posedge clk50M or negedge rst_n)
	begin
		if(!rst_n)
			rx_img_done <= 1'b0;
		else if(r1_data8bit_en && data_cnt == rx_data_cnt_max)
			rx_img_done <= 1'b1;
		else
			rx_img_done <= 1'b0;	
	end
	
	//读写控制状态
	always@(posedge clk50M or negedge rst_n)
	begin
		if(!rst_n)
			ctrl_state <= 1'b1;
		else if(rx_img_done)
			ctrl_state <= 1'b0;
		else 
			ctrl_state <= ctrl_state;
	end
	
endmodule ```