c++项目起始（三）

已于 2024-04-12 14:55:18 修改
阅读量369 收藏 7
点赞数 8
分类专栏： c++项目之路 文章标签： c++ 开发语言
于 2024-02-02 10:15:22 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/yk_rainy/article/details/135978534
版权

在之前两篇文章中我们初始化了一个cmake构建的项目并传入git库， 接下来我们改改代码并介绍前面用到的cmake

作为一个git项目， 得有README.md和.gitignore文件， README.md作为项目的介绍说明， 我们在案例中写入c++ demo， .gitignore文件的作用是告诉git有哪些文件可以忽略，例如我们忽略build目录文件和.vscode目录文件， 这样每次提交代码git会忽略这些目录

build/*
.vscode/*

接下来我们以一个开源项目的cmakelists.txt来说明一些常用的指令：

cmake_minimum_required(VERSION 3.1)

##
## PROJECT
## name and version
##
project(nlohmann_json VERSION 3.11.2 LANGUAGES CXX)

##
## MAIN_PROJECT CHECK
## determine if nlohmann_json is built as a subproject (using add_subdirectory) or if it is the main project
##
set(MAIN_PROJECT OFF)
if (CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_SOURCE_DIR)
    set(MAIN_PROJECT ON)
endif()

##
## INCLUDE
##
##
set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_MODULE_PATH})
include(ExternalProject)

##
## OPTIONS
##

if (POLICY CMP0077)
    # Allow CMake 3.13+ to override options when using FetchContent / add_subdirectory.
    cmake_policy(SET CMP0077 NEW)
endif ()

# VERSION_GREATER_EQUAL is not available in CMake 3.1
if(${MAIN_PROJECT} AND (${CMAKE_VERSION} VERSION_EQUAL 3.13 OR ${CMAKE_VERSION} VERSION_GREATER 3.13))
    set(JSON_BuildTests_INIT ON)
else()
    set(JSON_BuildTests_INIT OFF)
endif()
option(JSON_BuildTests                     "Build the unit tests when BUILD_TESTING is enabled." ${JSON_BuildTests_INIT})
option(JSON_CI                             "Enable CI build targets." OFF)
option(JSON_Diagnostics                    "Use extended diagnostic messages." OFF)
option(JSON_GlobalUDLs                     "Place use-defined string literals in the global namespace." ON)
option(JSON_ImplicitConversions            "Enable implicit conversions." ON)
option(JSON_DisableEnumSerialization       "Disable default integer enum serialization." OFF)
option(JSON_LegacyDiscardedValueComparison "Enable legacy discarded value comparison." OFF)           
option(JSON_Install                        "Install CMake targets during install step." ${MAIN_PROJECT})
option(JSON_MultipleHeaders                "Use non-amalgamated version of the library." ON)
option(JSON_SystemInclude                  "Include as system headers (skip for clang-tidy)." OFF)

if (JSON_CI)
    include(ci)
endif ()

##
## CONFIGURATION
##
include(GNUInstallDirs)

set(NLOHMANN_JSON_TARGET_NAME               ${PROJECT_NAME})
set(NLOHMANN_JSON_CONFIG_INSTALL_DIR        "${CMAKE_INSTALL_DATADIR}/cmake/${PROJECT_NAME}" CACHE INTERNAL "")
set(NLOHMANN_JSON_INCLUDE_INSTALL_DIR       "${CMAKE_INSTALL_INCLUDEDIR}")
set(NLOHMANN_JSON_TARGETS_EXPORT_NAME       "${PROJECT_NAME}Targets")
set(NLOHMANN_JSON_CMAKE_CONFIG_TEMPLATE     "cmake/config.cmake.in")
set(NLOHMANN_JSON_CMAKE_CONFIG_DIR          "${CMAKE_CURRENT_BINARY_DIR}")
set(NLOHMANN_JSON_CMAKE_VERSION_CONFIG_FILE "${NLOHMANN_JSON_CMAKE_CONFIG_DIR}/${PROJECT_NAME}ConfigVersion.cmake")
set(NLOHMANN_JSON_CMAKE_PROJECT_CONFIG_FILE "${NLOHMANN_JSON_CMAKE_CONFIG_DIR}/${PROJECT_NAME}Config.cmake")
set(NLOHMANN_JSON_CMAKE_PROJECT_TARGETS_FILE "${NLOHMANN_JSON_CMAKE_CONFIG_DIR}/${PROJECT_NAME}Targets.cmake")
set(NLOHMANN_JSON_PKGCONFIG_INSTALL_DIR     "${CMAKE_INSTALL_DATADIR}/pkgconfig")

if (JSON_MultipleHeaders)
    set(NLOHMANN_JSON_INCLUDE_BUILD_DIR "${PROJECT_SOURCE_DIR}/include/")
    message(STATUS "Using the multi-header code from ${NLOHMANN_JSON_INCLUDE_BUILD_DIR}")
else()
    set(NLOHMANN_JSON_INCLUDE_BUILD_DIR "${PROJECT_SOURCE_DIR}/single_include/")
    message(STATUS "Using the single-header code from ${NLOHMANN_JSON_INCLUDE_BUILD_DIR}")
endif()

if (NOT JSON_ImplicitConversions)
    message(STATUS "Implicit conversions are disabled")
endif()

if (JSON_DisableEnumSerialization)
    message(STATUS "Enum integer serialization is disabled")
endif()

if (JSON_LegacyDiscardedValueComparison)
    message(STATUS "Legacy discarded value comparison enabled")
endif()

if (JSON_Diagnostics)
    message(STATUS "Diagnostics enabled")
endif()

if (JSON_SystemInclude)
    set(NLOHMANN_JSON_SYSTEM_INCLUDE "SYSTEM")
endif()

##
## TARGET
## create target and add include path
##
add_library(${NLOHMANN_JSON_TARGET_NAME} INTERFACE)
add_library(${PROJECT_NAME}::${NLOHMANN_JSON_TARGET_NAME} ALIAS ${NLOHMANN_JSON_TARGET_NAME})
if (${CMAKE_VERSION} VERSION_LESS "3.8.0")
    target_compile_features(${NLOHMANN_JSON_TARGET_NAME} INTERFACE cxx_range_for)
else()
    target_compile_features(${NLOHMANN_JSON_TARGET_NAME} INTERFACE cxx_std_11)
endif()

target_compile_definitions(
    ${NLOHMANN_JSON_TARGET_NAME}
    INTERFACE
    $<$<NOT:$<BOOL:${JSON_GlobalUDLs}>>:JSON_USE_GLOBAL_UDLS=0>
    $<$<NOT:$<BOOL:${JSON_ImplicitConversions}>>:JSON_USE_IMPLICIT_CONVERSIONS=0>
    $<$<BOOL:${JSON_DisableEnumSerialization}>:JSON_DISABLE_ENUM_SERIALIZATION=1>
    $<$<BOOL:${JSON_Diagnostics}>:JSON_DIAGNOSTICS=1>
    $<$<BOOL:${JSON_LegacyDiscardedValueComparison}>:JSON_USE_LEGACY_DISCARDED_VALUE_COMPARISON=1>
)

target_include_directories(
    ${NLOHMANN_JSON_TARGET_NAME}
    ${NLOHMANN_JSON_SYSTEM_INCLUDE} INTERFACE
    $<BUILD_INTERFACE:${NLOHMANN_JSON_INCLUDE_BUILD_DIR}>
    $<INSTALL_INTERFACE:include>
)

## add debug view definition file for msvc (natvis)
if (MSVC)
    set(NLOHMANN_ADD_NATVIS TRUE)
    set(NLOHMANN_NATVIS_FILE "nlohmann_json.natvis")
    target_sources(
        ${NLOHMANN_JSON_TARGET_NAME}
        INTERFACE
            $<INSTALL_INTERFACE:${NLOHMANN_NATVIS_FILE}>
            $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/${NLOHMANN_NATVIS_FILE}>
    )
endif()

# Install a pkg-config file, so other tools can find this.
CONFIGURE_FILE(
    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/pkg-config.pc.in"
    "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.pc"
)

##
## TESTS
## create and configure the unit test target
##
if (JSON_BuildTests)
    include(CTest)
    enable_testing()
    add_subdirectory(tests)
endif()

##
## INSTALL
## install header files, generate and install cmake config files for find_package()
##
include(CMakePackageConfigHelpers)
# use a custom package version config file instead of
# write_basic_package_version_file to ensure that it's architecture-independent
# https://github.com/nlohmann/json/issues/1697
configure_file(
    "cmake/nlohmann_jsonConfigVersion.cmake.in"
    ${NLOHMANN_JSON_CMAKE_VERSION_CONFIG_FILE}
    @ONLY
)
configure_file(
    ${NLOHMANN_JSON_CMAKE_CONFIG_TEMPLATE}
    ${NLOHMANN_JSON_CMAKE_PROJECT_CONFIG_FILE}
    @ONLY
)

if(JSON_Install)
    install(
        DIRECTORY ${NLOHMANN_JSON_INCLUDE_BUILD_DIR}
        DESTINATION ${NLOHMANN_JSON_INCLUDE_INSTALL_DIR}
    )
    install(
        FILES ${NLOHMANN_JSON_CMAKE_PROJECT_CONFIG_FILE} ${NLOHMANN_JSON_CMAKE_VERSION_CONFIG_FILE}
        DESTINATION ${NLOHMANN_JSON_CONFIG_INSTALL_DIR}
    )
    if (NLOHMANN_ADD_NATVIS)
        install(
            FILES ${NLOHMANN_NATVIS_FILE}
            DESTINATION .
    )
    endif()
    export(
        TARGETS ${NLOHMANN_JSON_TARGET_NAME}
        NAMESPACE ${PROJECT_NAME}::
        FILE ${NLOHMANN_JSON_CMAKE_PROJECT_TARGETS_FILE}
    )
    install(
        TARGETS ${NLOHMANN_JSON_TARGET_NAME}
        EXPORT ${NLOHMANN_JSON_TARGETS_EXPORT_NAME}
        INCLUDES DESTINATION ${NLOHMANN_JSON_INCLUDE_INSTALL_DIR}
    )
    install(
        EXPORT ${NLOHMANN_JSON_TARGETS_EXPORT_NAME}
        NAMESPACE ${PROJECT_NAME}::
        DESTINATION ${NLOHMANN_JSON_CONFIG_INSTALL_DIR}
    )
    install(
        FILES "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.pc"
        DESTINATION ${NLOHMANN_JSON_PKGCONFIG_INSTALL_DIR}
    )
endif()

1. cmake_minimum_required(VERSION 3.1)   指定项目最低cmake版本为3.1

2. project(nlohmann_json VERSION 3.11.2 LANGUAGES CXX)  指定项目名称、版本号和编程语言

3. set(MAIN_PROJECT OFF)  设置变量 MAIN_PROJECT 为OFF

4. if (CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_SOURCE_DIR)  用于做一些选择性的事情

5. include(ExternalProject) 引入ExternalProject模块

6. option(JSON_CI   "Enable CI build targets." OFF)  设定选项开关是否打开或者关闭

7. message(STATUS "Using the multi-header code from ${NLOHMANN_JSON_INCLUDE_BUILD_DIR}")  打印message信息， 主要用于校验变量等操作

8. add_library(${NLOHMANN_JSON_TARGET_NAME} INTERFACE)  定义一个库并指定源文件，如果没有指定静态库或者动态库则默认静态库

9. target_include_directories 为目标添加头文件搜索路径

超喜欢下雨天
关注
专栏目录
C++网络编程方面的开源项目
程序猿老樊的博客
06-16 808
合理的选择开源库能让我们快速的开发出可靠的软件，大大的节约开发时间和开发成本。因此，对开源库的特点和应用场景的掌握是非常重要也是非常必要的。
七、如何设置C++项目 set up C++ project
m0_66179815的博客
05-16 783
Visual Studio设置项目文件目录、组织项目文件
CMake使用基础汇总
Leo的专栏
07-27 1594
CMake入门基础
Cmake中文教程（十一）【2022.05.12】
yangjj2005的博客
05-12 1675
# 第 11 步：添加导出配置 在本教程的“安装与检测”一节中，我们添加了 CMake 安装项目的库和头文件的功能。在“封装与安装”一节中 ，我们添加了封装信息的功能，以便将其分发给其他人。 下一步是添加必要的信息，以便其他 CMake 项目无论是从构建目录、本地安装还是封装时都可以使用我们的项目。 第一步是更新我们的install(TARGETS)命令不仅可以指定 一个DESTINATION，还可以指定EXPORT。EXPORT关键字生成一个 CMake 文件，其中包含从安装树导入 install
CMake Tutorial 巡礼(11)_添加导出参数
耳东小白的小笔记本儿
10-16 884
CMake Tutorial 跟我一起学
cmake 生成供find_package使用的自定义模块
热门推荐
沧海一帆的专栏
11-08 1万+
cmake中经常使用find_package寻找模块，使用起来非常方便．find_package的原理是什么呢？如果自己写个模块，如何提供给别人使用．如果别人希望用find_package的形式使用你的模块中的库，我该如何用cmake写这个库呢？ 下面用一个例子来说明： myapp程序通过find_package调用mylib中的库 1.myapp工程 myapp工程目录如下 . ├── CMak...
qt c++ 圆弧绘制基于圆心坐标，起始坐标，终点坐标
04-20
总结来说，Qt C++中基于圆心坐标、起始坐标和终点坐标绘制圆弧，主要依赖于QPainter类的drawArc()函数，结合QPainter的其他属性设置，可以创建出丰富多彩的图形效果。通过学习和实践这些基本操作，你可以轻松地在Qt...
Visual Studio 2019创建C++ Hello World项目的方法
08-19
在本文中，我们将深入探讨如何使用Visual Studio 2019创建一个基本的C++“Hello World”项目。Visual Studio是Microsoft开发的一款强大的集成开发环境（IDE），它为多种编程语言，包括C++，提供了全面的支持。对于...
modbus 服务端（从站）C++小项目源码
08-07
本项目是关于在C++环境中实现Modbus从站（或称为客户端）服务端的小型项目，主要关注0x03功能码的数据交互。下面将详细阐述Modbus协议的基本概念、0x03功能码的作用以及C++实现Modbus服务器的关键技术点。 首先，...
C++项目之演讲比赛模拟
sir_TI的博客
09-30 949
演讲系统（SpeechContext）小结 前记 最近把C++ 的知识点过了一遍，虽然说不能完全的了解C++语言的特性，但是也发现了它的美，后面想要学习C++的热情高涨，故完成了一个小项目，来达到温故知新的效果吧。 主要涉及知识点：类、STL等 需求 1.比赛规则 学校举行一场演讲比赛，共有12个人参加。比赛共两轮，第一轮为淘汰赛，第二轮为决赛。 每次比赛共有10名裁判分别对每个选手进行打分。 ...
cmake学习5:如何将自己的库作为第三方库给别人使用
Heart_M的博客
10-09 2223
前面两篇文章我们分别将自己的工程安装在本地和将自己的工程打包给其他人直接使用,现在我们要做的就是如果在其他的cmake里面使用我们自己的工程,从build路径,从local安装,从打包的文件中
mediastream2交叉编译过程
code_back的博客
08-26 636
由于bctoolbox库采用C++11编写，gcc版本应大于gcc4.7 ， mediastream2库在gcc-4.9.3交叉编译环境下编译成功。 bcunit库的交叉编译 修改CMakelist.txt文件，在文件正文起始部分加上 /*****************************************复制起始*****************************************/ SET(CMAKE_SYSTEM_NAME Lin...
使用Cmake封装API接口成Package方法
weixin_46158722的博客
10-19 986
本文是个人探究API封装成Package以让他人像使用OpeCV，PCL等第三方库那样方便时所总结的经验。
C++生成dll和调用dll以及利用CMAKE生成c++ dll的问题
yangjj2005的博客
05-09 5095
一、dll生成 1、设置项目属性：打开vs，建立空项目，在项目的 配置属性->常规->项目默认值->配置类型 修改为：动态库(.dll) 2、准备文件：填写头文件和源文件，注意头文件的声明，源文件正常。 ————————————————————————————————————— | 头文件： ...
cmake
fanre的专栏
03-12 145
https://cmake.org/cmake/help/latest/guide/tutorial/index.html ############################################################################################################ # MathFunctions/CMakeLists.txt add_library(MathFunctions mysqrt.cxx)#生成链接库，(链接库名称，
正确使用CMake
wanywhn的博客
05-10 5304
文章目录简介一个错误的例子目标（Target）和属性（Properties）构建要求与使用要求libjsonutils放下CMAKE_CXX_FLAGS使用target_link_libraries建立依赖关系导入目标好的项目应该导出目标目标如果你想做到这一点，自行完成这就是你如何使用CMake在Config.cmake中导入目标 简介 这篇文章探讨了所谓的现代CMake的概念，它主张放弃传统的基...
C语言 12 函数
天河有尽后为涯，星海无边前作岸。
09-13 1120
程序的入口点就是main函数，只需要将程序代码编写到主函数中就可以运行了，不过这个函数只是由我们来定义，而不是我们来调用。当然，除了主函数之外，一直在使用的printf那么，函数的具体定义是什么呢？函数是完成特定任务的独立程序代码单元。每次要做这个任务时，都要完完整整地将任务的每一行代码都写下来，如果程序中多处都需要执行这个任务，每个地方都完整地写一遍，实在是太臃肿了，有没有一种更好的办法能优化代码呢？
CF C. Nikita and LCM
qq_74190237的博客
09-13 287
思维题.首先先对数组排序,考虑一种特殊情况,那就是如果数组最大值不能被其他数整除,这代表什么?代表其他数里面有某个质因子,最大值里面没有或者数量不管,所有最小公倍数都会大于最大值.那么其他情况的话,就可以确定所有的数都是最大数的因子,那么形成的最小公倍数也一定是最大数的因子,那么就可以枚举一下最大数的因子,就可以了.给长度为n的数组,求出最长的特殊子数组,如果子数组的最小公倍数不在原数组中,那么就是特殊的.
C++_map_set详解
最新发布
2302_77644537的博客
09-16 856
set是按照一定次序存储元素的容器在set中，元素的value也标识它(value就是key，类型为T)，并且每个value必须是唯一的。set中的元素不能在容器中修改(元素总是const)，但是可以从容器中插入或删除它们。在内部，set中的元素总是按照其内部比较对象(类型比较)所指示的特定严格的排序准则（默认是小于）进行排序。set在底层是用二叉搜索树(红黑树)实现的。map是关联容器，它按照特定的次序(按照key来比较)存储由键值key和值value组合而成的元素。
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值