最短编辑距离 poj3356

有三种情况可以导致我们上面设计的状态会发生转移。我们现在来看A[i] 和 B[j] ，
①、我们可以在 B[j]后面插入一个核苷酸（即一个字符）ch，ch==A[i]，这样做的话，
至少需要 dp[i - 1][j] + 1步操作，即 dp[i][j] = dp[i - 1][j] + 1。
②、我们可以删除 B[j]，这样的话，B[1...j] 变为A[1...i] 需要 dp[i][j - 1]步，
即 dp[i][j] = dp[i][j - 1] + 1。
③、我们也可以考虑修改 B[j]，使它变为A[j]，但是如果 B[j]本来就等于 A[i]的话，
那修改其实相当于用了 0步，如果 B[j] != A[i] 的话，那修改相当于用了 1步。
所以 dp[i][j] = dp[i - 1][j - 1] + （A[i] == B[j] ? 0, 1）。

决策：
决策就很简单了，从上面三种状态转移中选择一个最小值就可以了。

处理边界：
处理好边界非常重要，这里需要注意的是对dp[0][0....m],dp[0.....n][0]的初始化，
可以这样看，dp[0][i],就是说A[1...n]是一个空串，而B[1...m]十个长度为i的串，
很显然B串变为A串就是删除i个核苷酸。

program edit;
var a,b:ansistring;
    l,k,la,lb,i,j,cost:longint;
    c:array[0..1000,0..1000]of longint;
function min(a,b:longint):longint;
begin
 if a<b then min:=a else min:=b;
end;
function max(a,b:longint):longint;
begin
 if a<b then max:=b else max:=a;
end;
begin
 while not eof do
  begin
   readln(a);
   readln(b);
   k:=pos(' ',a);
   val(copy(a,1,k-1),la);
   delete(a,1,k);
   k:=pos(' ',b);
   val(copy(b,1,k-1),lb);
   delete(b,1,k);
   l:=max(la,lb);
   for i:=1 to l do
    begin
     c[i,0]:=i;
     c[0,i]:=i;
    end;//注意边界处理
   c[0,0]:=0;
   for i:=1 to la do
    for j:=1 to lb do
     begin
      c[i,j]:=min(c[i-1,j]+1,c[i,j-1]+1);
      if a[i]=b[j] then
       c[i,j]:=min(c[i,j],c[i-1,j-1])
      else
       c[i,j]:=min(c[i,j],c[i-1,j-1]+1);
     end;
   writeln(c[la,lb]);
  end;
end.