07输入输出接口

一、I/O接口概述

▶微机的外部设备多种多样
●工作原理、驱动方式、信息格式、以及工作速度方面彼此差别很大
●它们不能与CPU直接相连
●必须经过中间电路（I/O接口）再与系统相连

▶I/O接口是位于基本系统与外设间、实现两者数据交换的控制电路
●在PC机主板上的可编程接口电路
●系统总线插槽中的电路卡（Card）

1.I/O接口的典型结构

1.1 内部结构

数据寄存器
保存处理器与外设之间交换的数据
数据输入寄存器：保存从输入设备获取的数据，处理器选择合适的方式进行读取
数据输出寄存器：保存处理器发往输出设备的数据，适时到达输出设备

状态寄存器
保存接口电路和外设当前的工作状态信息

控制寄存器
保存处理器控制接口电路和外设操作的有关信息

1.2 外部特性

接口电路的外部特性由其引出信号来体现

I/O接口处于处理器与外设之间：

面向微处理器一侧的信号
与处理器总线或系统总线类似
有数据信号、地址信号和控制信号等

面向外设一侧的信号
与外设有关
外设数据信号、外设状态信号和外设控制信号

1.3 基本功能

数据缓冲：
匹配快速的处理器与相对慢速的外设的数据交换
缓冲：实现接口双方数据传输的速度匹配

信号变换：
把信号相互转换为适合对方的形式
计算机直接处理的信号：数字量（0和1组成的信号编码）；开关量（只有两种状态的信号）；脉冲量（低脉冲信号，高脉冲信号）

1.4 软件编程

接口芯片具有可编程性（Programmable）

命令字（控制字）
写入接口芯片、选择工作方式、控制数据传输

初始化程序
选择I/O接口工作方式、设置原始工作状态等

驱动程序
操纵I/O接口完成具体工作

2. I/O端口的编址

I/O端口＝I/O地址，对应I/O接口的寄存器
一个接口电路可以具有多个I/O端口，每个端口用来保存和交换不同的信息
数据寄存器、状态寄存器和控制寄存器占有的I/O地址常依次被称为数据端口、状态端口和控制端口
输入、输出端口可以是同一个I/O地址

2.1 I/O端口与存储器地址独立编址

I/O端口单独编排地址，独立于存储器地址
优点：
I/O端口的地址空间独立
控制和地址译码电路相对简单
专门的I/O指令使程序清晰易读
缺点：
I/O指令没有存储器指令丰富

2.2 I/O端口与存储器地址统一编址

将I/O端口与存储器地址统一编排
优点：
不需要专门的I/O指令
I/O数据存取灵活
缺点：
占去部分存储器空间
程序不易阅读

2.3 I/O地址译码

与存储器地址译码在原理和方法上完全相同
I/O地址不太强调连续，多采用部分译码

3.输入输出指令

输入指令IN：数据从I/O接口输入到微处理器

IN AL/AX/EAX,i8/DX

输出指令OUT：数据从微处理器输出I/O接口

OUT i8/DX,AL/AX/EAX

串输入INS指令
串输出OUTS指令

3.1 I/O寻址方式

直接寻址
I/O指令直接提供8位I/O地址
只能寻址最低256个I/O地址（00～FFH）
用i8表示I/O地址，表达形式上与立即数一样

DX间接寻址
用DX寄存器保存访问的I/O地址
可寻址全部I/O地址（0000～FFFFH）
直接书写成DX，表示I/O地址

3.2 I/O数据传输量

8位I/O传输：I/O指令使用AL
16位I/O传输：I/O指令使用AX
32位I/O传输：I/O指令使用EAX

4. 16位DOS应用程序

16位DOS操作系统运行于
Intel 8086和8088处理器
IA-32处理器的实地址工作方式

DOS平台下使用实地址存储模型
只能访问1MB存储空间，分成不大于64KB的段
默认采用16位操作数尺寸：
使用16位或8位寄存器、操作数和寻址方式
堆栈以16位为单位压入PUSH和弹出POP数据

IA-32处理器的实地址工作方式
还允许使用32位寄存器、操作数和寻址方式
执行大多数新增的32位通用指令

4.1 DOS平台的源程序框架

; eg0700.asm in DOS
	include io16.inc
	; 包含16位输入输出文件
	.data	; 定义数据段
	……	; 数据定义（数据待填）
	.code	; 定义代码段
start:		; 程序执行起始位置
	mov ax,@data
	mov ds,ax
	……	; 主程序（指令待填）
	exit 0	; 程序正常执行结束
	……	; 子程序（指令待填）
	end start	; 汇编结束

4.2 DOS功能调用

DOS操作系统的系统函数（功能）以中断服务程序形式提供，采用软件中断进行功能调用，使用寄存器传递参数
基本输入输出系统ROM-BIOS、操作系统DOS和Linux都采用中断调用方式提供系统功能

DOS系统调用一般有如下4个步骤：
（1）在AH寄存器中设置系统功能调用号
（2）在指定寄存器中设置入口参数
（3）用中断调用指令（INT N）执行功能调用
（4）根据出口参数分析功能调用执行情况

CMOS RAM是使用CMOS技术的存储器芯片
PC机用以保存配置信息以及实时时钟
断点后由后备电池供电，避免信息丢失

具有64个字节存储容量
通过两个I/O地址访问

二、无条件传送和程序查询传送

通过处理器执行I/O指令完成
无条件传送
查询传送
中断传送
以硬件为主，加快传输速度
直接存储器存取（DMA）
使用专门的I/O处理机

1.无条件传送

处理器与慢速变化的设备交换数据
外设总是处于“就绪”状态，随时可以进行数据传送
无条件传送的接口电路：只考虑数据缓冲
无条件传送的软件编程：十分简单

1.1 三态缓冲器

三态缓冲器:加有控制端的同相器或反相器
控制端T有效时，控制输入A端输出到Y端
控制端T无效时，输出Y端呈现高阻状态

74LS244：双4位三态同相缓冲器

双向三态缓冲器：两个三态缓冲器构成
输出允许控制端OE*：控制数据的输出
方向控制端DIR：控制数据驱动的方向

74LS245 ：8位双向三态缓冲器芯片

1.2 锁存器

使用D触发器构成
输入端为D端，控制端为C端
两个相反的输出信号Q和Q*
复位R或置位S控制端

电平锁存：电平控制输出能跟随输入变化
边沿锁存：输出只能锁存输入的状态

74LS273：上升沿锁存的8位边沿锁存器
74LS373：电平锁存的8位三态缓冲锁存器
74LS374：边沿锁存的8位三态缓冲锁存器

2.程序查询传送

处理器启动外设工作，需要进行数据交换时 先了解（查询）外设的工作状态 ；在外设可以交换信息时（就绪、准备好）；实现数据输入或输出

处理器判断是否全部完成 如果没有，重复上述过程 继续进行数据交换

查询传送的特点 工作可靠，适用性较广 查询需大量时间，效率较低

程序控制的查询传送有查询和传送两个环节
首先查询外设工作状态
检测、等待外设准备就绪
进行数据传输

2.1查询过程

设计实现查询功能的电路
连接外设的状态输入信号
保存在状态寄存器中
通过状态端口读取

外设的工作状态在状态寄存器中
使用一位或若干位表达
查询通过输入指令来实现

有多个状态，按照一定原则轮流查询
先检测到就绪的外设先开始数据传送

2.2查询输入接口

读取状态端口查询外设状态，若已就绪，读取数据端口得到外设提供的数据

	mov dx,5001h	;DX指向状态端口
status:	in al,dx	;读状态端口
		test al,01h	;测试状态位D0
		jz status
	;D0＝0，未就绪，继续查询
		dec dx
	;D0＝1，就绪，DX改指数据端口
		in al,dx	;从数据端口输入数据

2.3查询输出接口

读取状态端口查询外设状态，若已就绪，将数据写入数据端口输出给外设

		mov dx,5001h	;DX指向状态口
status:	in al,dx	;读取状态口的状态数据
		test al,80h	;测试标志位D7
		jnz status
	;D7＝1，未就绪，继续查询
		dec dx
	;D7＝0，就绪，DX改指数据口
		mov al,buf	;将变量BUF送AL
		out dx,al	;将AL中的数据送数据口

三、中断控制系统

中断是微机系统中非常重要的一种技术
利用外部中断：
微机系统可以实时响应外部设备的数据传送请求、能够及时处理外部意外或紧急事件
利用内部中断：
处理器为用户提供了发现、调试并解决程序执行时异常情况的有效途径

1.中断传送

处理器在执行程序过程中，被内部或外部的事件所打断，转去执行一段预先安排好的中断服务程序；服务结束后，又返回原来的断点，继续执行原来的程序。

中断源
引起中断的事件或原因
内部中断
外部中断
可屏蔽中断
非屏蔽中断

1.1中断工作过程

中断请求
中断响应
    关中断
    断点保护
    中断源识别
        现场保护
中断服务----------------->数据交换的实质性环节
        恢复现场
    开中断
中断返回

中断响应条件
每条指令执行完时
允许中断(可屏蔽中断)
没有更高级的请求发生
……

中断传送工作流程

1.2 中断源的识别

向量中断
在中断响应周期，处理器获得中断向量号
一个中断向量号对应一个中断
自动转向相应的中断服务程序

中断查询
中断请求保存在中断状态寄存器
处理器依次查询中断状态寄存器
某个中断请求状态有效说明其提出请求
转向对应的中断服务程序

1.3 中断优先权排队

中断优先权
每个中断源被处理的级别

中断优先权排队
事先为每个中断源所确定的优先处理顺序

查询中断时
依次查询，先查询的中断具有较高的优先权

硬件电路实现时
分布方式的菊花链排队电路
集中方式的编码电路和比较电路

1.4 中断嵌套

中断嵌套：中断处理中又响应中断

高于当前正在服务的中断：
暂停当前工作
先行服务于级别更高的中断
接着处理被打断的中断

低于或等于当前正在服务的中断：
不予理会，待完成当前中断服务后再处理

2.IA-32中断

采用向量中断机制
能够处理256个中断
用中断向量号0～255区别
可屏蔽中断需要中断控制器实现优先权管理

2.1内部中断

内部中断是由于处理器内部执行程序出现异常引起的程序中断（异常 Exception） ，如：
除法错异常（向量号0）
调试异常（向量号1）
断点异常（向量号3）
溢出异常（向量号4）
无效代码异常（向量号6）
通用保护异常（向量号13）
页面失效异常（向量号14）

• 除法错异常
  执行除法指令时，若除数为0或商超过了寄存器所能表达的范围，产生的一个向量号为0的内部中断

〔例7-3〕产生除法错中断的程序
		; 数据段
msg	byte 0dh,0ah, 'No divide overflow !',0
		; 代码段
		call readuiw
		mov bl,1
		div bl
		mov eax,offset msg ; 没有除法错，显示信息
		call dispmsg

• 溢出异常

〔例7-4〕产生溢出中断的程序
		; 数据段
msg	byte 0dh,0ah,'No overflow !',0
		; 代码段
		call readuib
		add al,100
		jno noflow	; 没有溢出，转移
		into	; 有溢出，产生溢出中断
		jmp done
noflow:	mov eax,offset msg	; 显示无溢出信息
		call dispmsg
done:

2.2外部中断

非屏蔽中断
外部通过非屏蔽中断NMI请求信号提出的中断
处理器在当前指令执行结束予以响应
非屏蔽中断的中断向量号是2
非屏蔽中断主要用于处理系统的意外或故障

可屏蔽中断
外部通过可屏蔽中断INTR请求信号提出的中断
允许可屏蔽中断的条件下、当前指令执行结束予以响应 输出可屏蔽中断响应信号INTA*，产生可屏蔽中断响应总线周期，读取中断向量号
需要中断控制器负责处理中断优先权排队等管理工作
可屏蔽中断主要用于与外设进行数据交换

中断标志

IF＝1，处理器开中断
可以响应，允许中断，中断开放
IF＝0，处理器关中断
不能响应，禁止中断，中断被屏蔽
关中断的情况：
系统复位后
任何一个中断被响应后
执行关中断指令CLI后
开中断的方法：
执行开中断指令STI
执行中断返回指令IRET恢复中断前IF状态

2.3中断和异常的响应过程

①标志寄存器压入堆栈，保护标志位；被中断指令的逻辑地址压入堆栈，保护断点
②如果有错误代码，将其压入堆栈 ；实地址方式的异常不返回错误代码
③根据向量号获得中断服务程序（中断或异常的处理程序）的段选择器和指令指针
④对于中断，设置IF为0，禁止可屏蔽中断
⑤控制转移至中断服务程序入口地址，开始执行中断或异常处理程序

2.4中断描述符表和中断向量表

3.内部中断服务程序

〔例7-5〕内部中断服务程序－1
; 数据段
intoff	word ?
	; 用于保存原中断服务程序的偏移地址
intseg	word ?
 	; 用于保存原中断服务程序的段基地址
intmsg	byte 'A Instruction Interrupt !',0dh,0ah,0	; 字符串（以0结尾）
	;代码段
	mov ax,3580h
	; 获取系统的原80H中断向量表项
	int 21h
	mov intoff,bx	; 保存偏移地址
	mov intseg,es	; 保存段基地址
	push ds
	mov dx,offset new80h
	mov ax,seg new80h
	mov ds,ax
	mov ax,2580h	; 设置本程序80H中断向量表项
	int 21h
	pop ds
	mov dx,offset intmsg
	int 80h	; 调用80H中断服务程序
	mov dx,intoff	; 恢复原80H中断向量表项
	mov ax,intseg	; 注意先设置DX、后设置DS
	mov ds,ax
	mov ax,2580h
	int 21h
	new80h	proc	; 过程定义
	sti	; 开中断
	push ax	; 保护寄存器
	push bx
	push si
	mov si,dx
new1:	mov al,[si]	; 获取欲显示字符
	cmp al,0	; 为“0”结束
	jz new2
	mov bx,0	; ROM-BIOS调用显示一个字符
	mov ah,0eh
	int 10h
	inc si
	jmp new1
	new2:	pop si	; 恢复寄存器
	pop bx
	pop ax
	iret	; 中断返回
new80h	endp	; 中断服务程序结束
	; 80H内部中断服务程序
	; 显示字符串（以0结尾）
	; DS∶DX＝缓冲区首地址

4.中断控制器

4.1 8259A的寄存器

4.2 8259A的工作方式

4.3 8259A的编程

4.4 8259A的应用

5.可屏蔽中断服务程序

〔例7-6〕可屏蔽中断服务程序
; 数据段
intmsg	byte  'A 8259A Interrupt !',0dh,0ah,0
counter	byte 0	; 中断次数记录单元
	; 代码段
	mov ax,3508h	; 获取原中断向量表项
	int 21h
	push es	; 利用堆栈保存
	push bx
	cli	; 关中断
	push ds	; 设置新中断向量表项
	mov ax,seg new08h
	mov ds,ax
	mov dx,offset new08h
	mov ax,2508h
	int 21h
	pop ds
	in al,21h	; 读出IMR
	push ax	; 保存原IMR内容
	and al,0feh	; 允许IRQ0，其他不变
	out 21h,al	; 设置新IMR内容	
	mov counter,0	; 设置中断次数初值
	sti	; 开中断
start1:	cmp counter,10	; 主程序仅循环等待中断
	jb start1	; 中断10次退出
	cli	; 关中断
	pop ax	; 恢复IMR
	out 21h,al
	pop dx	; 恢复原中断向量表项
	pop ds
	mov ax,2508h
	int 21h
	sti	; 开中断
	new08h	proc 
	sti	; 开中断
	push ax	; 保护寄存器
	push si
	push ds
	mov ax,@data	; 设置DS
	mov ds,ax
	inc counter	; 中断次数加1
	mov si,offset intmsg	; 显示信息
	call dpstri
	mov al,20h	; 发送EOI命令
	out 20h,al
	pop ds	; 恢复寄存器
	pop si
	pop ax
	iret	; 中断返回
new08h	endp
dpstri	proc	; 显示字符串子程序
	push ax	; 入口参数：DS:SI＝字符串首址
	push bx
dps1:	mov al,[si]
	cmp al,0
	jz dps2
	mov bx,0	; 调用ROM-BIOS功能显示AL中字符
	mov ah,0eh
	int 10h
	inc si
	jmp dps1
dps2:	pop bx
	pop ax
	ret
dpstri	endp

6.驻留中断服务程序

没有驻留的程序执行结束后，使用的主存空间被DOS回收用于其他程序
驻留TSR程序：程序执行结束保存在主存
中断服务程序要让其他程序使用必须驻留
用DOS功能调用的31H号实现程序驻留并返回

〔例7-7〕驻留中断服务程序
include io16.inc
	.code
new04h	proc	; 中断服务程序
	sti
	push ax	; 保存寄存器
	push bx
	push si
	push ds
	mov ax,cs	; 数据在代码段中，故DS＝CS
	mov ds,ax
	mov si,offset intmsg
dps1:	mov al,[si]
	cmp al,0
	jz dps2
	mov bx,0	; 调用ROM-BIOS功能显示AL中字符
	mov ah,0eh
	int 10h
	inc si
	jmp dps1
dps2:	pop ds	; 恢复寄存器
	pop si
	pop bx
	pop ax
	iret	; 中断返回
intmsg  byte 0dh,0ah,'Overflow !',0	; 溢出显示的信息
new04h	endp	; 中断服务程序结束
start:	mov ax,cs
	mov ds,ax	; 设置04H中断向量	
	mov dx,offset new04h
	cli
	mov ax,2504h
	int 21h
	sti
	mov ax,offset tsrmsg	; 显示安装信息
	call dispmsg
	mov dx,offset start	; 计算驻留程序的长度
	add dx,256	; 增加256个字节
	add dx,15
	shr dx,4	; 调整为“节”（16个字节）
	mov ax,3100h	; 程序驻留，返回DOS	
	int 21h
tsrmsg	byte 'INT 04H Program Installed !',0dh,0ah,0
	end start

四、DMA传送

希望克服程序控制传送的不足：
外设→CPU→存储器
外设←CPU←存储器

直接存储器存取DMA：
外设→存储器
外设←存储器

CPU释放总线，由DMA控制器管理

DMA传送过程

DMA控制器