轴的网格划分

        轴的规则网格生成：
        图8-1所示为轴的示意图，要求生成图8-2所示的规则六面体网格单元。

图8-2 生成的网格图

        用自底向上建模方式生成的具体操作是:
　　1)选择最大圆面所在的位置，按不同的半径生成关键点，然后再按半径连成线，通过生成的半径线绕中心旋转生成一个面，对面进行重经操作后，就形成了不同半径的圆面或圆环面。
　　2)对圆面和圆环面生成二维单元(plane42)，其中为了保证生成的单元都是六面体，在圆面的中心又生成了一个正方形面，然后对其划分曲格，生成的结果如图8-3b所示。
　　3)改变单元的属性，即设定单元为3D单元(SOLID45)，指定单元的边长，采用沿线拖拉延伸的方式，在生成体的同时将网格划分完成。
　　其中具体的操作内容请参考下面的APDL文件。
　　//Zhou.txt

FINISH
/CLEAR,START
/TITIE,'The Process of Axis Meshing'      !指定标题名
/PREP7
ET,1,PLANE42                              !指定单元类型
ET,2,SOLID45

K,1,,,,                         !生成中心线的关键点
K,2,,,560,
K,4,,100,220,
K,5,,80,220,                    !按半径值生成关键点
K,6,,75,220,
K,7,,65,220,
K,8,,50,220,
K,9,,0,220,

LSTR,9,4                        !按半径连线
LSTR,9,8
LSTR,9,7
LSTR,9,6
LSTR,9,5
AROTAT,1,,,,,,2,1,360,,          !将半径线绕中心线旋转生成面
AROTAT,2,,,,,,2,1,360,,
AROTAT,5,,,,,,2,1,360,,
AROTAT,3,,,,,,2,1,360,,
AROTAT,4,,,,,,2,1,360,,

AOVLAP,ALL                       !生成的半径面进行重叠操作
NUMCMP,ALL                       !进行实体合并操作
NUMMRG,ALL,,,,LOW                !压缩实体的编号

LSTR,9,2                         !将中心线连成两段
LSTR,9,1

KL,1,0.5,,                       !在中心圆面的线上按比率生成关键点
KL,8,0.5,,
KL,7,0.5,,
KL,6,0.5,,
A,26,27,24,25                    !由4个关键点生成面
AOVLAP,1,2,3,4,21                !对生成的面与中心面进行重叠操作
AADD,22,23,24,25,                   !对重叠生成的面相加
APLOT

ESIZE,15,0,                      !设置面网格的等分数
MSHKEY,1                         !设定采用映射网格的方式
AMESH,ALL                        !对所有的面划分网格
/IMAGE,SAVE,axis_2d,BMP          !生成2D的位图文件

K,30,,0,500,                     !按轴的长度在中心线生成关键点
K,31,,0,300,
K,32,,0,200,
K,33,,0,80,
LSTR,9,30                        !连线
LSTR,9,31
LSTR,9,32
LSTR,9,33
SAVE

ASEL,S,,,26,29                    !选择编号为26~29的4个面
ASEL,A,,,1                        !再选择正方形面
CM,a1,AREA                        !生成元件名A1
ASEL,S,,,9,12                     !生成元件名A2
CM,a2,AREA
ASEL,S,,,17,20
CM,a3,AREA                        !生成元件名A3
ASEL,S,,,13,16
CM,a4,AREA                        !生成元件名A4
ASEL,S,,,5,8
CM,a5,AREA                        !生成元件名A5
CMGRP,a6,A1,A2                    !生成组件名A6

/VIEW,1,1,1,1                     !调整视角方向
TYPE,2                            !指定单元类型2，即3D单元
ESIZE,20,0                        !指定生成3D单元的边长
CMSEL,S,a1                        !按元件A1选择面
VDRAG,ALL,,,,,,41                 !沿线41拖拉生成体
CMSEL,S,a2
VDRAG,ALL,,,,,,1                  !元件A2沿线1拖拉生成体
CMSEL,S,a3
VDRAG,ALL,,,,,,6
CMSEL,S,a5
VDRAG,ALL,,,,,,7
CMSEL,S,a4
VDRAG,ALL,,,,,,8
CMSEL,S,a6
VDRAG,ALL,,,,,,42

ALLSEL,ALL                        !选择所有的实体
ESEL,S,TYPE,,1                    !选择单元类型1的面
ACLEAR,ALL                        !删除2D单元
EPLOT
ALLSEL,ALL
NUMMRG,ALL,,,,LOW                 !合并实体的操作
NUMCMP,ALL                        !压缩实体的编号
!/DIST,1,0.729000,1                !指定视角的距离
!/TRIAD,LTOP                       !移到坐标三角符号到左上角
ePLOT
/PLOPTS,DATA,0                    !关闭日期和时间的显示
/AUTO,1                           !自动调整视图fit
/REP,FAST 
/IMAGE,SAVE,axis_3d,BMP           !生成一个3D的位图
FINISH

        生成2D单元网格图，如图8-3b所示。

图8-3b 生成的面网格