CDS 带参数实例

CDS 带参数：

@AbapCatalog.sqlViewName: 'ZV_DZPZ'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: '取各系统对账凭证'
define view ZCDS_GET_ACDOCA_ALL
  with parameters
    in_PER_l   :ze_fiscyearper,
    in_PER_u   :ze_fiscyearper,
    in_LASTDAY :budat
  as select from ZCDS_GET_ACDOCA_CY
                   ( in_PER_l : $parameters.in_PER_l,
                     in_PER_u : $parameters.in_PER_u,
                     in_LASTDAY : $parameters.in_LASTDAY )
{
  *
}
union all select from ZCDS_GET_ACDOCA_XYC
                      (  in_PER_l : $parameters.in_PER_l,
                         in_PER_u : $parameters.in_PER_u,
                         in_LASTDAY : $parameters.in_LASTDAY )
{
  *
}
union all select from ZCDS_GET_ACDOCA_XZ
                          ( in_PER_l : $parameters.in_PER_l,
                            in_PER_u : $parameters.in_PER_u,
                            in_LASTDAY : $parameters.in_LASTDAY )
{
  *
};

 

 

@AbapCatalog.sqlViewName: 'ZV_CYPZ'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'CY对账凭证'
define view ZCDS_GET_ACDOCA_CY
  with parameters
    in_PER_l   :ze_fiscyearper,
    in_PER_u   :ze_fiscyearper,
    in_LASTDAY :budat
  as select from /bic/azefi_d011 as ACDOCA
    inner join   zhbt004         as T04 on  ACDOCA.ktopl      =  T04.ktopl
                                        and ACDOCA.zzassacc01 =  T04.zfzhs
                                        and ACDOCA.racct      >= T04.zac_from
                                        and ACDOCA.racct      <= T04.zac_to
                                        and ACDOCA.rbukrs     >= T04.zbukrs_from
                                        and ACDOCA.rbukrs     <= T04.zbukrs_to
    inner join   zhbt003         as T03 on T03.zacgrp = T04.zacgrp
  // and T03.xopvw  = 'X' //未清项管理
{
  key rbukrs, //公司代码
  key gjahr,  //会计年度
  key belnr,  //凭证编号
  key docln,  //行项目
      T04.zacgrp, //科目组
      T03.zacgrp_txt, //科目组描述
      T03.xopvw,   //未清项管理
      awref,       //参考凭证
      awitem,      //参考凭证行项目
      rassc,       //贸易伙伴编号
      hsl,         //以公司代码货币计的金额
      rhcur,       //公司代码货币
      wsl,         //以交易货币计的金额
      rwcur,       //交易货币
      drcrk, // 借贷
      poper,       //过账期间
      fiscyearper, //期间/年度
      budat,       //过账日期
      bldat,       //凭证日期
      usnam, //创建人
      timestamp,   //时戳
      blart,       //凭证类型
      ktosl,       //事物
      buzei,       //行项目
      ACDOCA.ktopl, //帐目表
      lifnr,       //供应商
      kunnr,       //客户
      mwskz,       //税码
      augdt,       //清帐日期
      augbl,       //清帐凭证
      auggj,       //清算会计年度
      zzassacc01,  //款项性质 辅助字段
      zzassacc06,  //业态
      racct, //科目号
      sgtxt //项目文本
}
where
         fiscyearper >= :in_PER_l
  and    fiscyearper <= :in_PER_u
  and(
         T03.xopvw   =  'X'
    and(
         augdt       =  '00000000'
      or augdt       >  :in_LASTDAY
    )
    or   T03.xopvw   =  ''
  )

;