******************************
*创建空数组用来存放模板的中心
ImageXPix:=[]
ImageYPix:=[]
dev_get_window (WindowHandle)
*****************************
*确定好相机移动的九个物理坐标数组
WorldX:=[5,5,5,0,0,0,-5,-5,-5]
WorldY:=[-5,0,5,-5,0,5,-5,0,5]
*开始标定
i:=0
**********8
open_framegrabber ('GigEVision2',0, 0, 0, 0, 0, 0, 'progressive', -1, 'default', -1, 'false', 'default', 'ccd1', 0, -1, AcqHandle)
grab_image_start (AcqHandle, -1)
while (true)
grab_image (Image, AcqHandle)
*******************
*画模板区域
if(i=0)
draw_region (Region,WindowHandle)
reduce_domain (Image, Region, ImageReduced)
create_shape_model (ImageReduced, 'auto', -0.39, 0.79, 'auto', 'auto', 'use_polarity', 'auto', 'auto', ModelID)
i:=i+1
endif
*******************
*匹配模板，得到模板中心·
find_shape_model (Image, ModelID, -0.39, 0.78, 0.5, 1, 0.5, 'least_squares', 0, 0.9, Row, Column, Angle, Score)
if(Score>0)
dev_display_shape_matching_results (ModelID, 'red', Row, Column, Angle, 1, 1, 0)
*模板中心的坐标集合
ImageXPix:=[ImageXPix,Column]
ImageYPix:=[ImageYPix,Row]
endif
stop()
endwhile
*************
*相机走完九个物理坐标后，手动跳出while循环
close_framegrabber (AcqHandle)
**********************
*根据三个以上点对计算反射变换矩阵
vector_to_hom_mat2d (ImageYPix, ImageXPix, WorldY, WorldX, HomMat2D)
******************
*保存和读取标定好的仿射矩阵
write_tuple (HomMat2D, 'E:/A视觉/333.tup')
read_tuple ('E:/A视觉/333.tup', HomMat2D)
dev_get_window (WindowHandle)
************************
*打开串口，与运动程序通讯
open_serial ('COM5', SerialHandle)
set_serial_param (SerialHandle, 9600, 8, 'none', 'none', 1, 1000, 'unchanged')
*******************
*利用标定好的矩阵进行实际的操作。
i:=0
open_framegrabber ('GigEVision2',0, 0, 0, 0, 0, 0, 'progressive', -1, 'default', -1, 'false', 'default', 'ccd1', 0, -1, AcqHandle)
grab_image_start (AcqHandle, -1)
while (true)
grab_image (Image, AcqHandle)
if(i=0)
draw_region (Region,WindowHandle)
reduce_domain (Image, Region, ImageReduced)
get_image_size (Image, Width, Height)
create_shape_model (ImageReduced, 'auto', -0.39, 0.79, 'auto', 'auto', 'use_polarity', 'auto', 'auto', ModelID)
i:=i+1
endif
* Do something
find_shape_model (Image, ModelID, -0.39, 0.78, 0.5, 1, 0.5, 'least_squares', 0, 0.9, Row, Column, Angle, Score)
if(Score>0)
dev_display_shape_matching_results (ModelID, 'red', Row, Column, Angle, 1, 1, 0)
*将图像中心的像素坐标仿射得到物理坐标Qy1, Qx1
affine_trans_point_2d (HomMat2D, Height/2-1, Width/2-1, Qy1, Qx1)
*将找到的模板中心的像素坐标仿射得到物理坐标Qy2, Qx2
affine_trans_point_2d (HomMat2D, Row, Column, Qy2, Qx2)
*求出相机中心和模板中心之间的物理距离差
*string_send:='go2:'+5+','+5+',0'
string_send:='go2:'+(Qx1-Qx2)+','+(Qy1-Qy2)+',0'
*将这个物理距离差通过串口发送给运动控制程序，让相机中心移动到模板的中心位置
write_serial (SerialHandle, ords(string_send))
*write_serial (SerialHandle, string_send)
try
while(1)
*获得鼠标的能力 1表示鼠标左键 4表示鼠标右键
get_mbutton (WindowHandle, Row3, Column3, Button)
if(Button=1)
grab_image (Image, AcqHandle)
find_shape_model (Image, ModelID, -0.39, 0.78, 0.5, 1, 0.5, 'least_squares', 0, 0.9, Row, Column, Angle, Score)
if(Score>0)
dev_display (Image)
dev_set_color ('green')
gen_cross_contour_xld (Cross1,Height/2-1, Width/2-1, 60, 0)
dev_set_color ('red')
gen_cross_contour_xld (Cross, Row, Column, 15,rad(45))
*验证相机中心和模板中心是否基本重合
affine_trans_point_2d (HomMat2D, Row, Column, Qy2, Qx2)
string_send:='go2:'+(Qx1-Qx2)+','+(Qy1-Qy2)+',0'
*将这个物理距离差通过串口发送给运动控制程序，让相机中心移动到模板的中心位置
write_serial (SerialHandle, ords(string_send))
disp_message (WindowHandle, string_send, 'window', 12, 12, 'black', 'true')
endif
endif
if(Button=4)
break
endif
endwhile
catch (Exception)
endtry
endif
endwhile
close_framegrabber (AcqHandle)
下面是几种仿射变换算子的区别分析
1. 仿射变换类型
仿射变换有：平移、旋转、缩放、斜切（就是将斜体字导正）。
2. 求稳定的特征点
要进行仿射变换，必须先获取变换矩阵。要获取变换矩阵，必须先获取特征点坐标、角度等信息，几何匹配和bolb是获取特征点的高效方法，除此之外还有其它方法，只要能稳定的求出特征点即可。
3.仿射变换流程
（1.）获取特征点坐标、角度
（2.）计算仿射变换矩阵
（3.）对图像、区域、轮廓进行仿射变换
4. 根据特征点、角度计算仿射变换矩阵
一、 创建仿射变换矩阵
hom_mat2d_identity( : : : HomMat2DIdentity)
功能：产生仿射变换矩阵（产生一个空的二维空变换矩阵）
二、生产“旋转、缩放、平移、斜切”变换矩阵
hom_mat2d_rotate( : : HomMat2D, Phi, Px, Py : HomMat2DRotate)
//功能：把旋转角度添加到仿射变换矩阵
HomMat2D :（输入参数）仿射变换矩阵
Phi ：旋转角度（单位弧度）
Px ：变换的固定点行坐标。固定点是指以该点为支撑进行仿射变换 （这里是指围绕这点进行旋转）
Py ： 变换的固定点列坐标
HomMat2DRotate：输出的旋转变换的二维矩阵
hom_mat2d_scale( : : HomMat2D, Sx, Sy, Px, Py : HomMat2DScale)
//把缩放添加到仿射变换矩阵
HomMat2D（输入参数）：仿射变换矩阵
Sx（输入参数）：x轴方向的缩放因子
Sy（输入参数）：y轴方向的缩放因子
Px（输入参数）：变换的固定点行坐标
Py（输入参数）: 变换的固定点列坐标
HomMat2DScale（输出参数）：输出缩放变换矩阵
hom_mat2d_translate( : : HomMat2D, Tx, Ty : HomMat2DTranslate)
功能：把平移添加到防射变换矩阵
HomMat2D：（输入参数）仿射变换矩阵
Tx（输入参数）：沿x轴方向平移的距离
Ty:输入参数）：沿y轴方向平移的距离
HomMat2DTranslate(输出参数)：输出变换矩阵
hom_mat2d_slant( : : HomMat2D, Theta, Axis, Px, Py : HomMat2DSlant)
功能：把斜切添加到防射变换矩阵
HomMat2D （输入参数):仿射变换矩阵
Theta （输入参数):斜切角度（单位：弧度）
Axis （输入参数):斜切的坐标轴。取值列表：x,y
Px （输入参数):变换的固定点x坐标
Py （输入参数):变换的固定点y坐标
HomMat2DSlant （输出参数):输出斜切仿射变换矩阵
三、（如果有需求的时候）计算仿射变换参数
hom_mat2d_to_affine_par( : : HomMat2D : Sx, Sy, Phi, Theta, Tx, Ty)
功能：根据仿射变换矩阵（齐次二维变换矩阵）计算仿射变换参数
HomMat2D (输入参数):仿射变换矩阵
Sx (输出参数):x方向的缩放因子（如果从图像空间变换到物理空间，就是x方向的像素单量）
Sy (输出参数):y方向的缩放因子（如果从图像空间变换到物理空间，就是y方向的像素单量）
Phi (输出参数):旋转角度
Theta (输出参数):斜切角度
Tx (输出参数):沿x方向平移的距离
Ty (输出参数):沿y方向平移的距离
四、对图像、region和XLD进行仿射变换
affine_trans_contour_xld(Contours : ContoursAffinTrans : HomMat2D : )
功能：对XLD轮廓进行二维仿射变换 (支持缩放，旋转，平移，斜切)
Contours(输入参数):输入XLD轮廓
ContoursAffinTrans(输出参数):输出变换的XLD轮廓
HomMat2D(输入参数)：仿射变换矩阵
affine_trans_image(Image : ImageAffinTrans : HomMat2D, Interpolation, AdaptImageSize : )
功能：对图像轮廓进行二维仿射变换 (支持缩放、旋转、平移，斜切)
Image (输入参数):输入图像
ImageAffinTrans (输出参数):变换后的图像
HomMat2D (输入参数)：仿射变换矩阵
Interpolation (输入参数)：插值算法。参数值列表 nearest_neighbor,bilinear,constant,weighted
AdaptImageSize (输入参数)：结果图像尺寸是否自适应。默认值：false
affine_trans_region(Region : RegionAffineTrans : HomMat2D, Interpolate : )
功能：对区域进行任意二维仿射变换
Region (输入参数):输入区域
RegionAffineTrans (输出参数):变换的区域
HomMat2D (输入参数)：仿射变换矩阵
Interpolate (输入参数):插值算法。默认值：nearest_neighbor。参数值列表：constant，nearest_neighbor
affine_trans_polygon_xld(Polygon:PolygonsAffinTrans:HomMat2D:)
功能：对XLD多边形进行任意二维仿射变换
Polygon(输入参数):输入XLD多边形
PolygonsAffinTrans(输出参数):变换的XLD多边形
HomMat2D(输入参数):仿射变换矩阵
affine_trans_point_2d(::HomMat2D,Px,Py:Qx,Qy)
功能：对点进行任意二维仿射变换，（支持缩放、旋转、平移、斜切）
HomMat2D(输入参数):仿射变换矩阵
Px(输入参数):原始点x或行坐标
Py(输入参数):原始点y或列坐标
Qx(输出参数):变换点x或行坐标
Qy(输出参数):变换点y或列坐标
affine_trans_pixel(::HomMat2D,Row,Col:RowTrans,ColTrans)
功能：对像素进行任意二维仿射变换
HomMat2D(输入参数):仿射变换矩阵
Row(输入参数):输入像素行坐标
Col(输入参数):输入像素列坐标
RowTrans(输出参数):变换的像素行坐标
ColTrans(输出参数):变换的像素列坐标
注：affine_trans_point_2d与affine_trans_pixel的区别：affine_trans_pixel使用的图像坐标系的原点在图像的左上角，affine_trans_point_2d使用标准图像坐标系，原点在左上角像素的中心
vector_angle_to_rigid(::Row1,Column1,Angle1,Row2,Column2,Angle2:HomMat2D)
功能：根据点和角度计算刚性仿射变换矩阵，支持旋转和平移
Row1(输入参数):原始点行坐标
Column1(输入参数):原始点列坐标
Angle1(输入参数):原始点角度
Row2(输入参数):变换的目的点行坐标
Column2(输入参数):变换的目的点列坐标
Angle2(输入参数):变换的目的点角度
HomMat2D(输出参数):输出仿射变换矩阵
五.根据两个以上特征点计算仿射变换矩阵
vector_to_rigid(::Px,Py,Qx,Qy：HomMat2D)
功能：根据两个以上点对计算计算刚性仿射变换矩阵，支持旋转和平移
Px:(输入参数)原始点组的x坐标
Py:(输入参数)原始点组的y坐标
Qx:(输入参数)变换的目的点组的x坐标
Qy:输入参数)变换的目的点组的y坐标
HomMat2D:(输出参数)输出仿射变换矩阵
vector_to_similarity(::Px,Py,Qx,Qy：HomMat2D)
功能：根据两个以上点对计算相似仿射变换矩阵，支持旋转、平移和缩放
Px:(输入参数)原始点组的x坐标
Py:(输入参数)原始点组的y坐标
Qx:(输入参数)变换的目的点组的x坐标
Qy:(输入参数)变换的目的点组的y坐标
HomMat2D:(输出参数)输出仿射变换矩阵
六.根据三个以上特征点获取仿射变换矩阵
vector_to_hom_mat2d(::Px,Py,Qx,Qy：HomMat2D)
功能：根据三个以上点对计算仿射变换矩阵，支持旋转、平移、缩放、斜切
Px:(输入参数)原始点组的x坐标
Py:(输入参数)原始点组的y坐标
Qx:(输入参数)变换的目的点组的x坐标
Qy:(输入参数)变换的目的点组的y坐标
HomMat2D:(输出参数)输出仿射变换矩阵
6690
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
