Node版本切换

Node环境安装

参考博客
下载Node时，可以直接下载二进制文件，然后再根据博客配置环境变量

Node版本切换脚本

通过更改环境变量中的NODE_HOME和NODE_GHOME_GLOBAL,从而实现Node版本的切换。以管理员方式运行

 
@echo off
chcp 65001 >nul

echo --------------------------------------------
echo 当前Node.js版本为：
node -v
echo --------------------------------------------

:: 检查NODE_HOME和NODE_HOME_GLOBAL是否已经设置
echo 当前NODE_HOME环境变量为：%NODE_HOME%
echo 当前NODE_HOME_GLOBAL环境变量为：%NODE_HOME_GLOBAL%
echo ---------------------------------------------

echo 输入需要切换的Node.js版本：
echo  version        description
echo   14           切换环境为Node.js V14.20.0
echo   16           切换环境为Node.js V16.20.2
echo   20           切换环境为Node.js V20.17.0
echo   v           查看当前NODE_HOME和NODE_HOME_GLOBAL
echo ---------------------------------------------

set /P choose=请输入选择：

:: 根据用户输入设置NODE_HOME和NODE_HOME_GLOBAL
IF "%choose%"=="14" (
    IF EXIST "C:\Program Files\NodeJs\V14.20.0" (
        setx NODE_HOME "C:\Program Files\NodeJs\V14.20.0" /M
        setx NODE_HOME_GLOBAL "D:\Program Files\NodeJs\V14.20.0" /M
        echo 环境变量已经修改为Node.js V14.20.0
    ) ELSE (
        echo Node.js V14.20.0的路径不存在，请检查后重试。
    )
) ELSE IF "%choose%"=="16" (
    IF EXIST "C:\Program Files\NodeJs\V16.20.2" (
        setx NODE_HOME "C:\Program Files\NodeJs\V16.20.2" /M
        setx NODE_HOME_GLOBAL "D:\Program Files\NodeJs\V16.20.2" /M
        echo 环境变量已经修改为Node.js V16.20.2
    ) ELSE (
        echo Node.js V16.20.2的路径不存在，请检查后重试。
    )
) ELSE IF "%choose%"=="20" (
    IF EXIST "C:\Program Files\NodeJs\V20.17.0" (
        setx NODE_HOME "C:\Program Files\NodeJs\V20.17.0" /M
        setx NODE_HOME_GLOBAL "D:\Program Files\NodeJs\V20.17.0" /M
        echo 环境变量已经修改为Node.js V20.17.0
    ) ELSE (
        echo Node.js V20.17.0的路径不存在，请检查后重试。
    )
) ELSE IF "%choose%"=="v" (
    echo 当前NODE_HOME环境变量为：%NODE_HOME%
    echo 当前NODE_HOME_GLOBAL环境变量为：%NODE_HOME_GLOBAL%
) ELSE (
    echo 输入错误！请输入有效的版本号。
)

echo 请重启命令提示符或系统以使环境变量生效。
pause