Cortex-M4 线程切换

;/*
; * void hw_context_switch_to(uint32 to);
; * r0 --> to
; * this fucntion is used to perform the first thread switch
; */
hw_context_switch_to    PROC
    EXPORT hw_context_switch_to
    ; set to thread
    LDR     r1, =interrupt_to_thread
    STR     r0, [r1]

    IF      {FPU} != "SoftVFP"
    ; CLEAR CONTROL.FPCA
    MRS     r2, CONTROL             ; read
    BIC     r2, #0x04               ; modify
    MSR     CONTROL, r2             ; write-back
    ENDIF

    ; set from thread to 0
    LDR     r1, =interrupt_from_thread
    MOV     r0, #0x0
    STR     r0, [r1]

    ; set interrupt flag to 1
    LDR     r1, =thread_switch_interrupt_flag
    MOV     r0, #1
    STR     r0, [r1]

    ; set the PendSV and SysTick exception priority
    LDR     r0, =NVIC_SYSPRI2
    LDR     r1, =NVIC_PENDSV_PRI
    LDR.W   r2, [r0,#0x00]       ; read
    ORR     r1,r1,r2             ; modify
    STR     r1, [r0]             ; write-back

    ; trigger the PendSV exception (causes context switch)
    LDR     r0, =NVIC_INT_CTRL
    LDR     r1, =NVIC_PENDSVSET
    STR     r1, [r0]

    ; restore MSP
    LDR     r0, =SCB_VTOR
    LDR     r0, [r0]
    LDR     r0, [r0]
    MSR     msp, r0

    ; enable interrupts at processor level
    CPSIE   F
    CPSIE   I

    ; ensure PendSV exception taken place before subsequent operation
    DSB
    ISB

    ; never reach here!
    ENDP

用于执行第一次线程切换。

LDR r1,=interrupt_to_thread
STR r0,[r1]

将参数to的值存储到全局变量，interrupt_to_thread中

IF {FPU} != "SoftVFP"
是一个条件判断，如果处理器支持浮点运算（FPU不是软件模拟的），则执行其中的指令块。
;CLEAR CONTROL.FPCA
在这个情况下，通过指令序列清除了 CONTROL.FPCA 标志，可能用于关闭浮点运算的自动上下文保存。
MRS     r2, CONTROL             ; read
BIC     r2, #0x04               ; modify
MSR     CONTROL, r2             ; write-back
ENDIF

LDR     r1, =interrupt_from_thread
    MOV     r0, #0x0
    STR     r0, [r1]

清空from线程信息

    ; set interrupt flag to 1
    LDR     r1, =thread_switch_interrupt_flag
    MOV     r0, #1
    STR     r0, [r1]

将中断标志“thread_switch_interrupt_flag”设置为1，表明线程切换正在进行

LDR     r0, =NVIC_SYSPRI2
    LDR     r1, =NVIC_PENDSV_PRI
    LDR.W   r2, [r0,#0x00]       ; read
    ORR     r1,r1,r2             ; modify
    STR     r1, [r0]             ; write-back

设置PendSV和SysTick优先级，通过读取和修改NVIC_SYSPRI2寄存器的值来实现

LDR r0, =NVIC_INT_CTRL
LDR r1, =NVIC_PENDSVSET
STR r1,[r0]

触发PendSV异常

PendSV异常处理

; r0 --> switch from thread stack
; r1 --> switch to thread stack
; psr, pc, lr, r12, r3, r2, r1, r0 are pushed into [from] stack
PendSV_Handler   PROC
    EXPORT PendSV_Handler

    ; disable interrupt to protect context switch
    MRS     r2, PRIMASK
    CPSID   I

    ; get thread_switch_interrupt_flag
    LDR     r0, =thread_switch_interrupt_flag
    LDR     r1, [r0]
    CBZ     r1, pendsv_exit         ; pendsv already handled

    ; clear thread_switch_interrupt_flag to 0
    MOV     r1, #0x00
    STR     r1, [r0]

    LDR     r0, =interrupt_from_thread
    LDR     r1, [r0]
    CBZ     r1, switch_to_thread    ; skip register save at the first time

    MRS     r1, psp                 ; get from thread stack pointer

    IF      {FPU} != "SoftVFP"
    TST     lr, #0x10               ; if(!EXC_RETURN[4])
    VSTMFDEQ  r1!, {d8 - d15}       ; push FPU register s16~s31
    ENDIF

    STMFD   r1!, {r4 - r11}         ; push r4 - r11 register

    IF      {FPU} != "SoftVFP"
    MOV     r4, #0x00               ; flag = 0

    TST     lr, #0x10               ; if(!EXC_RETURN[4])
    MOVEQ   r4, #0x01               ; flag = 1

    STMFD   r1!, {r4}               ; push flag
    ENDIF

    LDR     r0, [r0]
    STR     r1, [r0]                ; update from thread stack pointer

栈初始化

rt_uint8_t *rt_hw_stack_init(void *tentry, void *parameter, rt_uint8_t *stack_addr, void *texit)
{
	struct stack_frame *stack_frame;
	rt_uint8_t *stk;
	unsigned long i;

	stk = stack_addr + sizeof(rt_uint32_t);
	stk  = (rt_uint8_t *)RT_ALIGN_DOWN((rt_uint32_t)stk, 8);
    stk -= sizeof(struct stack_frame);

    stack_frame = (struct stack_frame *)stk;
}