ABAP bgRFC 实例

已于 2022-08-11 23:22:34 修改
阅读量559 收藏 4
点赞数 1
分类专栏： 接口 ABAP 文章标签： abap
于 2022-08-11 23:21:46 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/xiefireworks/article/details/126294866
版权
ABAP 同时被 2 个专栏收录
61 篇文章 12 订阅
订阅专栏
接口
9 篇文章 2 订阅
订阅专栏

目录

目的地设置

出站事务bgRFC代码示例

出站队列bgRFC代码示例

入站和出站队列bgRFC代码示例

入站事务bgRFC代码示例

出站队列bgRFC队列单元交叉场景示例

开发API

bgRFC监控管理

注意事项

目的地设置

        不能使用'NONE',可以使用目标地址为空代替本地

        必须为ABAP连接，TCP/IP连接，参考条目

        出站队列的目的地必须在事务 SM59中维护，并表示出站 bgRFC 类型 t 和类型 q 的执行目的地。入站队列的目的地必须在事务 SBGRFCMAINIDST 中维护。如果目的地无效，则抛出异常 CX_BGRFC_INVALID_DESTINATION。

出站事务bgRFC代码示例

DATA: my_destination TYPE REF TO if_bgrfc_destination_outbound,
      my_unit        TYPE REF TO if_trfc_unit_outbound,
      dest_name      TYPE bgrfc_dest_name_outbound.

DATA: text TYPE text200.

TRY.
    dest_name = 'LOCALTEST'.
    my_destination = cl_bgrfc_destination_outbound=>create( dest_name ).
    my_unit = my_destination->create_trfc_unit( ).

    text = 'Simple Outbound'.

    CALL FUNCTION 'YLC_FUNC001' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.

    CALL FUNCTION 'YLC_FUNC002' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.

    CALL FUNCTION 'YLC_FUNC003' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.

    CALL FUNCTION 'YLC_FUNC004' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.

    CALL FUNCTION 'YLC_FUNC005' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.

    COMMIT WORK.
    WRITE:/ 'Success'.
  CATCH cx_bgrfc_invalid_destination .
    WRITE:/ 'Error'.
ENDTRY.

以一个LUW进行提交,RFC中不能使用COMMIT WORK，ROLLBACK WORK

使用错误消息可以触发数据回滚

RFC中更新自建，效果如下

出站队列bgRFC代码示例

        队列bgRFC队列名称只能字母数字和_/ （ [A-Z/][A-Z0-9_/]* ）

        单元是传输的单位。它要么完全传输，要么等待传输

DATA: my_destination TYPE REF TO if_bgrfc_destination_outbound,
      my_unit        TYPE REF TO if_qrfc_unit_outbound,
      dest_name      TYPE bgrfc_dest_name_outbound,
      queue_name     TYPE qrfc_queue_name,
      queue_names    TYPE qrfc_queue_name_tab.

DATA: text TYPE text200.

TRY.
    dest_name = 'LOCALTEST'.
    my_destination = cl_bgrfc_destination_outbound=>create( dest_name ).
    my_unit = my_destination->create_qrfc_unit( ).

    text = 'Simple Outbound - bgRFC type Q'.

    CALL FUNCTION 'YLC_FUNC001' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.

    CALL FUNCTION 'YLC_FUNC002' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.


    CALL FUNCTION 'YLC_FUNC003' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.

    CALL FUNCTION 'YLC_FUNC004' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.

    CALL FUNCTION 'YLC_FUNC005' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.

    my_unit->add_queue_name_outbound( 'TEST_FUN1' ).

    queue_name = 'TEST_FUN2'.
    INSERT queue_name INTO TABLE queue_names.
    my_unit->add_queue_names_outbound( queue_names ).

    COMMIT WORK.
    WRITE:/ 'Success'.

  CATCH cx_bgrfc_invalid_destination .
    WRITE:/ 'Error'.
  CATCH cx_qrfc_invalid_queue_name .
    WRITE:/ 'Error'.
  CATCH cx_qrfc_duplicate_queue_name.
    WRITE:/ 'Error'.
ENDTRY.

单元历史监控

入站和出站队列bgRFC代码示例

DATA: my_destination TYPE REF TO if_bgrfc_destination_outbound,
      my_unit        TYPE REF TO if_qrfc_unit_outinbound,
      dest_name      TYPE bgrfc_dest_name_outbound,
      queue_name     TYPE qrfc_queue_name,
      queue_names    TYPE qrfc_queue_name_tab.

DATA: text TYPE text200.

TRY.
    dest_name = 'LOCALTEST'.
    my_destination = cl_bgrfc_destination_outbound=>create( dest_name ).
    my_unit = my_destination->create_qrfc_unit_outinbound( ).

    text = 'Simple Outbound - bgRFC type Q'.

    CALL FUNCTION 'YLC_FUNC001' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.

    CALL FUNCTION 'YLC_FUNC002' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.


    CALL FUNCTION 'YLC_FUNC003' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.

    CALL FUNCTION 'YLC_FUNC004' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.

    CALL FUNCTION 'YLC_FUNC005' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.

    queue_name = 'TEST_FUN1'.
    INSERT queue_name INTO TABLE queue_names.

    my_unit->add_queue_names_outbound( queue_names = queue_names ignore_duplicates = abap_true  ).
    my_unit->add_queue_names_inbound( queue_names = queue_names ignore_duplicates = abap_true  ).

    COMMIT WORK.
    WRITE:/ 'Success'.

  CATCH cx_bgrfc_invalid_destination .
    WRITE:/ 'Error'.
  CATCH cx_qrfc_invalid_queue_name .
    WRITE:/ 'Error'.
ENDTRY.

入站事务bgRFC代码示例

DATA: my_destination TYPE REF TO if_bgrfc_destination_inbound,
      my_unit        TYPE REF TO if_trfc_unit_inbound,
      dest_name      TYPE bgrfc_dest_name_inbound.

DATA: text TYPE text200.

TRY.
    dest_name = 'BGINBOUND'.
    my_destination = cl_bgrfc_destination_inbound=>create( dest_name ).
    my_unit = my_destination->create_trfc_unit( ).

    text = 'Simple inbound bgRFC type T'.

    CALL FUNCTION 'YLC_FUNC001' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.

    CALL FUNCTION 'YLC_FUNC002' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.

    CALL FUNCTION 'YLC_FUNC003' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.

    CALL FUNCTION 'YLC_FUNC004' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.

    CALL FUNCTION 'YLC_FUNC005' IN BACKGROUND UNIT my_unit
      EXPORTING
        text = text.

    COMMIT WORK.
    WRITE:/ 'Success'.
  CATCH cx_bgrfc_invalid_destination .
    WRITE:/ 'Error'.
ENDTRY.

出站队列bgRFC队列单元交叉场景示例

DATA: my_destination TYPE REF TO if_bgrfc_destination_outbound,
      my_unit1       TYPE REF TO if_qrfc_unit_outbound,
      my_unit2       TYPE REF TO if_qrfc_unit_outbound,
      dest_name      TYPE bgrfc_dest_name_outbound,
      queue_name     TYPE qrfc_queue_name,
      queue_names    TYPE qrfc_queue_name_tab.

DATA: text TYPE text200.

TRY.
    dest_name = 'LOCALTEST'.
    my_destination = cl_bgrfc_destination_outbound=>create( dest_name ).
    my_unit1 = my_destination->create_qrfc_unit( ).
    my_unit2 = my_destination->create_qrfc_unit( ).

    text = 'Simple Outbound - bgRFC type Q multiple'.

    CALL FUNCTION 'YLC_FUNC001' IN BACKGROUND UNIT my_unit1
      EXPORTING
        text = text.

    CALL FUNCTION 'YLC_FUNC002' IN BACKGROUND UNIT my_unit1
      EXPORTING
        text = text.

    CALL FUNCTION 'YLC_FUNC003' IN BACKGROUND UNIT my_unit2
      EXPORTING
        text = text.

    CALL FUNCTION 'YLC_FUNC004' IN BACKGROUND UNIT my_unit2
      EXPORTING
        text = text.

    CALL FUNCTION 'YLC_FUNC005' IN BACKGROUND UNIT my_unit2
      EXPORTING
        text = text.

    queue_name = 'TEST_FUN2'.
    INSERT queue_name INTO TABLE queue_names.
    my_unit2->add_queue_names_outbound( queue_names ).

    my_unit1->add_queue_name_outbound( 'TEST_FUN1' ).
    my_unit2->add_queue_name_outbound( 'TEST_FUN1' ).


    COMMIT WORK.
    WRITE:/ 'Success'.

  CATCH cx_bgrfc_invalid_destination .
    WRITE:/ 'Error'.
  CATCH cx_qrfc_invalid_queue_name .
    WRITE:/ 'Error'.
  CATCH cx_qrfc_duplicate_queue_name.
    WRITE:/ 'Error'.
ENDTRY.

单元1先创建，单元2后创建

由于单元1和单元2均在队列1中，因此队列2需要等待单元1执行结束

 反之，先单元2再单元1，队列2不会等待队列1

结果数据

开发API

        锁定和解锁

        类 CL_QRFC_LOCK_INBOUND、CL_QRFC_LOCK_OUTBOUND 和 CL_QRFC_LOCK_NOSEND，您可以使用队列锁来阻止处理单元，也可以取消队列锁。

        LOCK_QUEUE_FROM_TOP 方法将第一个单元锁定在目标指定队列的开头。这使得追溯锁定队列成为可能。如果不存在任何单元，则会自动创建一个空单元来映射锁。

        LOCK_QUEUE_FROM_CURRENT_POS 方法锁定下一个单元的执行（指提交的单元），该单元被写入目标的指定队列。这使得抢先锁定队列成为可能。创建一个空单元来映射锁。

        所有队列锁在下一次 COMMIT WORK 时变为活动状态。如果在应用程序 LUW 中同时创建了单元锁和队列锁，则始终首先设置队列锁，然后将单元锁分配给适当的队列。

 DATA lock_id        TYPE bgrfc_lock_id.   
    lock_id = my_unit->delay( 30 ).
    lock_id = my_unit->lock( ).

        lock 一直锁定，直到手动处理

        delay 锁定一定时间后自动启动（单位 s）

 GET_UNIT_STATE返回后台单元状态

GET_QUEUE_STATE查询 qRFC 单元的队列状态

RUN_FAILED_UNIT再次启动有错误的单元

DELETE_FAILED_UNIT方法删除有错误的单元

CL_BGRFC_SERVER bgRFC服务器端类

可在RFC中使用，如下可在RFC中获取当前单元ID

DATA(lv_unit_id) = cl_bgrfc_server=>get_unit_id( ).

 异常

例外

原因

CX_QRFC_DUPLICATE_LOCK

后台 RFC 中的重复锁定

CX_QRFC_DUPLICATE_QUEUE_NAME

qRFC 中一个单元的重复队列名称

CX_QRFC_INVALID_QUEUE_NAME

队列名称无效

CX_BGRFC_INVALID_DESTINATION

后台 RFC 中的目标错误

CX_BGRFC_INVALID_UNIT

后台 RFC 单位无效

CX_QRFC_NO_FAILED_UNIT

队列不包含任何不正确的单位

CX_QRFC_NO_SINGLE_QUEUE_NAME

只允许使用一个队列名称

CX_BGRFC_WRONG_EXEC_CONTEXT

该函数无法在当前上下文中运行

CX_BGRFC_ILLEGAL_PERMUTATION

无效排列

CX_BGRFC_INVALID_RETRY_KEY

重试原因无效

CX_BGRFC_INVALID_TIME_SPEC

无效的日期规范

CX_QRFC_NO_QUEUE_NAME

缺少队列名称

检查队列状态示例

      my_unit->if_bgrfc_unit~unit_id.
      DATA(lv_state) = cl_trfc_client_inbound=>if_bgrfc_client~get_unit_state( lv_unit_id ).
      IF lv_state = if_bgrfc_client=>unit_state_runnable OR
         lv_state = if_bgrfc_client=>unit_state_retry OR
         lv_state = if_bgrfc_client=>unit_state_in_execution.
      ENDIF.

COMMIT WORK语句之后，一个单元被耗尽 。可以实现方法 CREATE_UNIT_BY_PATTERN以再次使用该单元。

SEPARATE_FROM_UPDATE_TASK方法 删除单元处理和更新记录之间的绑定。 

bgRFC监控管理

事务代码 SBGRFCPERFMON

 修复错误后重启错误单元

 bgRFC调试

 报错队列会锁定，解锁后再重启错误单元

注意事项

         RFC中不允许 WAIT, COMMIT WORK, ROLLBACK WORK语句，以及HTTP communication (using the class CL_HTTP_CLIENT) 和函数DB_COMMIT 的调用，可以使用MESSAGE进行干涉

        一个单元中的数据库操作，会在执行完后在数据库中持久化，如果此时出现错误消息，整个单元不能再次一起回滚。

        每个单元可以有任意数量的锁。一个单元只有在所有锁都被删除后才能被处理。每个锁由一个唯一的 lock_id表示. 只能释放自己的锁，其他程序的运行时行为不会受到过早释放锁的影响。

https://blog.csdn.net/xiefireworks/article/details/126294866

谢图图
关注
  • 1
    点赞
  • 踩
  • 4
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
abap4.0实例程序开发
11-23
abap4.0实例程序开发
AP RFC介绍：关于sRFC，aRFC，tRFC，qRFC和bgRFC
ChampaignWolf的专栏
03-27 1461
目录 总述 同步RFC：sRFC 异步RFC：aRFC 事务RFC：tRFC 队列RFC：qRFC 后台RFC：bgRFC 使用 集成 架构 本地数据队列：LDQ 名词对照 正文 大概八月份的时候做过一个有关两个SAP系统间成本分摊传输的项目，使用到了RFC（Remote Function Call）技术。因为之前有着医疗-CRM相关接口开发的经验，以为自己对...
ABAP bgRFC
xiefireworks的博客
08-11 1016
Background RFC bgRFC配置，监控管理 bgRFC单元状态,bgRFC调试
ABAP中bgRFC的用法与示例
SAP领域技术博客
12-09 2355
1. bgRFC 的配置T-code 使用bgRFC时，主要会用到以下的事务代码： SBGRFCCONF - bgRFC Configuration SBGRFCMON - bgRFC Monitor SBGRFCPERFMON - bgRFC Performance Monitor 2. Inbound与Outbound的配置 bgRFC可以分为Inbound与Outbound两种类型。 当系统A不需要与远程系统交互，仅是与本流程解耦合，使用inbound bgRFC 当系统A需要向系统B发送信息，
ABAP并发执行函数 异步RFC
qq_45063256的博客
07-04 974
在ABAP中实现并发就是调用异步RFC函数，可以同事执行多个函数模块而不需要等待按顺序执行，具体代码在本文的最后。本文模拟了30次调用函数，每次执行会花费2s时间，如果不用并发执行，按照以下代码块依次执行30次则会花费超过。可以看到，此时使用并发执行的方式运行时间反而更慢了，如果把模拟次数增加，运行时间将会差的更多。这里可以明显感觉到并发的执行效率远远优于非并发执行，这里的性能比超过了30。如果通过并发的方式执行函数，即同时执行30个函数，花费的时间约为。的时间，本次具体花费时间约为。
SAP ABAP 详细解析关于COMMIT WORK 和COMMIT WORK
qq_53645728的博客
03-06 2019
SAP ABAP 详细解析关于COMMIT WORK 和COMMIT WORK
SAP RFC介绍(sRFC/aRFC/tRFC/qRFC/pRFC)
qq_36952606的博客
07-27 1112
RFC实际上是异步RFC调用的应用之一，异步RFC调用适用于多个SAP ABAP系统间的并行处理(不支持非SAP系统)，可以在同一个系统内部使用异步RFC调用，并将部分处理负载转移到其它的应用服务器上，如果不现实指定异步RFC调用的目标，则在同一应用服务器内，也可以通过本地异步RFC调用实现多个工作过程的并行处理。通过事务RFC调用，可以将多个逻辑上相关的远程调用绑定到一个LUW上.在该LUW内，所有调用按其调用顺序，在目标系统的相同程序上下文中以单个事务的方式执行，要么执行所有，要么完全回滚。
SAP abap实例大全
03-18
sap abap开发实例 方便入门
ABAP 报表开发实例
11-07
ABAP 报表开发实例 ABAP 报表开发实例是指使用 ABAP 语言开发报表的实践过程。在这个实例中，我们将一步步地讲解如何开发一个报表，从确定所需表开始，到定义内表和数据，接着是选择屏幕、查询数据、输出结果等步骤...
ABAP开发实例
06-11
从实例出发介绍ABAP开发，并有截图，简单易学，新手学习很好
ABAP开发技巧(很全的实例_包括RFC...).pdf
09-24
ABAP开发技巧(很全的实例_包括RFC...)
增强慎用commit语句
lxxiaoxiami的博客
03-31 954
增强里面写commit相关语句，可能会造成严重问题。同样，rollback work也不能出现在增强中 举例：在我们的MIGO操作时，首先产生物料凭证，同时去生成会计凭证。在中间书写commit语句(比如常用的增强点：MB_MIGO_BADI），可能造成生成物料凭证时，commit到了数据库，而后续凭证因为某些问题，没有产生成功，此时就造成了整体业务的不一致。 提交数据库方式： 1、显示提交。是指使用commit work或者这条语句触发的提交（包含封装这条语句的function module，如DB
ABAP 远程 RFC 函数创建完整详细教程（外部系统调用SAP接口）
qq_41757790的博客
08-16 6817
SAP 系统被外部系统调用的 RFC 接口函数完整创建过程。
ABAP RFC
xiefireworks的博客
08-10 1665
每个任务 ID 定义了一个单独的 RFC 连接，具有自己的上下文，这意味着在重复调用相同任务 ID 的功能模块的情况下，如果连接仍然存在，则可以访问相关功能组的全局数据。因此，当使用同步 RFC 时，被调用系统必须可用。如果接收系统不可用，则函数调用保留在发送系统的出站队列中，从那里定期重复调用，直到接收系统可以处理它。3 系统内置“BACK” 在远程调用的功能模块中使用，并链接回调用方，只能在已同步调用的功能模块中指定此项，在回调时，系统总是会在建立新的 RFC 连接之前尝试使用现有的 RFC 连接。..
SAP小技巧 使用bgRFC优化TRFC,QRFC
ABAP 技巧与实战
04-22 1320
点击蓝字关注我们一前言bgRFC是设计整合TRFC与QRFC调用的一种后台调用RFC的方式. 与单纯的TRFC/QRFC比较, bgRFC增加了入站目标管理,并且把入站目标与系统进程资源...
SAP ABAP创建RFC接口_实例（S/4 HANA）
qq_42080586的博客
07-13 3496
SAP ABAP创建RFC接口_实例……
SAP ABAP QRFC 使用，MQ，队列，实例
最新发布
VRZHENG的博客
11-14 850
在SAP中经常有碰到队列的情况，比如发送队列（各个系统交互等等），而且这样的情况不在少数，当多个系统同时使用的时候便会导致系统卡死，用户体验差，那么这个时候就要应用到MQ。在开源社区中有Rabbit MQ，那么在SAP中有没有现成可以使用的技术和情况呢？答案是必然的不然本文也不会存在。就是QRFC（Queqe RFC）也称队列RFC。本文旨在十分钟让你懂得如何使用QRFC并将他应用到实际的生产生活。那么截至到这里你已经能以队列的形式调用啦。
ABAP RFC远程调用
ChampaignWolf的专栏
03-06 6505
RFC可以在SAP系统之间、SAP系统与非SAP系统之间进行远程调用，且调用可以是双向的（SAP系统可以调用非SAP系统、非SAP系统也可以调用SAP系统——如Java通过Jco连接器来访问SAP）：RFM限制RFM：支持远程调用的功能模块。即SAP系统中的函数可以被其他SAP或非SAP系统调用 在SAP中，RFM的创建方式与普通功能模块类似，只是编写功能模块时，需要在Attributes选项卡中...
SAP RFC介绍：关于sRFC，aRFC，tRFC，qRFC和bgRFC
weixin_30398227的博客
12-29 870
大概八月份的时候做过一个有关两个SAP系统间成本分摊传输的项目，使用到了RFC（Remote Function Call）技术。因为之前有着医疗-CRM相关接口开发的经验，以为自己对RFC很熟悉了，做起来会很顺利，不想还是遇到了些问题。打算整理一下有关它们的内容，进一步学习。 本文内容的主要来源是SAP的英文文档。会比较偏重基本概念上的东西，偶尔涉及实际的代码、配置。后续可能会根据我的实际使用情...
sapabap开发实例代码
09-04
以下是一个简单的SAP ABAP开发实例代码： DATA: lv_number TYPE i, lv_message TYPE string. lv_number = 10. IF lv_number >= 0. lv_message = '这个数字是正数。'. ELSE. lv_message = '这个数字是负数。'. ...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值