线性规划一

LINGO 线性规划

以例1.2为例

$$\begin{gathered} \max z=2x_1+3x_2-5x_3, \\ s.t. \\ {x}_1+x_2+x_3=7, \\ 2x_1-5x_2+x_3\ge 10, \\ {x}_1+3x_2+x_3\le 12. \\ {x}_1,x_2,x_3\ge 0. \end{gathered}$$

不使用集合的方法

直接把上面的式子输进去，需要注意LINGO中不需要写变量 z，并且LINGO 中变量默认是非负的，如果要求变量的取值范围为实数，可以加上 @free(x) 。

max = 2 * x1 + 3 * x2 - 5 * x3;

    x1 +     x2 + x3  = 7;
2 * x1 - 5 * x2 + x3 >= 10;
    x1 + 3 * x2 + x3 <= 12;

使用集合的方法

要使用集合的方法，我们首先要确定LINGO模型有哪些集合。LINGO模型的集合会对应于数学模型中的矩阵或向量，因此我们首先要把上式化为标准型的矩阵形式。

$$\begin{gathered} \max z={\mathbf{c}}^T\mathbf{x} \\ s.t. \\ \mathbf{A}\mathbf{x}\le \mathbf{b} \\ {\mathbf{A}}_{eq}\mathbf{x}={\mathbf{b}}_{eq} \\ {\mathbf{b}}_l\le \mathbf{x}\le {\mathbf{b}}_u \end{gathered}$$

$$\mathbf{c}=\left[\begin{array}{c}2\\ 3\\ 5\end{array}\right],\mathbf{x}=\left[\begin{array}{c}{x}_1\\ x_2\\ x_3\end{array}\right],$$
$$\mathbf{A}=\left[\begin{array}{ccc}-2& 5& -1\\ 1& 3& 1\end{array}\right],\mathbf{b}=\left[\begin{array}{c}-10\\ 12\end{array}\right],$$
$${\mathbf{A}}_{eq}=\left[\begin{array}{ccc}1& 1& 1\end{array}\right],{\mathbf{b}}_{eq}=\left[\begin{array}{c}7\end{array}\right],$$
$${\mathbf{b}}_l=\left[\begin{array}{c}0\\ 0\\ 0\end{array}\right],{\mathbf{b}}_u=\left[\begin{array}{c}+\infty \\ +\infty \\ +\infty \end{array}\right],$$

SETS:
    col    /1..3/  : c   , x; !column number of matrix, number of variables   ;
    row    /1..2/  : b      ; !row number of A        , number of <= equations;
    row_eq /1..1/  : b_eq   ; !row number of A_eq     , number of  = equations;
    le(row   , col): A      ; !to define A   ;
    eq(row_eq, col): A_eq   ; !to define A_eq;
ENDSETS

DATA:
    c    =  2   3  -5 ;
    b    = -10  12    ;
    b_eq =  7         ;
    A    = -2   5  -1 
            1   3   1 ;
    A_eq =  1   1   1 ;
ENDDATA

MAX = @SUM(col: c * x);
@FOR(row   (i): @SUM(col(j): A   (i,j) * x(j)) <= b   (i));
@FOR(row_eq(i): @SUM(col(j): A_eq(i,j) * x(j))  = b_eq(i));

读取文件的方法

要读取文件，只需要将数据段改为

DATA:
    c    = @FILE(Ldata.txt);
    b    = @FILE(Ldata.txt);
    b_eq = @FILE(Ldata.txt);
    A    = @FILE(Ldata.txt);
    A_eq = @FILE(Ldata.txt);
ENDDATA

Ldata.txt的内容为

2 3 -5 ~
-10 12 ~
7 ~
-2 5 -1
1 3 1~
1 1 1~