测量金属零件的尺寸

对应示例程序：
measure_metal_part.hdev

目标：测量金属零件的尺寸，包括线和开孔大小

思路为：
      1.读取图像
      2.亚像素边缘检测，获取零件的边缘轮廓。
      3.利用算子segment_contours_xld，将轮廓分为直线和圆弧。
      4.利用算子get_contour_global_attrib_xld ，对每个轮廓进行处理，直线就拟合直线，圆弧就拟合圆。
      5.显示处理结果。

图像：

代码：

* measure_metal_part.hdev: inspects metal part by fitting lines and circles
* 
*
dev_close_window ()
dev_update_window ('off')
* ****
* step: acquire image
* **** 读图  配置窗口 显示字体等前期准备
read_image (Image, 'metal-parts/metal-parts-01')
get_image_size (Image, Width, Height)
dev_open_window_fit_image (Image, 0, 0, Width, Width, WindowID)
set_display_font (WindowID, 14, 'mono', 'true', 'false')
dev_set_draw ('margin')
dev_set_line_width (3)
dev_display (Image)
disp_continue_message (WindowID, 'black', 'true')
stop ()
* ****
* step: create contours
* ****亚像素边缘检测
edges_sub_pix (Image, Edges, 'lanser2', 0.5, 40, 90)
dev_display (Edges)
disp_continue_message (WindowID, 'black', 'true')
stop ()
* ****
* step: process contours
* ****
segment_contours_xld (Edges, ContoursSplit, 'lines_circles', 6, 4, 4)  //根据直线和圆弧 分离轮廓
sort_contours_xld (ContoursSplit, SortedContours, 'upper_left', 'true', 'column') //对分离出的轮廓进行排序
dev_clear_window ()
dev_set_colored (12)
dev_display (SortedContours)
disp_continue_message (WindowID, 'black', 'true')
stop ()
* ****
* step: perform fitting
* ****重新开辟个窗口 对图像进行放大显示
ROI := [115,225,395,535]
dev_open_window (0, round(Width / 2), (ROI[3] - ROI[1]) * 2, (ROI[2] - ROI[0]) * 2, 'black', WindowHandleZoom)
dev_set_part (round(ROI[0]), round(ROI[1]), round(ROI[2]), round(ROI[3]))
set_display_font (WindowHandleZoom, 14, 'mono', 'true', 'false')
count_obj (SortedContours, NumSegments)   //统计轮廓的数目
dev_display (Image)
NumCircles := 0
NumLines := 0
for i := 1 to NumSegments by 1
    select_obj (SortedContours, SingleSegment, i)
    get_contour_global_attrib_xld (SingleSegment, 'cont_approx', Attrib)  //根据返回的值 判断这个轮廓是直线还是圆弧
    
    
    if (Attrib == 1)  //返回值为1，则是圆  对圆轮廓进行拟合 并显示
        NumCircles := NumCircles + 1
        fit_circle_contour_xld (SingleSegment, 'atukey', -1, 2, 0, 5, 2, Row, Column, Radius, StartPhi, EndPhi, PointOrder)
        gen_ellipse_contour_xld (ContEllipse, Row, Column, 0, Radius, Radius, 0, rad(360), 'positive', 1.0)
        dev_set_color ('white')
        dev_display (ContEllipse)
        set_tposition (WindowHandleZoom, Row - Radius - 10, Column)
        write_string (WindowHandleZoom, 'C' + NumCircles)
        ResultText := 'C' + NumCircles + ': radius = ' + Radius
    else   //处理是直线的情况  直线拟合和显示
        NumLines := NumLines + 1
        fit_line_contour_xld (SingleSegment, 'tukey', -1, 0, 5, 2, RowBegin, ColBegin, RowEnd, ColEnd, Nr, Nc, Dist)
        gen_contour_polygon_xld (Line, [RowBegin,RowEnd], [ColBegin,ColEnd])
        dev_set_color ('yellow')
        dev_display (Line)
        distance_pp (RowBegin, ColBegin, RowEnd, ColEnd, Length)
        set_tposition (WindowHandleZoom, (RowBegin + RowEnd) / 2 - Nr * 10, (ColBegin + ColEnd) / 2)
        write_string (WindowHandleZoom, 'L' + NumLines)
        ResultText := 'L' + NumLines + ': length = ' + Length
    endif
    set_tposition (WindowHandleZoom, 275 + i * 10, 230)  //逐条显示测量结果
    write_string (WindowHandleZoom, ResultText)
endfor
disp_continue_message (WindowID, 'black', 'true')
stop ()
dev_set_window (WindowHandleZoom)
dev_close_window ()
dev_clear_window ()

用到的几个算子：
    segment_contours_xld-- 将亚像素轮廓分割为直线段、圆、或圆弧(三种方式：直线，直线和圆，直线和弧，根据实际图像进行选择)
    get_contour_global_attrib_xld -返回XLD轮廓的全局属性值 判断轮廓是否适合被划分为圆 返回值:-1 适合直线 0适合圆弧 1 适合圆