springblade docker一键build、批量rm push到私有仓库-Registry 脚本

在虚拟机上搭了个 k8s，想把blade项目部署上去，由于使用的是私有仓库 registry，不适用于官方文档的docker部署方式，所以写了几个 简单的脚本方便部署。以下脚本 皆是 window环境

build 脚本

脚本名称：docker_build.bat
内容如下：

@echo off
setlocal enabledelayedexpansion
::生成的 build 文件
set mk_dir=docker_build
set mk_file=build_all.bat
for /r . %%a in (Dockerfile) do (if exist %%a (
  ::@echo %%a
  ::dockerFile 文件位置
  set dk_fl=%%a
  ::dockerFile 文件 父级目录
  set dk_fl_p=!dk_fl:~0,-11!
  call:handler_dk_fl %%a
  )
)

echo start docker command ---^>^> %cd%\%mk_dir%\%mk_file%
::执行 docker build -- 自动执行 去掉下方注释
::if exist %cd%\%mk_dir%\%mk_file% call %cd%\%mk_dir%\%mk_file%
echo -------- execute done... --------
pause
exit /b 0

::处理str 并生成 docker build 文件
:handler_dk_fl
setlocal enabledelayedexpansion
set target_char=\
set target_char_num=0
set target_char_index=0
:: docker tag 换成自己的 tag_p 前缀 tag_v 版本
set tag_p=192.168.1.58:5000/
set tag_v=z1
::echo need handler str: !dk_fl_p!
::复制字符串，用来截短，而不影响源字符串
set dk_fl_p_cp=!dk_fl_p!
::处理str
:next
if "!dk_fl_p_cp!" neq "" (
  set /a target_char_num+=1
  if "!dk_fl_p_cp:~0,1!"=="!target_char!" (
    set /a target_char_index=target_char_num
  )
  set dk_fl_p_cp=!dk_fl_p_cp:~1!
  goto next
)
::生成 docker build 文件
set tag=!dk_fl_p:~%target_char_index%!
::echo char '!target_char!' in str "!dk_fl_p!" last index: !target_char_index!
if not exist %cd%\%mk_dir% mkdir %cd%\%mk_dir%
echo start docker build --tag %tag_p%!tag!:%tag_v% -f %1 !dk_fl_p!>> %cd%\%mk_dir%\%mk_file%
goto:eof

脚本里面 字符串中字符位置 的获取 参考了 这里

将该 脚本放在 项目根目录，运行后会在根目录生成 文件夹：docker_build 以及该文件夹下的文件 build_all.bat，如图：


build_all中 即为 一键build的脚本，内容如下：

如需 自动 build ，可以去掉 docker_build.bat脚本中 如下代码的注释：

执行效果如下：

注意把 docker_build.bat 中的 set tag_p=192.168.1.58:5000/ 和 tag_v=z1 换成自己需要的tag。
执行完成后的docker images ：

rm 脚本

脚本名称：rm_images.bat
同样放在项目根目录， 批量 删除上一步生成的脚本文件 和 docker 镜像，内容如下：
注意脚本中的变量是否与你实际的一致， 特别是label_key，如果有其它的带有 blade- 名称的镜像，一定要把label_key修改 合适自己的，否则 可能会误删！（label_key我这里是用来做名称 过滤的）

@echo off
::生成的 build 文件
set mk_dir=docker_build
set mk_file=build_all.bat
set label_key=blade-
if exist %cd%\%mk_dir%\%mk_file% del %cd%\%mk_dir%\%mk_file%
::rmdir /S /Q %mk_dir%
for /f "tokens=3" %%a in ('docker images^|findstr %label_key%') do echo %%a && docker rmi %%a
echo -------- rm all done... --------

push 脚本

脚本名称：docker_push.bat
将build出来的镜像 推送到 registry中，内容如下：

::docker push
@echo off
set label_key=blade-
for /f "tokens=1" %%a in ('docker images^|findstr %label_key%') do echo %%a && start docker push %%a
echo -------- push all done... --------

set label_key=blade- 同样需要注意，最好改成合适自己的

结束

推送完成之后 进行验证：

验证正常。