裸机开发三 —— S3C2440时钟

最新推荐文章于 2024-10-15 21:14:53 发布

朱三楞

最新推荐文章于 2024-10-15 21:14:53 发布

阅读量118

点赞数

文章标签： fpga开发单片机嵌入式硬件

本文链接：https://blog.csdn.net/weixin_44894598/article/details/129893717

版权

文章详细介绍了如何通过设置S3C2440微处理器的时钟源、MPLL和分频系数，将工作频率分别配置为FCLK=400MHz，HCLK=100MHz，PCLK=50MHz。通过汇编代码展示了具体的时钟配置步骤，包括关闭看门狗、设置MPLL倍频以及调整时钟分频。

摘要由CSDN通过智能技术生成

1.Operating Frequency 工作频率

参考芯片手册1-4

Fclk Up to 400MHz
Hclk Up to 136MHz
Pclk Up to 68MHz

2.时钟体系

2.1时钟源选择

S3C2440的时钟源来源有两种：

外部晶振（OSC）
外部时钟信号（EXTCLK）

选择哪一路作为S3C2440的时钟源由模式控制引脚OM3和OM2引脚（的电平）决定

2.2MPLL改变主时钟FCLK的控制时序（上电复位时序）

3.写代码

设置芯片的时钟工作频率最高

FCLK = 400Mhz
HCLK = 100Mhz
PCLK = 50Mhz

1.设置PLL更改之后的锁定时间（默认即可）

2.设置分频系数（UCLK=UPLL（默认值）、HCLK = FCLK/4（100M）、PCLK=HCLK/2（50M））

3.HDIVN不为0，设置CPU为异步模式

注：其中#R1_nF:OR:R1_iA的值为0xc0000000。

4.设置MPLL倍频，产生FCLK=400Mhz

4.1计算公式

4.2汇编

@ brief:	S3C2440启动文件
@ author:	deng
@ note:
@			1.关闭看门狗
@			2.设置栈顶指针SP（从Nand启动）
@			3.设置时钟：FCLK=400Mhz，HCLK=100Mhz，PCLK=50Mhz
@			4.调用main函数，保存返回地址，转入C程序

.text
.global _start

_start:

    /* 关闭开门狗*/
    ldr r0, =0x53000000
    ldr r1, =0
    str r1, [r0]


    /* 设置MPLL，FCLK:HCLK:PCLK = 400M: 100M: 50M */
    /* LOCKTIME(0x4C000000) = 0xFFFFFFFF */
    ldr r0, =0x4C000000
    ldr r1, =0xFFFFFFFF
    str r1, [r0]

    /* CLKDIVN(0x4C000014) = 0X5, tFCLK:tHCLK:tPCLK = 1:4:8  */
    ldr r0, =0x4C000014
    ldr r1, =0X5
    str r1, [r0]

    /* 设置CPU工作于异步模式 */
    mrc p15,0,r0,c1,c0,0
	orr r0,r0,#0xc0000000   //R1_nF:OR:R1_iA
	mcr p15,0,r0,c1,c0,0

    /* 设置MPLLCON(0x4C000004) = (92<<12)|(1<<4)|(1<<0) 
	 *  m = MDIV+8 = 92+8=100
	 *  p = PDIV+2 = 1+2 = 3
	 *  s = SDIV = 1
	 *  FCLK = 2*m*Fin/(p*2^s) = 2*100*12/(3*2^1)=400M
	 */
    ldr r0, =0x4C000004
	ldr r1, =(92<<12)|(1<<4)|(1<<0)
	str r1, [r0]

    /* 一旦设置PLL, 就会锁定lock time直到PLL输出稳定
	 * 然后CPU工作于新的频率FCLK
	 */


    /* 设置启动方式 */
    /* 设置内存: sp 栈 */
	/* 分辨是nor/nand启动
	 * 写0到0地址, 再读出来
	 * 如果得到0, 表示0地址上的内容被修改了, 它对应ram, 这就是nand启动
	 * 否则就是nor启动
	 */
     mov r1, #0
     ldr r0, [r1] /* 读出原来的值备份 */
     str r1, [r1] /* 0->[0] */
     ldr r2, [r1] /* r2=[0] */
     cmp r1, r2  /* r1==r2? 如果相等表示是NAND启动 */
     ldr sp, =0x40000000+4096 /* 先假设是nor启动 */
     moveq sp, #4096 /* nand启动 */
     streq r0, [r1] /* 恢复原来的值 */


    bl main

halt:
    b halt

截至23 .04.1