halcon表面检测8——通过在频域中进行滤波来检测不均匀照明的表面中的缺陷（划痕）（find_scratches_banpass_fft）

该程序显示如何检测缺陷（划痕）
通过在频域中进行滤波来获得不均匀照明的表面。

处理步骤：
首先，创建一个合适的带通滤波器。

然后，在频域中对输入图像进行傅立叶变换和滤波，从而增强了高频信息。

最后，将其转换回空间域，并通过形态学对增强后的缺陷进行后处理。

*该程序显示如何检测缺陷（划痕）
*通过在频域中进行滤波来获得不均匀照明的表面。

*处理步骤：
*首先，创建一个合适的带通滤波器。
*然后，在频域中对输入图像进行傅立叶变换和滤波，从而增强了高频信息。
*最后，将其转换回空间域，并通过形态学对增强后的缺陷进行后处理。

dev_update_off ()
dev_close_window ()
read_image (Image, 'surface_scratch')
*反转图像
invert_image (Image, ImageInverted)
get_image_size (Image, Width, Height)
dev_open_window (0, 0, Width, Height, 'black', WindowHandle)
set_display_font (WindowHandle, 16, 'mono', 'true', 'false')
dev_display (Image)
* 
* 优化快速傅立叶变换的速度
* Message := 'Optimize the speed of the fast fourier transform.'
* Message[1] := 'Please wait...'
* disp_message (WindowHandle, Message, 'window', 12, 12, 'black', 'true')
* optimize_rft_speed (Width, Height, 'standard')
* disp_continue_message (WindowHandle, 'black', 'true')
* stop ()
* 
* 通过在频域中过滤来增强划痕
* 生成正弦形状的带通滤波器
gen_sin_bandpass (ImageBandpass, 0.4, 'none', 'rft', Width, Height)
*计算输入图像的快速傅立叶变换
rft_generic (ImageInverted, ImageFFT, 'to_freq', 'none', 'complex', Width)
 *在频域中使用滤波器对图像进行卷积
convol_fft (ImageFFT, ImageBandpass, ImageConvol)
 *计算输入图像的快速傅立叶变换
rft_generic (ImageConvol, Lines, 'from_freq', 'n', 'byte', Width)
* 
* 使用形态将划痕分割
*阈值分割
threshold (Lines, Region, 5, 255)
*连通区域提取
connection (Region, ConnectedRegions)
*筛选
select_shape (ConnectedRegions, SelectedRegions, 'area', 'and', 5, 5000)
*形态学膨胀操作
dilation_circle (SelectedRegions, RegionDilation, 5.5)
*合并区域
union1 (RegionDilation, RegionUnion)
*获得特定区域Region位置的图像
reduce_domain (Image, RegionUnion, ImageReduced)
*线条提取器（即lines_gauss算子）
lines_gauss (ImageReduced, LinesXLD, 0.8, 3, 5, 'dark', 'false', 'bar-shaped', 'false')
*合并大致共线的轮廓（在一条直线上的轮廓）
union_collinear_contours_xld (LinesXLD, UnionContours, 40, 3, 3, 0.2, 'attr_keep')
*使用形状特征选择轮廓或多边形
select_shape_xld (UnionContours, SelectedXLD, 'contlength', 'and', 15, 1000)
*从子像素XLD轮廓创建一个区域
gen_region_contour_xld (SelectedXLD, RegionXLD, 'filled')
*合并区域
union1 (RegionXLD, RegionUnion)
*圆形元素膨胀
dilation_circle (RegionUnion, RegionScratches, 10.5)
* 
* 展示结果
dev_set_draw ('margin')
dev_set_line_width (3)
dev_set_colored (12)
dev_display (Image)
dev_display (RegionScratches)